[gentoo-commits] gentoo-x86 commit in net-analyzer/wireshark: wireshark-1.99.0.1975.ebuild metadata.xml ChangeLog

[Jeroen Roovers (jer)]

jer         14/10/02 12:17:00

  Modified:             metadata.xml ChangeLog
  Added:                wireshark-1.99.0.1975.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.14_rc1/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.25                 net-analyzer/wireshark/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/wireshark/metadata.xml?rev=1.25&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/wireshark/metadata.xml?rev=1.25&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/wireshark/metadata.xml?r1=1.24&r2=1.25

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/wireshark/metadata.xml,v
retrieving revision 1.24
retrieving revision 1.25
diff -u -r1.24 -r1.25
--- metadata.xml	27 Sep 2014 10:58:51 -0000	1.24
+++ metadata.xml	2 Oct 2014 12:17:00 -0000	1.25
@@ -33,5 +33,6 @@
 <flag name='pcap'>Use <pkg>net-libs/libpcap</pkg> for network packet capturing (build dumpcap, rawshark)</flag>
 <flag name='qt4'>Build the wireshark executable with an experimental Qt UI instead of GTK+.</flag>
 <flag name='smi'>Use <pkg>net-libs/libsmi</pkg> to resolve numeric OIDs into human readable format</flag>
+<flag name='sse4_2'> Support SSE4.2 (Streaming SIMD Extensions 4.2) instructions</flag>
 </use>
 </pkgmetadata>



1.657                net-analyzer/wireshark/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/wireshark/ChangeLog?rev=1.657&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/wireshark/ChangeLog?rev=1.657&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/wireshark/ChangeLog?r1=1.656&r2=1.657

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/wireshark/ChangeLog,v
retrieving revision 1.656
retrieving revision 1.657
diff -u -r1.656 -r1.657
--- ChangeLog	27 Sep 2014 10:58:51 -0000	1.656
+++ ChangeLog	2 Oct 2014 12:17:00 -0000	1.657
@@ -1,6 +1,13 @@
 # ChangeLog for net-analyzer/wireshark
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/wireshark/ChangeLog,v 1.656 2014/09/27 10:58:51 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/wireshark/ChangeLog,v 1.657 2014/10/02 12:17:00 jer Exp $
+
+*wireshark-1.99.0.1975 (02 Oct 2014)
+
+  02 Oct 2014; Jeroen Roovers <jer@g.o> +wireshark-1.99.0.1975.ebuild,
+  +files/wireshark-1.99.0.1975-gcc_option.patch,
+  +files/wireshark-1.99.0.1975-sse4_2.patch, metadata.xml:
+  Version bump.
 
   27 Sep 2014; Jeroen Roovers <jer@g.o> -wireshark-1.10.9.ebuild,
   -files/wireshark-1.10.1-oldlibs.patch,



1.1                  net-analyzer/wireshark/wireshark-1.99.0.1975.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/wireshark/wireshark-1.99.0.1975.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/wireshark/wireshark-1.99.0.1975.ebuild?rev=1.1&content-type=text/plain

Index: wireshark-1.99.0.1975.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/wireshark/wireshark-1.99.0.1975.ebuild,v 1.1 2014/10/02 12:17:00 jer Exp $

EAPI=5
inherit autotools eutils fcaps qt4-r2 user versionator

DESCRIPTION="A network protocol analyzer formerly known as ethereal"
HOMEPAGE="http://www.wireshark.org/"

WS_GIT="0efa992"
WS_PV="$(version_format_string '$1.$2.$3-$4-g${WS_GIT}')"
SRC_URI="${HOMEPAGE}download/automated/src/${PN}-${WS_PV}.tar.bz2"

LICENSE="GPL-2"
SLOT="0/${PV}"
KEYWORDS=""
IUSE="
	adns +caps crypt doc doc-pdf geoip +gtk3 ipv6 kerberos lua +netlink +pcap
	portaudio +qt4 selinux smi sse4_2 ssl zlib
"
REQUIRED_USE="
	ssl? ( crypt )
"

GTK_COMMON_DEPEND="
	x11-libs/gdk-pixbuf
	x11-libs/pango
	x11-misc/xdg-utils
"
RDEPEND="
	>=dev-libs/glib-2.14:2
	netlink? ( dev-libs/libnl:3 )
	adns? ( >=net-dns/c-ares-1.5 )
	crypt? ( dev-libs/libgcrypt:0 )
	caps? ( sys-libs/libcap )
	geoip? ( dev-libs/geoip )
	gtk3? (
		${GTK_COMMON_DEPEND}
		x11-libs/gtk+:3
	)
	kerberos? ( virtual/krb5 )
	lua? ( >=dev-lang/lua-5.1 )
	pcap? ( net-libs/libpcap )
	portaudio? ( media-libs/portaudio )
	qt4? (
		dev-qt/qtcore:4
		dev-qt/qtgui:4
		x11-misc/xdg-utils
		)
	selinux? ( sec-policy/selinux-wireshark )
	smi? ( net-libs/libsmi )
	ssl? ( net-libs/gnutls )
	zlib? ( sys-libs/zlib !=sys-libs/zlib-1.2.4 )
"

DEPEND="
	${RDEPEND}
	doc? (
		app-doc/doxygen
		app-text/asciidoc
		dev-libs/libxml2
		dev-libs/libxslt
		doc-pdf? ( dev-java/fop )
		www-client/lynx
	)
	>=virtual/perl-Pod-Simple-3.170.0
	sys-devel/bison
	sys-devel/flex
	virtual/perl-Getopt-Long
	virtual/perl-Time-Local
	virtual/pkgconfig
"

S=${WORKDIR}/${PN}-${WS_PV}

pkg_setup() {
	enewgroup wireshark
}

src_prepare() {
	epatch \
		"${FILESDIR}"/${PN}-1.6.13-ldflags.patch \
		"${FILESDIR}"/${PN}-1.11.0-oldlibs.patch \
		"${FILESDIR}"/${PN}-1.11.3-gtk-deprecated-warnings.patch \
		"${FILESDIR}"/${P}-gcc_option.patch \
		"${FILESDIR}"/${P}-sse4_2.patch

	# Qt5 support is broken since the build system does not determine
	# properly which `moc' it ought to use
	sed -i -e 's|Qt5||g' acinclude.m4 || die

	epatch_user

	eautoreconf
}

src_configure() {
	local myconf

	# Workaround bug #213705. If krb5-config --libs has -lcrypto then pass
	# --with-ssl to ./configure. (Mimics code from acinclude.m4).
	if use kerberos; then
		case $(krb5-config --libs) in
			*-lcrypto*)
				ewarn "Kerberos was built with ssl support: linkage with openssl is enabled."
				ewarn "Note there are annoying license incompatibilities between the OpenSSL"
				ewarn "license and the GPL, so do your check before distributing such package."
				myconf+=( "--with-ssl" )
				;;
		esac
	fi

	# Enable wireshark binary with any supported GUI toolkit (bug #473188)
	if use gtk3 || use qt4 ; then
		myconf+=( "--enable-wireshark" )
	else
		myconf+=( "--disable-wireshark" )
	fi

	# Hack around inability to disable doxygen/fop doc generation
	use doc || export ac_cv_prog_HAVE_DOXYGEN=false
	use doc-pdf || export ac_cv_prog_HAVE_FOP=false

	# dumpcap requires libcap
	# --disable-profile-build bugs #215806, #292991, #479602
	econf \
		$(use_enable ipv6) \
		$(use_with adns c-ares) \
		$(use_with caps libcap) \
		$(use_with crypt gcrypt) \
		$(use_with geoip) \
		$(use_with gtk3) \
		$(use_with kerberos krb5) \
		$(use_with lua) \
		$(use_with pcap dumpcap-group wireshark) \
		$(use_with pcap) \
		$(use_with portaudio) \
		$(use_with qt4 qt) \
		$(use_with smi libsmi) \
		$(use_with ssl gnutls) \
		$(use_with zlib) \
		$(usex netlink --with-libnl=3 --without-libnl) \
		$(usex sse4_2 --enable-sse4_2 '') \
		--disable-profile-build \
		--disable-usr-local \
		--disable-warnings-as-errors \
		--sysconfdir="${EPREFIX}"/etc/wireshark \
		--without-adns \
		${myconf[@]}
}

src_compile() {
	default
	use doc && emake -j1 -C docbook
}

src_install() {
	default
	if use doc; then
		dohtml -r docbook/{release-notes.html,ws{d,u}g_html{,_chunked}}
		if use doc-pdf; then
			insinto /usr/share/doc/${PF}/pdf/
			doins docbook/{{developer,user}-guide,release-notes}-{a4,us}.pdf
		fi
	fi

	# FAQ is not required as is installed from help/faq.txt
	dodoc AUTHORS ChangeLog NEWS README{,.bsd,.linux,.macos,.vmware} \
		doc/{randpkt.txt,README*}

	# install headers
	local wsheader
	for wsheader in \
		color.h \
		config.h \
		epan/*.h \
		epan/crypt/*.h \
		epan/dfilter/*.h \
		epan/dissectors/*.h \
		epan/ftypes/*.h \
		epan/wmem/*.h \
		register.h \
		wiretap/*.h \
		ws_symbol_export.h \
		wsutil/*.h
	do
		insinto /usr/include/wireshark/$( dirname ${wsheader} )
		doins ${wsheader}
	done

	#with the above this really shouldn't be needed, but things may be looking in wiretap/ instead of wireshark/wiretap/
	insinto /usr/include/wiretap
	doins wiretap/wtap.h

	if use gtk3 || use qt4; then
		local c d
		for c in hi lo; do
			for d in 16 32 48; do
				insinto /usr/share/icons/${c}color/${d}x${d}/apps
				newins image/${c}${d}-app-wireshark.png wireshark.png
			done
		done
	fi

	if use gtk3; then
		domenu wireshark.desktop
	fi

	if use qt4; then
		sed -e '/Exec=/s|wireshark|&-qt|g' wireshark.desktop > wireshark-qt.desktop || die
		domenu wireshark-qt.desktop
	fi

	prune_libtool_files
}

pkg_postinst() {
	# Add group for users allowed to sniff.
	enewgroup wireshark

	if use pcap; then
		fcaps -o 0 -g wireshark -m 4710 -M 0710 \
			cap_dac_read_search,cap_net_raw,cap_net_admin \
			"${EROOT}"/usr/bin/dumpcap
	fi

	ewarn "NOTE: To run wireshark as normal user you have to add yourself to"
	ewarn "the wireshark group. This security measure ensures that only trusted"
	ewarn "users are allowed to sniff your traffic."
}