[gentoo-commits] gentoo-x86 commit in dev-util/weka: ChangeLog weka-3.5.7.ebuild

[Petteri Raty (betelgeuse)]

betelgeuse    08/02/07 19:34:05

  Modified:             ChangeLog
  Added:                weka-3.5.7.ebuild
  Log:
  Version bump. Fixes bug #209289.
  (Portage version: 2.1.4)

Revision  Changes    Path
1.25                 dev-util/weka/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/weka/ChangeLog?rev=1.25&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/weka/ChangeLog?rev=1.25&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/weka/ChangeLog?r1=1.24&r2=1.25

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/weka/ChangeLog,v
retrieving revision 1.24
retrieving revision 1.25
diff -u -r1.24 -r1.25
--- ChangeLog	7 Dec 2007 19:03:17 -0000	1.24
+++ ChangeLog	7 Feb 2008 19:34:04 -0000	1.25
@@ -1,6 +1,11 @@
 # ChangeLog for dev-util/weka
-# Copyright 2000-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/weka/ChangeLog,v 1.24 2007/12/07 19:03:17 betelgeuse Exp $
+# Copyright 2000-2008 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/weka/ChangeLog,v 1.25 2008/02/07 19:34:04 betelgeuse Exp $
+
+*weka-3.5.7 (07 Feb 2008)
+
+  07 Feb 2008; Petteri Räty <betelgeuse@g.o> +weka-3.5.7.ebuild:
+  Version bump. Fixes bug #209289.
 
 *weka-3.5.6 (07 Dec 2007)
 



1.1                  dev-util/weka/weka-3.5.7.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/weka/weka-3.5.7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/weka/weka-3.5.7.ebuild?rev=1.1&content-type=text/plain

Index: weka-3.5.7.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/weka/weka-3.5.7.ebuild,v 1.1 2008/02/07 19:34:04 betelgeuse Exp $

JAVA_PKG_IUSE="doc source"

inherit eutils java-pkg-2 versionator

MY_P="${PN}-$(replace_all_version_separators '-')"
DESCRIPTION="A Java data mining package"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.zip"
HOMEPAGE="http://www.cs.waikato.ac.nz/ml/weka/"
SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~ppc ~x86"
DEPEND=">=virtual/jdk-1.5
	app-arch/unzip"
RDEPEND=">=virtual/jre-1.5"
IUSE=""

S="${WORKDIR}/${MY_P}"

src_unpack() {
	unpack ${A}
	cd "${S}"

	unzip -qq "${PN}-src.jar" -d src || die "Failed to unpack the source"

	rm -v *.jar || die
}

src_compile() {
	mkdir build dist
	echo "Compiling sources"
	# We need to set the maximum heap size to 128m to avoid
	#	OutOfMemoryErrors
	find src/ -name "*.java" | xargs javac -J-Xmx128m -d build \
		$(java-pkg_javac-args) -sourcepath src/ -nowarn \
		|| die "Failed to compile sources"

	echo "Copying resources"
	cd src
	find . -type f -not -name '*.java' -and -not -name "*.MF" -print | \
	while read file; do
		mkdir -p $(dirname "../build/${file}")
		cp "${file}" "../build/${file}" || die "Failed to extract resources"
	done
	cd ..

	echo "Creating JAR"
	jar cf dist/${PN}.jar -C build . || die "Failed to create JAR archive"

	if use doc ; then
		mkdir -p dist/doc
		echo "Generating javadocs"
		find src/ -name "*.java" | xargs javadoc -d dist/doc/ \
		-J-Xmx128m -quiet || die "Failed to generate javadoc"
	fi
}

src_install() {
	java-pkg_dojar dist/*.jar

	java-pkg_dolauncher weka --main "${PN}.gui.GUIChooser"
	# Really need a virtual to list all available drivers and pull the ones
	# instaled
	java-pkg_register-optional-dependency hsqldb,jdbc-mysql,mckoi-1

	use source && java-pkg_dosrc src/weka

	dodoc README || die
	use doc && java-pkg_dojavadoc dist/doc/

	dodir /usr/share/${PN}/data/
	insinto /usr/share/${PN}/data/
	doins data/*
}



-- 
gentoo-commits@l.g.o mailing list