[gentoo-commits] gentoo-x86 commit in net-irc/irssi: ChangeLog irssi-0.8.16.ebuild

[Sven Wegener (swegener)]

swegener    14/05/30 03:52:47

  Modified:             ChangeLog
  Added:                irssi-0.8.16.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 0x64D4CF24)

Revision  Changes    Path
1.189                net-irc/irssi/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/irssi/ChangeLog?rev=1.189&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/irssi/ChangeLog?rev=1.189&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/irssi/ChangeLog?r1=1.188&r2=1.189

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-irc/irssi/ChangeLog,v
retrieving revision 1.188
retrieving revision 1.189
diff -u -r1.188 -r1.189
--- ChangeLog	10 Mar 2014 22:22:19 -0000	1.188
+++ ChangeLog	30 May 2014 03:52:47 -0000	1.189
@@ -1,6 +1,11 @@
 # ChangeLog for net-irc/irssi
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-irc/irssi/ChangeLog,v 1.188 2014/03/10 22:22:19 swegener Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-irc/irssi/ChangeLog,v 1.189 2014/05/30 03:52:47 swegener Exp $
+
+*irssi-0.8.16 (30 May 2014)
+
+  30 May 2014; Sven Wegener <swegener@g.o> +irssi-0.8.16.ebuild:
+  Version bump.
 
   10 Mar 2014; Sven Wegener <swegener@g.o> irssi-0.8.16_rc1.ebuild,
   irssi-9999.ebuild, metadata.xml:



1.1                  net-irc/irssi/irssi-0.8.16.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/irssi/irssi-0.8.16.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/irssi/irssi-0.8.16.ebuild?rev=1.1&content-type=text/plain

Index: irssi-0.8.16.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-irc/irssi/irssi-0.8.16.ebuild,v 1.1 2014/05/30 03:52:47 swegener Exp $

EAPI=5

inherit autotools-utils eutils flag-o-matic perl-module toolchain-funcs

# Keep for _rc compability
MY_P="${P/_/-}"

DESCRIPTION="A modular textUI IRC client with IPv6 support"
HOMEPAGE="http://irssi.org/"
SRC_URI="http://irssi.org/files/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE="ipv6 +perl ssl socks5 +proxy"

RDEPEND="sys-libs/ncurses
	>=dev-libs/glib-2.6.0
	ssl? ( dev-libs/openssl )
	perl? ( dev-lang/perl )
	socks5? ( >=net-proxy/dante-1.1.18 )"
DEPEND="${RDEPEND}
	virtual/pkgconfig"
RDEPEND="${RDEPEND}
	perl? ( !net-im/silc-client )"

S=${WORKDIR}/${MY_P}

src_prepare() {
	epatch "${FILESDIR}/${PN}-0.8.15-tinfo.patch"
	sed -e "s@pkg-config@$(tc-getPKG_CONFIG)@g" \
		-i "${S}/curses.m4" \
		|| die "Could not configure pkg-config in curses.m4"
	AUTOTOOLS_AUTORECONF=1
	autotools-utils_src_prepare
}

src_configure() {
	econf \
		--with-ncurses="${EPREFIX}"/usr \
		--with-perl-lib=vendor \
		--enable-static \
		$(use_with proxy) \
		$(use_with perl) \
		$(use_with socks5 socks) \
		$(use_enable ssl) \
		$(use_enable ipv6)
}

src_install() {
	emake \
		DESTDIR="${D}" \
		docdir="${EPREFIX}"/usr/share/doc/${PF} \
		install

	use perl && fixlocalpod

	prune_libtool_files --modules

	dodoc AUTHORS ChangeLog README TODO NEWS
}