[gentoo-commits] gentoo-x86 commit in app-arch/rpm: metadata.xml rpm-5.3.5.ebuild ChangeLog

[Tomas Chvatal (scarabeus)]

scarabeus    12/06/02 10:21:28

  Modified:             metadata.xml ChangeLog
  Added:                rpm-5.3.5.ebuild
  Log:
  Add skel for rpm-5.3.5. The ebuild is not finished, but can stand as base to start from.
  
  (Portage version: 2.2.0_alpha108/cvs/Linux x86_64)

Revision  Changes    Path
1.15                 app-arch/rpm/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/rpm/metadata.xml?rev=1.15&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/rpm/metadata.xml?rev=1.15&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/rpm/metadata.xml?r1=1.14&r2=1.15

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-arch/rpm/metadata.xml,v
retrieving revision 1.14
retrieving revision 1.15
diff -u -r1.14 -r1.15
--- metadata.xml	23 Sep 2011 21:14:07 -0000	1.14
+++ metadata.xml	2 Jun 2012 10:21:28 -0000	1.15
@@ -2,11 +2,18 @@
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
 <maintainer>
-  <email>sochotnicky@g.o</email>
-  <name>Stanislav Ochotnicky</name>
+	<email>sochotnicky@g.o</email>
+	<name>Stanislav Ochotnicky</name>
 </maintainer>
 <use>
-  <flag name='magic'>Add magic file support (<pkg>sys-apps/file</pkg>)</flag>
-  <flag name='webdav-neon'>Include support for <pkg>net-libs/neon</pkg></flag>
+	<flag name='augeas'>Add support for configuration files changing (<pkg>app-admin/augeas</pkg>)</flag>
+	<flag name='keyutils'>Enable for the keyring ccache using keyutils.</flag>
+	<flag name='magic'>Add magic file support (<pkg>sys-apps/file</pkg>)</flag>
+	<flag name='nss'>Build support for ssl/crypto handling using <pkg>dev-libs/nss</pkg></flag>
+	<flag name='openssl'>Build support for ssl/crypto handling using <pkg>dev-libs/openssl</pkg></flag>
+	<flag name='pkcs11'>Build token data management utilities based on OpenCryptoki's (<pkg>dev-libs/opencryptoki</pkg>) PKCS#11 implementation.</flag>
+	<flag name='uuid'>Enable server side UUID generation (via <pkg>dev-libs/ossp-uuid</pkg>)</flag>
+	<flag name='webdav-neon'>Include support for <pkg>net-libs/neon</pkg></flag>
+	<flag name='xar'>Build support for xar archives using <pkg>app-arch/xar</pkg></flag>
 </use>
 </pkgmetadata>



1.143                app-arch/rpm/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/rpm/ChangeLog?rev=1.143&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/rpm/ChangeLog?rev=1.143&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/rpm/ChangeLog?r1=1.142&r2=1.143

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-arch/rpm/ChangeLog,v
retrieving revision 1.142
retrieving revision 1.143
diff -u -r1.142 -r1.143
--- ChangeLog	1 Jun 2012 14:19:27 -0000	1.142
+++ ChangeLog	2 Jun 2012 10:21:28 -0000	1.143
@@ -1,6 +1,13 @@
 # ChangeLog for app-arch/rpm
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-arch/rpm/ChangeLog,v 1.142 2012/06/01 14:19:27 scarabeus Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-arch/rpm/ChangeLog,v 1.143 2012/06/02 10:21:28 scarabeus Exp $
+
+*rpm-5.3.5 (02 Jun 2012)
+
+  02 Jun 2012; Tomáš Chvátal <scarabeus@g.o> +files/remaining-5.3.5.txt,
+  +rpm-5.3.5.ebuild, metadata.xml:
+  Add skel for rpm-5.3.5. The ebuild is not finished, but can stand as base to
+  start from.
 
 *rpm-4.10.0 (01 Jun 2012)
 



1.1                  app-arch/rpm/rpm-5.3.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/rpm/rpm-5.3.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/rpm/rpm-5.3.5.ebuild?rev=1.1&content-type=text/plain

Index: rpm-5.3.5.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-arch/rpm/rpm-5.3.5.ebuild,v 1.1 2012/06/02 10:21:28 scarabeus Exp $

EAPI=4

PYTHON_DEPEND="2"

inherit eutils multilib python user versionator

DESCRIPTION="RPM Package Manager"
HOMEPAGE="http://rpm5.org/"
SRC_URI="http://rpm5.org/files/${PN}/${PN}-$(get_version_component_range 1-2)/${P}.tar.gz"

LICENSE="GPL-2 LGPL-2"
SLOT="0"
KEYWORDS=""
IUSE="acl augeas berkdb +bzip2 crypt debug expat gnutls keyutils lua lzma nls nss openssl pcre perl pkcs11 readline ruby selinux sqlite ssl tcl uuid webdav-neon xar xattr +zlib"

RDEPEND="
	dev-libs/beecrypt
	dev-libs/popt
	sys-apps/file
	acl? ( sys-apps/acl )
	augeas? ( app-admin/augeas )
	berkdb? ( sys-libs/db )
	bzip2? ( app-arch/bzip2 )
	crypt? ( dev-libs/libgcrypt )
	expat? ( dev-libs/expat )
	keyutils? ( sys-apps/keyutils )
	lua? ( dev-lang/lua )
	lzma? ( app-arch/xz-utils )
	pcre? ( dev-libs/libpcre )
	perl? ( dev-lang/perl )
	pkcs11? ( dev-libs/pakchois )
	readline? ( sys-libs/readline:0 )
	ruby? ( >=dev-lang/ruby-1.9 )
	selinux? (
		sys-libs/libselinux
		sys-libs/libsemanage
		sys-libs/libsepol
	)
	sqlite? ( dev-db/sqlite:3 )
	ssl? (
		nss? ( dev-libs/nss )
		openssl? ( dev-libs/openssl )
		gnutls? (
			dev-libs/libtasn1
			net-libs/gnutls
		)
	)
	tcl? ( dev-lang/tcl )
	uuid? ( dev-libs/ossp-uuid )
	webdav-neon? ( net-libs/neon )
	xar? ( app-arch/xar )
	xattr? ( sys-apps/attr )
	zlib? ( sys-libs/zlib )
"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	virtual/yacc
	nls? ( sys-devel/gettext )
"

REQUIRED_USE="
	ssl? (
		^^ (
			gnutls
			nss
			openssl
		)
	)
"

pkg_setup () {
	python_set_active_version 2
	python_pkg_setup
}

src_configure() {
	local myconf=""

	# default internal/external switches
	# crypto default is beecrypt, user can change this on runtime
	#   and we build beecrypt every time
	# tomcrypt is not in portage
	# cudf is not in portage
	# users usually do not want to use debug malloc
	myconf+="
		--with-usecrypto=beecrypt
		--with-beecrypt=external
		--with-file=external
		--with-popt=external
		--without-tomcrypt
		--without-cudf
		--without-dmalloc
	"

	# ssl handling
	# tasn1 is handled in most portage packages with gnutls, do the same
	if use ssl; then
		myconf+="
			$(use_with gnutls)
			$(use_with gnutls libtasn1)
			$(use_with nss)
			$(use_with openssl)
		"
	else
		myconf+="
			--without-gnutls
			--without-libtasn1
			--without-nss
			--without-openssl
		"
	fi

	# enable db if we use berkdb or sqlite
	if use berkdb || use sqlite; then
		myconf+="
			--with-dbsql=external
		"
	else
		myconf+="
			--without-dbsql
		"
	fi

	# for berkdb enable the options if possible
	if use berkdb; then
		myconf+="
			--with-db-largefile
			--with-db-rpc
		"
	fi

	# we need python by default anyway so always --with-python
	econf \
		--disable-rpath \
		--disable-dependency-tracking \
		--enable-build-pic \
		--enable-build-pie \
		--enable-largefile \
		--with-python \
		--without-pythonembed \
		--with-python-lib-dir="$(python_get_libdir)" \
		--with-python-inc-dir="$(python_get_includedir)" \
		$(use_enable nls) \
		$(use_enable debug build-debug) \
		$(use_with acl) \
		$(use_with augeas) \
		$(use_with berkdb db) \
		$(use_with bzip2) \
		$(use_with crypt gcrypt) \
		$(use_with expat) \
		$(use_with keyutils) \
		$(use_with lua lua external) \
		$(use_with lzma xz external) \
		$(use_with pcre pcre external) \
		$(use_with perl) \
		$(use_with pkcs11 pakchois) \
		$(use_with readline) \
		$(use_with selinux) \
		$(use_with selinux semanage) \
		$(use_with selinux sepol) \
		$(use_with sqlite) \
		$(use_with tcl) \
		$(use_with uuid) \
		$(use_with webdav-neon neon external) \
		$(use_with xar xar external) \
		$(use_with xattr attr) \
		$(use_with zlib) \
		${myconf}

	# TODO: see files/remaining-5.3.5.txt
	ewarn "This package is far from complete"
	ewarn "If you want to test it please see \"${FILESDIR}/remaining-5.3.5.txt\""
	ewarn "and implement missing features."
	ewarn "Do NOT report bugs without providing patches!"
}

src_install() {
	emake DESTDIR="${D}" INSTALLDIRS=vendor install || die "emake install failed"
	dodoc CHANGES CREDITS NEWS README TODO
}

pkg_preinst() {
	enewgroup rpm 37
	enewuser rpm 37 /bin/sh /var/lib/rpm rpm
}

pkg_postinst() {
	chown -R rpm:rpm "${ROOT}"/usr/$(get_libdir)/rpm
	chown -R rpm:rpm "${ROOT}"/var/lib/rpm
	chown rpm:rpm "${ROOT}"/usr/bin/rpm{,2cpio,build,constant}
	if [[ ${ROOT} == "/" ]] ; then
		if [[ -f ${ROOT}/var/lib/rpm/Packages ]] ; then
			einfo "RPM database found... Rebuilding database (may take a while)..."
			"${ROOT}"/usr/bin/rpm --rebuilddb --root="${ROOT}"
		else
			einfo "No RPM database found... Creating database..."
			"${ROOT}"/usr/bin/rpm --initdb --root="${ROOT}"
		fi
	fi
	chown rpm:rpm "${ROOT}"/var/lib/rpm/*

	python_mod_optimize rpm
}

pkg_postrm() {
	python_mod_cleanup rpm
}