[gentoo-commits] repo/gentoo:master commit in: dev-libs/libuv/

[Jeroen Roovers]

commit:     6c5a74a1c6b30ad867f8b33f8ffd89f293063c1e
Author:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
AuthorDate: Fri Mar 15 15:00:20 2019 +0000
Commit:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
CommitDate: Fri Mar 15 15:08:15 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6c5a74a1

dev-libs/libuv: Add live ebuild

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Jeroen Roovers <jer <AT> gentoo.org>

 dev-libs/libuv/libuv-9999.ebuild | 47 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

diff --git a/dev-libs/libuv/libuv-9999.ebuild b/dev-libs/libuv/libuv-9999.ebuild
new file mode 100644
index 00000000000..5e8f4c3920c
--- /dev/null
+++ b/dev-libs/libuv/libuv-9999.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools git-r3 multilib-minimal
+
+DESCRIPTION="Cross-platform asychronous I/O"
+HOMEPAGE="https://github.com/libuv/libuv"
+EGIT_REPO_URI="${HOMEPAGE}"
+
+LICENSE="BSD BSD-2 ISC MIT"
+SLOT="0/1"
+KEYWORDS=""
+IUSE="static-libs"
+RESTRICT="test"
+
+DEPEND="sys-devel/libtool
+	virtual/pkgconfig[${MULTILIB_USEDEP}]"
+
+src_prepare() {
+	default
+
+	echo "m4_define([UV_EXTRA_AUTOMAKE_FLAGS], [serial-tests])" \
+		> m4/libuv-extra-automake-flags.m4 || die
+
+	# upstream fails to ship a configure script
+	eautoreconf
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		cc_cv_cflags__g=no
+		$(use_enable static-libs static)
+	)
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_test() {
+	mkdir "${BUILD_DIR}"/test || die
+	cp -pPR "${S}"/test/fixtures "${BUILD_DIR}"/test/fixtures || die
+	default
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	find "${D}" -name '*.la' -delete || die
+}