[gentoo-commits] gentoo-x86 commit in net-misc/chrony: ChangeLog chrony-1.25.ebuild chrony-1.25_pre2.ebuild chrony-1.25_pre1.ebuild

[Jeroen Roovers (jer)]

jer         11/05/04 14:36:38

  Modified:             ChangeLog
  Added:                chrony-1.25.ebuild
  Removed:              chrony-1.25_pre2.ebuild chrony-1.25_pre1.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha30/cvs/Linux i686)

Revision  Changes    Path
1.68                 net-misc/chrony/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/chrony/ChangeLog?rev=1.68&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/chrony/ChangeLog?rev=1.68&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/chrony/ChangeLog?r1=1.67&r2=1.68

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/chrony/ChangeLog,v
retrieving revision 1.67
retrieving revision 1.68
diff -u -r1.67 -r1.68
--- ChangeLog	27 Apr 2011 05:07:56 -0000	1.67
+++ ChangeLog	4 May 2011 14:36:38 -0000	1.68
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/chrony
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/chrony/ChangeLog,v 1.67 2011/04/27 05:07:56 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/chrony/ChangeLog,v 1.68 2011/05/04 14:36:38 jer Exp $
+
+*chrony-1.25 (04 May 2011)
+
+  04 May 2011; Jeroen Roovers <jer@g.o> -chrony-1.25_pre1.ebuild,
+  -chrony-1.25_pre2.ebuild, +chrony-1.25.ebuild:
+  Version bump.
 
 *chrony-1.25_pre2 (27 Apr 2011)
 



1.1                  net-misc/chrony/chrony-1.25.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/chrony/chrony-1.25.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/chrony/chrony-1.25.ebuild?rev=1.1&content-type=text/plain

Index: chrony-1.25.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/chrony/chrony-1.25.ebuild,v 1.1 2011/05/04 14:36:38 jer Exp $

EAPI=2

inherit eutils toolchain-funcs

MY_P="${P/_pre/-pre}"

DESCRIPTION="NTP client and server programs"
HOMEPAGE="http://chrony.tuxfamily.org/"
SRC_URI="http://download.tuxfamily.org/${PN}/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~hppa ~mips ~ppc ~sparc ~x86"
IUSE="caps readline"

RDEPEND="
	readline? ( >=sys-libs/readline-4.1-r4 )
	caps? ( sys-libs/libcap )
"
DEPEND="${RDEPEND}"

S="${WORKDIR}/${MY_P}"

src_prepare() {
	sed -i "s:/etc/chrony\.:/etc/chrony/chrony.:g" \
		examples/* chrony*.{1,5,8} faq.txt chrony.texi || die "sed failed"
}

src_configure() {
	tc-export CC
	local myconf
	use readline || myconf+=" --disable-readline"
	#use ipv6     || myconf+=" --disable-ipv6"
	use caps     || myconf+=" --disable-linuxcaps"
	# selfwritten configure
	./configure \
		--prefix=/usr \
		--sysconfdir=/etc/chrony \
		--infodir=/usr/share/info \
		--mandir=/usr/share/man \
		--docdir=/usr/share/doc/${PF} \
		${myconf} ${EXTRA_ECONF} || die "configure failed"
}

src_compile() {
	emake all || die "make failed"
	emake docs || die "make docs failed"
}

src_install() {
	emake DESTDIR="${D}" install || die
	rm "${D}"/usr/share/doc/${PF}/COPYING || die
	dodoc examples/chrony.{conf,keys}.example || die
	doinfo chrony.info* || die

	newinitd "${FILESDIR}"/chronyd.rc chronyd || die
	dosed "s:the documentation directory:/usr/share/doc/${PF}/:" \
		/etc/init.d/chronyd || die "doc sed failed"
	newconfd "${FILESDIR}"/chronyd.conf chronyd || die

	keepdir /var/{lib,log}/chrony /etc/chrony

	insinto /etc/logrotate.d
	newins "${FILESDIR}"/chrony.logrotate chrony
}