[gentoo-commits] gentoo-x86 commit in mail-client/sylpheed: metadata.xml ChangeLog sylpheed-3.1.1.ebuild sylpheed-3.1.0.ebuild

[Akinori Hattori (hattya)]

hattya      11/05/07 14:51:33

  Modified:             metadata.xml ChangeLog
  Added:                sylpheed-3.1.1.ebuild
  Removed:              sylpheed-3.1.0.ebuild
  Log:
  new upstream release. fixes bug #354963.
  
  (Portage version: 2.1.9.42/cvs/Linux i686)

Revision  Changes    Path
1.3                  mail-client/sylpheed/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/sylpheed/metadata.xml?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/sylpheed/metadata.xml?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/sylpheed/metadata.xml?r1=1.2&r2=1.3

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/mail-client/sylpheed/metadata.xml,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- metadata.xml	19 Aug 2004 08:40:11 -0000	1.2
+++ metadata.xml	7 May 2011 14:51:33 -0000	1.3
@@ -5,4 +5,7 @@
   <maintainer>
     <email>hattya@g.o</email>
   </maintainer>
+  <use>
+    <flag name="oniguruma">Use <pkg>dev-libs/oniguruma</pkg> for regular expression</flag>
+  </use>
 </pkgmetadata>



1.289                mail-client/sylpheed/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/sylpheed/ChangeLog?rev=1.289&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/sylpheed/ChangeLog?rev=1.289&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/sylpheed/ChangeLog?r1=1.288&r2=1.289

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/mail-client/sylpheed/ChangeLog,v
retrieving revision 1.288
retrieving revision 1.289
diff -u -r1.288 -r1.289
--- ChangeLog	23 Mar 2011 20:44:48 -0000	1.288
+++ ChangeLog	7 May 2011 14:51:33 -0000	1.289
@@ -1,6 +1,12 @@
 # ChangeLog for mail-client/sylpheed
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mail-client/sylpheed/ChangeLog,v 1.288 2011/03/23 20:44:48 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-client/sylpheed/ChangeLog,v 1.289 2011/05/07 14:51:33 hattya Exp $
+
+*sylpheed-3.1.1 (07 May 2011)
+
+  07 May 2011; Akinori Hattori <hattya@g.o> -sylpheed-3.1.0.ebuild,
+  +sylpheed-3.1.1.ebuild, metadata.xml:
+  new upstream release. fixes bug #354963.
 
   23 Mar 2011; Tim Harder <radhermit@g.o> sylpheed-2.6.0.ebuild,
   sylpheed-3.0.2.ebuild, sylpheed-3.0.3.ebuild, sylpheed-3.1.0.ebuild:



1.1                  mail-client/sylpheed/sylpheed-3.1.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/sylpheed/sylpheed-3.1.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/sylpheed/sylpheed-3.1.1.ebuild?rev=1.1&content-type=text/plain

Index: sylpheed-3.1.1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/mail-client/sylpheed/sylpheed-3.1.1.ebuild,v 1.1 2011/05/07 14:51:33 hattya Exp $

EAPI="3"

inherit autotools eutils

IUSE="crypt ipv6 ldap nls oniguruma pda spell ssl xface"

DESCRIPTION="A lightweight email client and newsreader"
HOMEPAGE="http://sylpheed.sraoss.jp/"
SRC_URI="http://sylpheed.sraoss.jp/${PN}/v${PV%.*}/${P}.tar.bz2"

LICENSE="GPL-2 LGPL-2.1"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
SLOT="0"

COMMON_DEPEND=">=x11-libs/gtk+-2.4:2
	nls? ( >=sys-devel/gettext-0.12.1 )
	crypt? ( >=app-crypt/gpgme-1 )
	ldap? ( net-nds/openldap )
	oniguruma? ( dev-libs/oniguruma )
	pda? ( app-pda/jpilot )
	spell? ( app-text/gtkspell )
	ssl? ( dev-libs/openssl )"
DEPEND="${COMMON_DEPEND}
	dev-util/pkgconfig
	xface? ( >=media-libs/compface-1.4 )"
RDEPEND="${COMMON_DEPEND}
	app-misc/mime-types
	net-misc/curl"

AT_M4DIR="ac"

src_prepare() {

	use crypt || cp ac/missing/gpgme.m4 ac

	eautoreconf

}

src_configure() {

	local htmldir=/usr/share/doc/${PF}/html

	econf \
		$(use_enable crypt gpgme) \
		$(use_enable ipv6) \
		$(use_enable ldap) \
		$(use_enable oniguruma) \
		$(use_enable pda jpilot) \
		$(use_enable spell gtkspell) \
		$(use_enable ssl) \
		$(use_enable xface compface) \
		--with-manualdir=${htmldir}/manual \
		--with-faqdir=${htmldir}/faq \
		--disable-updatecheck \
		|| die

}

src_install() {

	emake DESTDIR="${D}" install || die

	dodoc AUTHORS ChangeLog* NEWS* README* TODO*
	doicon *.png
	domenu *.desktop

}