[gentoo-commits] gentoo-x86 commit in sys-apps/kmod: kmod-18-r1.ebuild kmod-18-r2.ebuild ChangeLog

[Samuli Suominen (ssuominen)]

ssuominen    14/10/30 05:39:20

  Modified:             kmod-18-r1.ebuild ChangeLog
  Added:                kmod-18-r2.ebuild
  Log:
  Include upstream patch for udev-217 compability and adjust blockers accordingly.
  
  (Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

Revision  Changes    Path
1.13                 sys-apps/kmod/kmod-18-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/kmod/kmod-18-r1.ebuild?rev=1.13&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/kmod/kmod-18-r1.ebuild?rev=1.13&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/kmod/kmod-18-r1.ebuild?r1=1.12&r2=1.13

Index: kmod-18-r1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/kmod/kmod-18-r1.ebuild,v
retrieving revision 1.12
retrieving revision 1.13
diff -u -r1.12 -r1.13
--- kmod-18-r1.ebuild	3 Oct 2014 06:32:51 -0000	1.12
+++ kmod-18-r1.ebuild	30 Oct 2014 05:39:20 -0000	1.13
@@ -1,6 +1,6 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/kmod/kmod-18-r1.ebuild,v 1.12 2014/10/03 06:32:51 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/kmod/kmod-18-r1.ebuild,v 1.13 2014/10/30 05:39:20 ssuominen Exp $
 
 EAPI=5
 
@@ -30,9 +30,13 @@
 # See bug #408915.
 RESTRICT="test"
 
+# Block everything above and including 217 for -static-nodes-indicate-that-creation-of-static-nodes-.patch
 RDEPEND="!sys-apps/module-init-tools
 	!sys-apps/modutils
 	!<sys-apps/openrc-0.12
+	!>=sys-fs/udev-217
+	!>=sys-fs/eudev-2.1
+	!>=sys-apps/systemd-217
 	lzma? ( >=app-arch/xz-utils-5.0.4-r1 )
 	python? ( ${PYTHON_DEPS} )
 	zlib? ( >=sys-libs/zlib-1.2.6 )" #427130



1.172                sys-apps/kmod/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/kmod/ChangeLog?rev=1.172&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/kmod/ChangeLog?rev=1.172&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/kmod/ChangeLog?r1=1.171&r2=1.172

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/kmod/ChangeLog,v
retrieving revision 1.171
retrieving revision 1.172
diff -u -r1.171 -r1.172
--- ChangeLog	3 Oct 2014 06:32:51 -0000	1.171
+++ ChangeLog	30 Oct 2014 05:39:20 -0000	1.172
@@ -1,6 +1,14 @@
 # ChangeLog for sys-apps/kmod
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/kmod/ChangeLog,v 1.171 2014/10/03 06:32:51 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/kmod/ChangeLog,v 1.172 2014/10/30 05:39:20 ssuominen Exp $
+
+*kmod-18-r2 (30 Oct 2014)
+
+  30 Oct 2014; Samuli Suominen <ssuominen@g.o>
+  +files/kmod-18-static-nodes-indicate-that-creation-of-static-nodes-.patch,
+  +kmod-18-r2.ebuild, kmod-18-r1.ebuild:
+  Include upstream patch for udev-217 compability and adjust blockers
+  accordingly.
 
   03 Oct 2014; Raúl Porcel <armin76@g.o> kmod-18-r1.ebuild:
   m68k/s390/sh stable



1.1                  sys-apps/kmod/kmod-18-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/kmod/kmod-18-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/kmod/kmod-18-r2.ebuild?rev=1.1&content-type=text/plain

Index: kmod-18-r2.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/kmod/kmod-18-r2.ebuild,v 1.1 2014/10/30 05:39:20 ssuominen Exp $

EAPI=5

PYTHON_COMPAT=( python{2_7,3_2,3_3,3_4} )

inherit bash-completion-r1 eutils multilib python-r1

if [[ ${PV} == 9999* ]]; then
	EGIT_REPO_URI="git://git.kernel.org/pub/scm/utils/kernel/${PN}/${PN}.git"
	inherit autotools git-2
else
	SRC_URI="mirror://kernel/linux/utils/kernel/kmod/${P}.tar.xz"
	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
	inherit libtool
fi

DESCRIPTION="library and tools for managing linux kernel modules"
HOMEPAGE="http://git.kernel.org/?p=utils/kernel/kmod/kmod.git"

LICENSE="LGPL-2"
SLOT="0"
IUSE="debug doc lzma python static-libs +tools zlib"

# Upstream does not support running the test suite with custom configure flags.
# I was also told that the test suite is intended for kmod developers.
# So we have to restrict it.
# See bug #408915.
RESTRICT="test"

# Block everything below 217 for -static-nodes-indicate-that-creation-of-static-nodes-.patch
RDEPEND="!sys-apps/module-init-tools
	!sys-apps/modutils
	!<sys-apps/openrc-0.12
	!<sys-fs/udev-217
	!<sys-fs/eudev-2.1
	!<sys-apps/systemd-217
	lzma? ( >=app-arch/xz-utils-5.0.4-r1 )
	python? ( ${PYTHON_DEPS} )
	zlib? ( >=sys-libs/zlib-1.2.6 )" #427130
DEPEND="${RDEPEND}
	doc? ( dev-util/gtk-doc )
	lzma? ( virtual/pkgconfig )
	python? (
		dev-python/cython[${PYTHON_USEDEP}]
		virtual/pkgconfig
		)
	zlib? ( virtual/pkgconfig )"
if [[ ${PV} == 9999* ]]; then
	DEPEND="${DEPEND}
		dev-libs/libxslt"
fi

REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"

DOCS="NEWS README TODO"

src_prepare() {
	if [ ! -e configure ]; then
		if use doc; then
			gtkdocize --copy --docdir libkmod/docs || die
		else
			touch libkmod/docs/gtk-doc.make
		fi
		eautoreconf
	else
		epatch "${FILESDIR}"/${PN}-15-dynamic-kmod.patch #493630
		elibtoolize
	fi

	epatch "${FILESDIR}"/${P}-static-nodes-indicate-that-creation-of-static-nodes-.patch

	# Restore possibility of running --enable-static wrt #472608
	sed -i \
		-e '/--enable-static is not supported by kmod/s:as_fn_error:echo:' \
		configure || die
}

src_configure() {
	local myeconfargs=(
		--bindir="${EPREFIX}/bin"
		--with-rootlibdir="${EPREFIX}/$(get_libdir)"
		--enable-shared
		$(use_enable static-libs static)
		$(use_enable tools)
		$(use_enable debug)
		$(use_enable doc gtk-doc)
		$(use_with lzma xz)
		$(use_with zlib)
		--with-bashcompletiondir="$(get_bashcompdir)"
	)

	local ECONF_SOURCE="${S}"

	kmod_configure() {
		mkdir -p "${BUILD_DIR}" || die
		run_in_build_dir econf "${myeconfargs[@]}" "$@"
	}

	BUILD_DIR="${WORKDIR}/build"
	kmod_configure --disable-python

	if use python; then
		python_parallel_foreach_impl kmod_configure --enable-python
	fi
}

src_compile() {
	if [[ ${PV} != 9999* ]]; then
		# Force -j1 because of -15-dynamic-kmod.patch, likely caused by lack of eautoreconf
		# wrt #494806
		local MAKEOPTS="${MAKEOPTS} -j1"
	fi

	emake -C "${BUILD_DIR}"

	if use python; then
		local native_builddir=${BUILD_DIR}

		python_compile() {
			emake -C "${BUILD_DIR}" -f Makefile -f - python \
				VPATH="${native_builddir}:${S}" \
				native_builddir="${native_builddir}" \
				libkmod_python_kmod_{kmod,list,module,_util}_la_LIBADD='$(PYTHON_LIBS) $(native_builddir)/libkmod/libkmod.la' \
				<<< 'python: $(pkgpyexec_LTLIBRARIES)'
		}

		python_foreach_impl python_compile
	fi
}

src_install() {
	emake -C "${BUILD_DIR}" DESTDIR="${D}" install
	einstalldocs

	if use python; then
		local native_builddir=${BUILD_DIR}

		python_install() {
			emake -C "${BUILD_DIR}" DESTDIR="${D}" \
				VPATH="${native_builddir}:${S}" \
				install-pkgpyexecLTLIBRARIES \
				install-dist_pkgpyexecPYTHON
		}

		python_foreach_impl python_install
	fi

	prune_libtool_files --modules

	if use tools; then
		local bincmd sbincmd
		for sbincmd in depmod insmod lsmod modinfo modprobe rmmod; do
			dosym /bin/kmod /sbin/${sbincmd}
		done

		# These are also usable as normal user
		for bincmd in lsmod modinfo; do
			dosym kmod /bin/${bincmd}
		done
	fi

	cat <<-EOF > "${T}"/usb-load-ehci-first.conf
	softdep uhci_hcd pre: ehci_hcd
	softdep ohci_hcd pre: ehci_hcd
	EOF

	insinto /lib/modprobe.d
	doins "${T}"/usb-load-ehci-first.conf #260139

	newinitd "${FILESDIR}"/kmod-static-nodes-r1 kmod-static-nodes
}

pkg_postinst() {
	if [[ -L ${EROOT%/}/etc/runlevels/boot/static-nodes ]]; then
		ewarn "Removing old conflicting static-nodes init script from the boot runlevel"
		rm -f "${EROOT%/}"/etc/runlevels/boot/static-nodes
	fi

	# Add kmod to the runlevel automatically if this is the first install of this package.
	if [[ -z ${REPLACING_VERSIONS} ]]; then
		if [[ ! -d ${EROOT%/}/etc/runlevels/sysinit ]]; then
			mkdir -p "${EROOT%/}"/etc/runlevels/sysinit
		fi
		if [[ -x ${EROOT%/}/etc/init.d/kmod-static-nodes ]]; then
			ln -s /etc/init.d/kmod-static-nodes "${EROOT%/}"/etc/runlevels/sysinit/kmod-static-nodes
		fi
	fi

	if [[ -e ${EROOT%/}/etc/runlevels/sysinit ]]; then
		if [[ ! -e ${EROOT%/}/etc/runlevels/sysinit/kmod-static-nodes ]]; then
			ewarn
			ewarn "You need to add kmod-static-nodes to the sysinit runlevel for"
			ewarn "kernel modules to have required static nodes!"
			ewarn "Run this command:"
			ewarn "\trc-update add kmod-static-nodes sysinit"
		fi
	fi
}