[gentoo-commits] gentoo-x86 commit in dev-python/botocore: botocore-1.1.3.ebuild metadata.xml ChangeLog

[Alex Brandt (alunduil)]

alunduil    15/07/29 18:51:40

  Added:                botocore-1.1.3.ebuild metadata.xml ChangeLog
  Log:
  add version 1.1.3
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 11A8217C!)

Revision  Changes    Path
1.1                  dev-python/botocore/botocore-1.1.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/botocore/botocore-1.1.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/botocore/botocore-1.1.3.ebuild?rev=1.1&content-type=text/plain

Index: botocore-1.1.3.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/botocore/botocore-1.1.3.ebuild,v 1.1 2015/07/29 18:51:40 alunduil Exp $

EAPI=5
PYTHON_COMPAT=( python2_7 python3_3 python3_4 )

inherit distutils-r1 vcs-snapshot

DESCRIPTION="Low-level, data-driven core of boto 3."
HOMEPAGE="https://github.com/boto/botocore"
SRC_URI="https://github.com/boto/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64"
IUSE="doc test"

CDEPEND="
	>=dev-python/docutils-0.10[${PYTHON_USEDEP}]
	~dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
	>=dev-python/python-dateutil-2.1[${PYTHON_USEDEP}]
	<dev-python/python-dateutil-3.0.0[${PYTHON_USEDEP}]
"
DEPEND="
	dev-python/setuptools[${PYTHON_USEDEP}]
	doc? (
		>=dev-python/guzzle_sphinx_theme-0.7.10[${PYTHON_USEDEP}]
		<dev-python/guzzle_sphinx_theme-0.8[${PYTHON_USEDEP}]
		>=dev-python/sphinx-1.1.3[${PYTHON_USEDEP}]
		<dev-python/sphinx-1.3[${PYTHON_USEDEP}]
	)
	test? (
		${CDEPEND}
		dev-python/mock[${PYTHON_USEDEP}]
		dev-python/nose[${PYTHON_USEDEP}]
	)
"
RDEPEND="${CDEPEND}"

python_compile_all() {
	use doc && emake -C docs html
}

python_test() {
	nosetests tests/unit || die "tests failed under ${EPYTHON}"
}

python_install_all() {
	use doc && local HTML_DOCS=( docs/build/html/. )

	distutils-r1_python_install_all
}



1.1                  dev-python/botocore/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/botocore/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/botocore/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
	<maintainer>
		<email>alunduil@g.o</email>
		<name>Alex Brandt</name>
	</maintainer>
	<longdescription lang="en">
	</longdescription>
</pkgmetadata>



1.1                  dev-python/botocore/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/botocore/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/botocore/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for dev-python/botocore
# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/botocore/ChangeLog,v 1.1 2015/07/29 18:51:40 alunduil Exp $

*botocore-1.1.3 (29 Jul 2015)

  29 Jul 2015; Alex Brandt <alunduil@g.o> +botocore-1.1.3.ebuild,
  +metadata.xml:
  add version 1.1.3