[gentoo-commits] gentoo-x86 commit in media-video/x264-encoder: ChangeLog x264-encoder-0.0.20110426.ebuild

[Alexis Ballier (aballier)]

aballier    11/04/27 17:20:43

  Modified:             ChangeLog
  Added:                x264-encoder-0.0.20110426.ebuild
  Log:
  new snapshot
  
  (Portage version: 2.2.0_alpha30/cvs/Linux x86_64)

Revision  Changes    Path
1.49                 media-video/x264-encoder/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/x264-encoder/ChangeLog?rev=1.49&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/x264-encoder/ChangeLog?rev=1.49&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/x264-encoder/ChangeLog?r1=1.48&r2=1.49

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/x264-encoder/ChangeLog,v
retrieving revision 1.48
retrieving revision 1.49
diff -u -r1.48 -r1.49
--- ChangeLog	3 Apr 2011 18:18:48 -0000	1.48
+++ ChangeLog	27 Apr 2011 17:20:43 -0000	1.49
@@ -1,6 +1,12 @@
 # ChangeLog for media-video/x264-encoder
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/x264-encoder/ChangeLog,v 1.48 2011/04/03 18:18:48 scarabeus Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/x264-encoder/ChangeLog,v 1.49 2011/04/27 17:20:43 aballier Exp $
+
+*x264-encoder-0.0.20110426 (27 Apr 2011)
+
+  27 Apr 2011; Alexis Ballier <aballier@g.o>
+  +x264-encoder-0.0.20110426.ebuild, +files/x264-encoder-nolib-20110425.patch:
+  new snapshot
 
   03 Apr 2011; Tomáš Chvátal <scarabeus@g.o>
   x264-encoder-0.0.20100605.ebuild, x264-encoder-0.0.20101029.ebuild,



1.1                  media-video/x264-encoder/x264-encoder-0.0.20110426.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/x264-encoder/x264-encoder-0.0.20110426.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/x264-encoder/x264-encoder-0.0.20110426.ebuild?rev=1.1&content-type=text/plain

Index: x264-encoder-0.0.20110426.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/x264-encoder/x264-encoder-0.0.20110426.ebuild,v 1.1 2011/04/27 17:20:43 aballier Exp $

EAPI=2
inherit eutils multilib toolchain-funcs versionator

MY_P=x264-snapshot-$(get_version_component_range 3)-2245

DESCRIPTION="A free commandline encoder for X264/AVC streams"
HOMEPAGE="http://www.videolan.org/developers/x264.html"
SRC_URI="http://ftp.videolan.org/pub/videolan/x264/snapshots/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="debug ffmpeg +mp4 +threads"

RDEPEND="mp4? ( >=media-video/gpac-0.4.1_pre20060122 )
	~media-libs/x264-${PV}
	ffmpeg? ( virtual/ffmpeg )"
DEPEND="${RDEPEND}
	amd64? ( >=dev-lang/yasm-0.6.2 )
	x86? ( || ( >=dev-lang/yasm-0.6.2 dev-lang/nasm )
		!<dev-lang/yasm-0.6.2 )
	x86-fbsd? ( >=dev-lang/yasm-0.6.2 )
	dev-util/pkgconfig"

S="${WORKDIR}/${MY_P}"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-nostrip.patch \
		"${FILESDIR}"/${PN}-nolib-20110425.patch
}

src_configure() {
	tc-export CC

	local myconf=""
	use debug && myconf="${myconf} --enable-debug"

	./configure \
		--prefix=/usr \
		--libdir=/usr/$(get_libdir) \
		--disable-avs \
		$(use_enable ffmpeg lavf) \
		$(use_enable ffmpeg swscale) \
		$(use_enable mp4 gpac) \
		$(use_enable threads thread) \
		--extra-asflags="${ASFLAGS}" \
		--extra-cflags="${CFLAGS}" \
		--extra-ldflags="${LDFLAGS}" \
		--host="${CHOST}" \
		${myconf} \
		|| die
}

src_install() {
	emake DESTDIR="${D}" install || die
}