[gentoo-commits] repo/gentoo:master commit in: dev-python/wxpython/

[Sven Wegener]

commit:     3de0e0b2f75e915cadd18d9cc943940b09260d4b
Author:     Sven Wegener <swegener <AT> gentoo <DOT> org>
AuthorDate: Tue Feb  2 21:01:14 2021 +0000
Commit:     Sven Wegener <swegener <AT> gentoo <DOT> org>
CommitDate: Wed Feb  3 07:44:17 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3de0e0b2

dev-python/wxpython: Enable DISTUTILS_IN_SOURCE_BUILD, bug #711970

Closes: https://bugs.gentoo.org/711970
Package-Manager: Portage-3.0.13, Repoman-3.0.2
Signed-off-by: Sven Wegener <swegener <AT> gentoo.org>

 dev-python/wxpython/wxpython-4.0.7-r1.ebuild | 92 ++++++++++++++++++++++++++++
 1 file changed, 92 insertions(+)

diff --git a/dev-python/wxpython/wxpython-4.0.7-r1.ebuild b/dev-python/wxpython/wxpython-4.0.7-r1.ebuild
new file mode 100644
index 00000000000..7585b66bcd4
--- /dev/null
+++ b/dev-python/wxpython/wxpython-4.0.7-r1.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{7,8,9} )
+WX_GTK_VER="3.0-gtk3"
+
+DISTUTILS_IN_SOURCE_BUILD="1"
+
+inherit distutils-r1 multiprocessing virtualx wxwidgets
+
+MY_PN="wxPython"
+MY_PV="${PV}.post2"
+
+DESCRIPTION="A blending of the wxWindows C++ class library with Python"
+HOMEPAGE="https://www.wxpython.org/"
+SRC_URI="mirror://pypi/${P:0:1}/${MY_PN}/${MY_PN}-${MY_PV}.tar.gz"
+
+LICENSE="wxWinLL-3"
+SLOT="4.0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="test webkit"
+# Tests broken: #726812, #722716
+RESTRICT="test"
+#RESTRICT="!test? ( test )"
+
+# wxPython doesn't seem to be able to optionally disable features. webkit is
+# optionally patched out because it's so huge, but other elements are not,
+# which makes us have to require all features from wxGTK
+RDEPEND="
+	>=x11-libs/wxGTK-3.0.4-r301:${WX_GTK_VER}=[gstreamer,libnotify,opengl,sdl,tiff,webkit?,X]
+	media-libs/libpng:0=
+	media-libs/tiff:0
+	virtual/jpeg:0"
+
+DEPEND="${RDEPEND}
+	app-doc/doxygen
+	dev-python/pathlib2[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	test? (
+		${VIRTUALX_DEPEND}
+		dev-python/appdirs[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)"
+
+S="${WORKDIR}/${MY_PN}-${MY_PV}"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-4.0.6-skip-broken-tests.patch"
+)
+
+python_prepare_all() {
+	if ! use webkit; then
+		eapply "${FILESDIR}/${PN}-4.0.6-no-webkit.patch"
+		rm unittests/test_webview.py || die
+	fi
+	# Most of these tests disabled below fail because of the virtx/portage
+	# environment, but some fail for unknown reasons.
+	rm unittests/test_uiaction.py \
+		unittests/test_notifmsg.py \
+		unittests/test_mousemanager.py \
+		unittests/test_display.py \
+		unittests/test_pi_import.py \
+		unittests/test_lib_agw_thumbnailctrl.py \
+		unittests/test_sound.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+src_configure() {
+	setup-wxwidgets
+}
+
+python_compile() {
+	DOXYGEN=/usr/bin/doxygen ${PYTHON} build.py dox etg --nodoc || die
+	${PYTHON} build.py build_py \
+		--use_syswx \
+		--no_magic \
+		--jobs=$(makeopts_jobs) \
+		--release || die
+}
+
+python_install() {
+	distutils-r1_python_install --skip-build
+}
+
+python_test() {
+	virtx pytest -vv unittests
+}