[gentoo-commits] repo/gentoo:master commit in: dev-python/sympy/

[Michał Górny]

commit:     3e6dee20d012ba79c2396a0cbc06068fd8d2cb55
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Apr 10 06:48:31 2021 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Apr 10 12:02:58 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3e6dee20

dev-python/sympy: Bump to 1.8

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/sympy/Manifest         |  1 +
 dev-python/sympy/sympy-1.8.ebuild | 62 +++++++++++++++++++++++++++++++++++++++
 2 files changed, 63 insertions(+)

diff --git a/dev-python/sympy/Manifest b/dev-python/sympy/Manifest
index 01265920025..cecb7a28ce2 100644
--- a/dev-python/sympy/Manifest
+++ b/dev-python/sympy/Manifest
@@ -1 +1,2 @@
 DIST sympy-1.7.1.tar.gz 6974183 BLAKE2B 4bd8c9d60c46b05a7fc6c622667858fe17d25798756dbe967ce19abc8047263fe540f332e39418e877852c0565270377bd01fea7e65aa35ed4e03079bc130805 SHA512 eb9387bb9c632203af650279f896427556725b7496c00d8dfe97b7476beedbbee5714659f7fb44b4fa986c9567cdcaefcc19401d63e1ca0e9a6c7317855440ea
+DIST sympy-1.8.tar.gz 7167842 BLAKE2B 878c6daf0584c9da54f82b9c68c62715792db428ab4ebfb355f0368c52edb254947d1ce1919e651279b767295ecb00a76b8cbbaa1fbe9c97915221c7403c3ded SHA512 61141e1d0a6105e725fb415edbdf981b3aa95debcfe73f9da5ca36afc7a70e91b5c28ed45454054c1b9a8d45e42bfe724e5b20da717746c301fd095da17f4db7

diff --git a/dev-python/sympy/sympy-1.8.ebuild b/dev-python/sympy/sympy-1.8.ebuild
new file mode 100644
index 00000000000..727e2d95fbc
--- /dev/null
+++ b/dev-python/sympy/sympy-1.8.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="Computer Algebra System in pure Python"
+HOMEPAGE="https://www.sympy.org/"
+SRC_URI="https://github.com/sympy/sympy/archive/${P}.tar.gz"
+S="${WORKDIR}/${PN}-${P}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+IUSE="examples imaging ipython latex mathml opengl pdf png pyglet symengine test texmacs theano"
+
+RDEPEND="
+	dev-python/mpmath[${PYTHON_USEDEP}]
+	dev-python/pexpect[${PYTHON_USEDEP}]
+	imaging? ( dev-python/pillow[${PYTHON_USEDEP}] )
+	ipython? ( dev-python/ipython[${PYTHON_USEDEP}] )
+	latex? (
+		virtual/latex-base
+		dev-texlive/texlive-fontsextra
+		png? ( app-text/dvipng )
+		pdf? ( app-text/ghostscript-gpl )
+	)
+	mathml? ( dev-libs/libxml2:2[${PYTHON_USEDEP}] )
+	opengl? ( dev-python/pyopengl[${PYTHON_USEDEP}] )
+	pyglet? ( dev-python/pyglet[${PYTHON_USEDEP}] )
+	symengine? ( dev-python/symengine[${PYTHON_USEDEP}] )
+	texmacs? ( app-office/texmacs )
+	theano? ( dev-python/aesara[${PYTHON_USEDEP}] )
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	virtx esetup.py test
+}
+
+python_install_all() {
+	local DOCS=( AUTHORS README.md )
+
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+
+	distutils-r1_python_install_all
+
+	if use texmacs; then
+		exeinto /usr/libexec/TeXmacs/bin/
+		doexe data/TeXmacs/bin/tm_sympy
+		insinto /usr/share/TeXmacs/plugins/sympy/
+		doins -r data/TeXmacs/progs
+	fi
+}