[gentoo-commits] repo/gentoo:master commit in: sys-kernel/gentoo-kernel-bin/

[Sam James]

commit:     57e7d198c6f42c64c6f37cadcf8f899d5293cd25
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sat Sep 18 04:50:42 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sat Sep 18 04:50:42 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=57e7d198

sys-kernel/gentoo-kernel-bin: add 5.10.66-r1 for arm64

Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-kernel/gentoo-kernel-bin/Manifest              |   1 +
 .../gentoo-kernel-bin-5.10.66-r1.ebuild            | 113 +++++++++++++++++++++
 2 files changed, 114 insertions(+)

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index df4f4f0076c..12d5fc07e04 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -56,6 +56,7 @@ DIST gentoo-kernel-5.10.64-1.x86.xpak 57233627 BLAKE2B 0c7253729bd26e4e47821b5ed
 DIST gentoo-kernel-5.10.65-1.amd64.xpak 65506456 BLAKE2B 4c65d32ee668930a5d856d5cfaf17e3686e0efa384ff34e41d5094434733cd2ee18e972f5497a6858b06aa3db2bb83dd709a7b7a7142caec23034c2eeadf6dbe SHA512 b365637f005724d94aed61d3340ce0aee592068be9f1d429208d82afc3076201f2cb7bb29e6dc99a6c3ba657c395e24ab527d8648b773b806bf59afb441fbfe7
 DIST gentoo-kernel-5.10.65-1.x86.xpak 57233550 BLAKE2B 3ed15cc6cd28dea01806b954c0378ddc83f79b010109ac1255eb3e439064a04d57974b67e673cc587567484eaad4163e5297a462214665d194a64757610d0586 SHA512 a513907eaee118a3ce0170c75fc8aa76c98c0f8301a257f4f4c967053178b3dc053de7187d0c4dc0b6be4ce1099d2a80d8bc6badc429d96207f7bc7300931824
 DIST gentoo-kernel-5.10.66-1.amd64.xpak 65538037 BLAKE2B 87488caaae9aeaba831f546dc6649b73024cec5f023fbe77e2ec2db00185f9e6b42b9fce3e246e4aa6af18df88dd2fca135092a87a8a3c0b8351580a00c8126c SHA512 0941da0d22529348792181dbd7a12f5e7cb4b6b92160f72aedeca1f0db1f4fb0bf32f7e8336d4b2f77b895299e1475860858edaf513a24371684699446e4dc55
+DIST gentoo-kernel-5.10.66-1.arm64.xpak 61278978 BLAKE2B 74962fb0328ae347c15a0c20b8081b9c2ea74acbe7651ec3a213c08531b25755d0341b1235bd5010ed8c2810767599010021361af4b8d18a203411a30bfbf049 SHA512 898bbac8b9314030a938f30b3fc0ec85c162be61a467b27cf2663fb7baa6190bd15aaf7a86e4b56d00edef16545c79b880ceff0156407dda0d6cde08ab1764ce
 DIST gentoo-kernel-5.10.66-1.x86.xpak 57245309 BLAKE2B 2a67657d2797243fc22bbe38a25db77052d4d2342e53907a007d383c7ebf45d150cebaf5ab3b542f3533b17670d8c7740c926ac8636b7a982e875f36e1a8eb45 SHA512 e27b532e9d0716e3afab61f487575d004f58abe40a29c5e82260df53fd853e6dd58fb6ddc73455a2a08157a2fba3e9fb34d58558eed5df62c1eb0ef525743a08
 DIST gentoo-kernel-5.12.19-1.amd64.xpak 66346655 BLAKE2B a03cbcdcd1a90d48d7e11e988d03efa43980f4d5d8af4b74e4c81f195faa01803af45fb38f7dc1f5af7e9b5338a53bc6f34837c37f7e853c088ec6c1dc084e44 SHA512 3d7f78c488ecee2532f8a8ad61e3aa0f5e238e4cd520d29288715a3dc5c488670d7378f3dc5bc110252dff10108dfbda27a54722c6b044151999428d002b34e1
 DIST gentoo-kernel-5.12.19-1.arm64.xpak 60043529 BLAKE2B 8746081847a39e1847b8e9f35fcd68565370b116d6418edf803c4cdca9d750ac8ada58c4a7fd377480a1c75b3c805864d419c02ee21675bc77ac195731385a18 SHA512 d1a8a9210a1ab3d3c1894be1fe524e64b859b0a02763feacfed1a24655540ade6c28af751b23e924fcc04fb9abd56e84c43d634ad80bbb4d5de79ed533b5ea50

diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.66-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.66-r1.ebuild
new file mode 100644
index 00000000000..9f8ae493e21
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.66-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 6 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}