[gentoo-commits] gentoo-x86 commit in media-sound/rosegarden: ChangeLog rosegarden-1.7.2-r1.ebuild

[Diego Petteno (flameeyes)]

flameeyes    08/10/10 12:46:52

  Modified:             ChangeLog
  Added:                rosegarden-1.7.2-r1.ebuild
  Log:
  Update to EAPI=2 and USE deps.
  (Portage version: 2.2_rc12/cvs/Linux 2.6.26-gentoo-r1 x86_64)

Revision  Changes    Path
1.59                 media-sound/rosegarden/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/rosegarden/ChangeLog?rev=1.59&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/rosegarden/ChangeLog?rev=1.59&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/rosegarden/ChangeLog?r1=1.58&r2=1.59

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/rosegarden/ChangeLog,v
retrieving revision 1.58
retrieving revision 1.59
diff -u -r1.58 -r1.59
--- ChangeLog	20 Sep 2008 11:16:45 -0000	1.58
+++ ChangeLog	10 Oct 2008 12:46:52 -0000	1.59
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/rosegarden
 # Copyright 2000-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/rosegarden/ChangeLog,v 1.58 2008/09/20 11:16:45 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/rosegarden/ChangeLog,v 1.59 2008/10/10 12:46:52 flameeyes Exp $
+
+*rosegarden-1.7.2-r1 (10 Oct 2008)
+
+  10 Oct 2008; Diego Pettenò <flameeyes@g.o>
+  +rosegarden-1.7.2-r1.ebuild:
+  Update to EAPI=2 and USE deps.
 
 *rosegarden-1.7.2 (20 Sep 2008)
 



1.1                  media-sound/rosegarden/rosegarden-1.7.2-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/rosegarden/rosegarden-1.7.2-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/rosegarden/rosegarden-1.7.2-r1.ebuild?rev=1.1&content-type=text/plain

Index: rosegarden-1.7.2-r1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/rosegarden/rosegarden-1.7.2-r1.ebuild,v 1.1 2008/10/10 12:46:52 flameeyes Exp $

EAPI=2

inherit eutils kde-functions cmake-utils

MY_PV="${PV/_rc*/}"
#MY_PV="${MY_PV/4./}"
MY_P="${PN}-${MY_PV}"
S="${WORKDIR}/${MY_P}"

DESCRIPTION="MIDI and audio sequencer and notation editor."
HOMEPAGE="http://www.rosegardenmusic.com/"
SRC_URI="mirror://sourceforge/rosegarden/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="alsa debug jack dssi lirc"

RDEPEND="
	alsa? ( >=media-libs/alsa-lib-1.0[midi]
		jack? ( >=media-sound/jack-audio-connection-kit-0.77 )
	)
	>=media-libs/ladspa-sdk-1.0
	>=media-libs/ladspa-cmt-1.14
	dssi? ( >=media-libs/dssi-0.4 )
	lirc? ( >=app-misc/lirc-0.7 )
	>=media-libs/liblrdf-0.3
	>=sci-libs/fftw-3.0.0
	>=media-libs/liblo-0.7"

DEPEND="${RDEPEND}
	>=dev-util/pkgconfig-0.15
	>=dev-util/cmake-2.4.2"

need-kde 3.5

pkg_setup() {
	if ! use alsa && use jack; then
		ewarn "If you want JACK support you also need to enable"
		ewarn "ALSA support, or the whole sound support will be"
		ewarn "disabled."
	fi
}

src_prepare() {
	epatch "${FILESDIR}/rosegarden-1.6.1-asneeded.patch" \
		"${FILESDIR}/rosegarden-1.6.1.desktop.diff"
}

src_configure() {
	tc-export CC CXX LD

	# cmake is stupid, very very stupid.
	sed -i -e 's:CMAKE_CXX_FLAGS_\(RELEASE\|RELWITHDEBINFO\|DEBUG\).*".*"):CMAKE_CXX_FLAGS_\1 "'"${CXXFLAGS}"'"):' \
		CMakeLists.txt || die "unable to sanitise CXXFLAGS"

	mycmakeargs="$(cmake-utils_use_want alsa SOUND)
		$(cmake-utils_use_want jack JACK)
		$(cmake-utils_use_want dssi DSSI)
		$(cmake-utils_use_want lirc LIRC)"
	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install
	dodoc AUTHORS README TRANSLATORS
}