[gentoo-commits] repo/gentoo:master commit in: sys-apps/flatpak/

[Zac Medico]

commit:     2cb46de602b1509668484ac6b1bfd7b361438d7d
Author:     Zac Medico <zmedico <AT> gentoo <DOT> org>
AuthorDate: Fri Mar 17 00:06:14 2023 +0000
Commit:     Zac Medico <zmedico <AT> gentoo <DOT> org>
CommitDate: Fri Mar 17 00:15:17 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2cb46de6

sys-apps/flatpak: add 1.12.8

Bug: https://bugs.gentoo.org/901507
Signed-off-by: Zac Medico <zmedico <AT> gentoo.org>

 sys-apps/flatpak/Manifest              |   1 +
 sys-apps/flatpak/flatpak-1.12.8.ebuild | 108 +++++++++++++++++++++++++++++++++
 2 files changed, 109 insertions(+)

diff --git a/sys-apps/flatpak/Manifest b/sys-apps/flatpak/Manifest
index b76cfc8608d7..9883f2091761 100644
--- a/sys-apps/flatpak/Manifest
+++ b/sys-apps/flatpak/Manifest
@@ -1,2 +1,3 @@
 DIST flatpak-1.12.3.tar.xz 1555340 BLAKE2B 512b3f6abfb06d242aedad2c27c9870750254a9d0a3769999739f8885bbf1740b649e2a41f2c079532b049fcce8b58529572ea35e930437ed6b62194a73bcbb6 SHA512 2f39665457b4c3b99e32ebc88cf5b70202dba6118887617d3d7faa20f688f3f3fc14e343b70c0d11eb15ee743a68d07078e6cda14fd91aa10ca375797cfc95bc
+DIST flatpak-1.12.8.tar.xz 1568984 BLAKE2B 6db457eba6b5c03ae4b7037e55f0537821152a80cad8746939fe93008922a9a33ff9f08635613e56a84f2d151826130c497c1e9f7f1e41a5b2dc215882f2eb14 SHA512 5a37d94e12c18a746b222c1ddbd20bddfb22079af1d3a79dc819cdb25f04774c9e4b3a51f9b5ed64f210317e7ec9fb97324ae38ec3430c6a515ba4042805fc57
 DIST flatpak-1.14.1.tar.xz 1626500 BLAKE2B bf33dcd5a0f0289e5bff32794012dcfc45dcdbb11ef0da5c68769c18b1bcd12fcc0308ea275a7532f59998db6afa019746313387b0f9636c7d9b91ceb7d66665 SHA512 1f22622b9a797b644b5fe9d26c3c4ec3f6b1a3b81a12d498e5aeeecb1a965c9aaa5c1d18843c938f116855bbbed3a8d9866997440f86241abe70eae13be7cdcb

diff --git a/sys-apps/flatpak/flatpak-1.12.8.ebuild b/sys-apps/flatpak/flatpak-1.12.8.ebuild
new file mode 100644
index 000000000000..6983ea31deb9
--- /dev/null
+++ b/sys-apps/flatpak/flatpak-1.12.8.ebuild
@@ -0,0 +1,108 @@
+# Copyright 2020-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{9,10,11} )
+
+inherit linux-info python-any-r1
+
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/${PV}/${P}.tar.xz"
+DESCRIPTION="Linux application sandboxing and distribution framework"
+HOMEPAGE="https://flatpak.org/"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="doc introspection policykit seccomp systemd X"
+RESTRICT="test"
+
+RDEPEND="
+	acct-group/flatpak
+	acct-user/flatpak
+	>=app-arch/libarchive-2.8:=
+	app-arch/zstd:=
+	>=app-crypt/gpgme-1.1.8:=
+	>=dev-libs/appstream-glib-0.5.10:=
+	>=dev-libs/glib-2.56:2=
+	>=dev-libs/libxml2-2.4:=
+	dev-libs/json-glib:=
+	dev-libs/libassuan:=
+	>=dev-util/ostree-2020.8:=[gpg(+)]
+	|| (
+		dev-util/ostree[curl]
+		dev-util/ostree[soup]
+	)
+	>=gnome-base/dconf-0.26:=
+	gnome-base/gsettings-desktop-schemas
+	>=net-libs/libsoup-2.4:2.4=
+	>=sys-apps/bubblewrap-0.5.0
+	sys-apps/dbus
+	>=sys-fs/fuse-2.9.9:0=
+	sys-apps/xdg-dbus-proxy
+	X? (
+		x11-apps/xauth
+		x11-libs/libXau:=
+	)
+	x11-libs/gdk-pixbuf:2=
+	policykit? ( >=sys-auth/polkit-0.98:= )
+	seccomp? ( sys-libs/libseccomp:= )
+	systemd? ( sys-apps/systemd:= )
+"
+
+DEPEND="${RDEPEND}"
+# pyparsing version pinned for https://bugs.gentoo.org/825230
+BDEPEND="
+	>=sys-devel/automake-1.13.4
+	>=sys-devel/gettext-0.18.2
+	virtual/pkgconfig
+	dev-util/gdbus-codegen
+	sys-devel/bison
+	introspection? ( >=dev-libs/gobject-introspection-1.40 )
+	doc? (
+		>=dev-util/gtk-doc-1.20
+		dev-libs/libxslt
+	)
+	$(python_gen_any_dep 'dev-python/pyparsing[${PYTHON_USEDEP}]')
+"
+
+PDEPEND="sys-apps/xdg-desktop-portal"
+
+python_check_deps() {
+	has_version -b "dev-python/pyparsing[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	local CONFIG_CHECK="~USER_NS"
+	linux-info_pkg_setup
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	# This line fails because locales are in /usr/lib/locale/locale-archive.
+	sed -i 's:^cp -r /usr/lib/locale/C.*:#\0:' tests/make-test-runtime.sh || die
+}
+
+src_configure() {
+	local myeconfargs=(
+		--enable-sandboxed-triggers
+		--localstatedir="${EPREFIX}"/var
+		--with-system-bubblewrap
+		--with-system-dbus-proxy
+		$(use_enable X xauth)
+		$(use_enable doc documentation)
+		$(use_enable doc gtk-doc)
+		$(use_enable introspection)
+		$(use_enable policykit system-helper)
+		$(use_enable seccomp)
+		$(use_with systemd)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	# resolve conflict with acct-user/flatpak for #856706
+	rm -rf "${ED}/usr/lib/sysusers.d"
+}