[gentoo-commits] repo/gentoo:master commit in: dev-vcs/gitolite-gentoo/

[Conrad Kostecki]

commit:     646a3fcc850dcbf34cf11198f1445d1aaf2b43ae
Author:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
AuthorDate: Fri Jul  9 23:25:06 2021 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Fri Jul  9 23:26:06 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=646a3fcc

dev-vcs/gitolite-gentoo: migrate to GLEP 81

Closes: https://bugs.gentoo.org/589468
Closes: https://bugs.gentoo.org/781566
Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 .../gitolite-gentoo-2.3.1-r2.ebuild                |  69 ++++++++++++++
 .../gitolite-gentoo-3.6.6.1-r2.ebuild              | 106 +++++++++++++++++++++
 2 files changed, 175 insertions(+)

diff --git a/dev-vcs/gitolite-gentoo/gitolite-gentoo-2.3.1-r2.ebuild b/dev-vcs/gitolite-gentoo/gitolite-gentoo-2.3.1-r2.ebuild
new file mode 100644
index 00000000000..d86d7ba5294
--- /dev/null
+++ b/dev-vcs/gitolite-gentoo/gitolite-gentoo-2.3.1-r2.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit perl-module
+
+DESCRIPTION="Highly flexible server for git directory version tracker, Gentoo fork"
+HOMEPAGE="https://cgit.gentoo.org/proj/gitolite-gentoo.git"
+SRC_URI="mirror://gentoo/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="contrib vim-syntax"
+
+DEPEND="
+	dev-lang/perl
+	>=dev-vcs/git-1.6.6
+	virtual/perl-File-Path
+	virtual/perl-File-Temp
+"
+RDEPEND="
+	${DEPEND}
+	acct-group/git
+	acct-user/git[gitolite]
+	!dev-vcs/gitolite
+	dev-perl/Net-SSH-AuthorizedKeysFile
+	vim-syntax? ( app-vim/gitolite-syntax )"
+
+src_prepare() {
+	rm Makefile doc/COPYING || die
+	rm -rf contrib/{gitweb,vim} || die
+
+	echo "${PF}-gentoo" > conf/VERSION
+}
+
+src_install() {
+	local gl_bin="${D}/usr/bin"
+	gl_bin=${gl_bin/\/\//\/}
+
+	dodir /usr/share/gitolite/{conf,hooks} /usr/bin
+
+	export PATH="${gl_bin}:${PATH}"
+	./src/gl-system-install ${gl_bin} \
+		"${D}"/usr/share/gitolite/conf "${D}"/usr/share/gitolite/hooks || die
+	sed -e "s:${D}::g" "${D}/usr/bin/gl-setup" \
+		-i "${D}/usr/share/gitolite/conf/example.gitolite.rc" || die
+
+	rm "${D}"/usr/bin/*.pm
+	insinto "${VENDOR_LIB}"
+	doins src/*.pm
+
+	dodoc README.mkd doc/*
+
+	use contrib && dodoc -r contrib
+}
+
+pkg_postinst() {
+	# bug 352291
+	ewarn
+	elog "Please make sure that your 'git' user has the correct homedir (/var/lib/gitolite)."
+	elog "Especially if you're migrating from gitosis."
+	ewarn
+	ewarn
+	elog "If you use the umask feature and upgrade from <=gitolite-gentoo-1.5.9.1"
+	elog "then please check the permissions of all repositories using the umask feature"
+	ewarn
+}

diff --git a/dev-vcs/gitolite-gentoo/gitolite-gentoo-3.6.6.1-r2.ebuild b/dev-vcs/gitolite-gentoo/gitolite-gentoo-3.6.6.1-r2.ebuild
new file mode 100644
index 00000000000..69ef11cfb53
--- /dev/null
+++ b/dev-vcs/gitolite-gentoo/gitolite-gentoo-3.6.6.1-r2.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+[[ ${PV} == *9999 ]] && SCM="git-2"
+EGIT_REPO_URI="git://git.gentoo.org/proj/gitolite-gentoo"
+EGIT_MASTER=master
+
+inherit perl-module ${SCM}
+
+DESCRIPTION="Highly flexible server for git directory version tracker, Gentoo fork"
+HOMEPAGE="https://cgit.gentoo.org/proj/gitolite-gentoo.git"
+if [[ ${PV} != *9999 ]]; then
+	SRC_URI="mirror://gentoo/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~x86"
+else
+	SRC_URI=""
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="selinux tools vim-syntax"
+
+DEPEND="
+	dev-lang/perl
+	>=dev-vcs/git-1.6.6
+	virtual/perl-File-Path
+	virtual/perl-File-Temp
+"
+RDEPEND="
+	${DEPEND}
+	acct-group/git
+	acct-user/git[gitolite]
+	>=dev-perl/Net-SSH-AuthorizedKeysFile-0.17
+	dev-perl/JSON
+	!dev-vcs/gitolite
+	vim-syntax? ( app-vim/gitolite-syntax )
+	selinux? ( sec-policy/selinux-gitosis )
+"
+
+src_prepare() {
+	default
+	echo "${PF}-gentoo" > src/VERSION || die
+}
+
+src_install() {
+	local uexec=/usr/libexec/${PN}
+
+	rm -rf src/lib/Gitolite/Test{,.pm}
+	insinto $VENDOR_LIB
+	doins -r src/lib/Gitolite
+
+	dodoc README.markdown CHANGELOG
+	# These are meant by upstream as examples, you are strongly recommended to
+	# customize them for your needs.
+	dodoc contrib/utils/ipa_groups.pl contrib/utils/ldap_groups.sh
+
+	insopts -m0755
+	insinto $uexec
+	doins -r src/{commands,syntactic-sugar,triggers,VREF}/
+	doins -r contrib/{commands,triggers,hooks}
+
+	insopts -m0644
+	doins src/VERSION
+
+	exeinto $uexec
+	doexe src/gitolite{,-shell}
+
+	dodir /usr/bin
+	for bin in gitolite{,-shell}; do
+		dosym /usr/libexec/${PN}/${bin} /usr/bin/${bin}
+	done
+
+	if use tools; then
+		dobin check-g2-compat convert-gitosis-conf
+		dobin contrib/utils/rc-format-v3.4
+	fi
+
+	fperms 0644 ${uexec}/VREF/MERGE-CHECK # It's meant as example only
+}
+
+pkg_postinst() {
+	local old_ver
+	for old_ver in ${REPLACING_VERSIONS}; do
+		if ver_test ${old_ver} -lt "3" ; then
+			ewarn
+			elog "***NOTE*** This is a major upgrade and will likely break your existing gitolite-2.x setup!"
+			elog "Please read http://gitolite.com/gitolite/migr.html first!"
+			ewarn
+			elog "***NOTE*** If you're using the \"umask\" feature of ${PN}-2.x:"
+			elog "You'll have to replace each \"umask = ...\" option by \"option umask = ...\""
+			elog "And you'll also have to enable the \"RepoUmask\" module in your .gitolite.rc"
+			ewarn
+		fi
+	done
+
+	# bug 352291
+	gitolite_home=$(awk -F: '$1 == "git" { print $6 }' /etc/passwd)
+	if [ -n "${gitolite_home}" -a "${gitolite_home}" != "/var/lib/gitolite" ]; then
+		ewarn
+		elog "Please make sure that your 'git' user has the correct homedir (/var/lib/gitolite)."
+		elog "Especially if you're migrating from gitosis."
+		ewarn
+	fi
+}