[gentoo-commits] proj/kde:master commit in: kde-frameworks/purpose/

[Andreas Sturmlechner]

commit:     ddfaa6ae9da4eae39db73bc8477ea7196681ba42
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sat Aug  1 20:36:44 2020 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sat Aug  1 20:36:44 2020 +0000
URL:        https://gitweb.gentoo.org/proj/kde.git/commit/?id=ddfaa6ae

kde-frameworks/purpose: 5.73.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 kde-frameworks/purpose/purpose-5.73.0.ebuild | 58 ++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)

diff --git a/kde-frameworks/purpose/purpose-5.73.0.ebuild b/kde-frameworks/purpose/purpose-5.73.0.ebuild
new file mode 100644
index 0000000000..53c1c4293f
--- /dev/null
+++ b/kde-frameworks/purpose/purpose-5.73.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_QTHELP="false"
+ECM_TEST="forceoptional"
+PVCUT=$(ver_cut 1-2)
+QTMIN=5.14.2
+inherit ecm kde.org
+
+DESCRIPTION="Library for providing abstractions to get the developer's purposes fulfilled"
+LICENSE="LGPL-2.1+"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="+dolphin +kaccounts"
+
+DEPEND="
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	=kde-frameworks/kcoreaddons-${PVCUT}*:5
+	=kde-frameworks/ki18n-${PVCUT}*:5
+	=kde-frameworks/kio-${PVCUT}*:5
+	=kde-frameworks/kirigami-${PVCUT}*:5
+	dolphin? ( =kde-frameworks/knotifications-${PVCUT}*:5 )
+	kaccounts? (
+		>=kde-apps/kaccounts-integration-19.04.3:5
+		net-libs/accounts-qt
+	)
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtquickcontrols-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=kde-frameworks/kdeclarative-${PVCUT}:5
+	kaccounts? ( net-libs/accounts-qml )
+"
+
+# requires running environment
+RESTRICT+=" test"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package dolphin KF5Notifications)
+		$(cmake_use_find_package kaccounts KAccounts)
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst(){
+	ecm_pkg_postinst
+
+	if ! has_version "kde-misc/kdeconnect[app]" ; then
+		elog "Optional runtime dependency:"
+		elog "kde-misc/kdeconnect[app] (send through KDE Connect)"
+	fi
+}