[gentoo-commits] repo/gentoo:master commit in: dev-python/dask/

[Michał Górny]

commit:     d392b6f6cdf4f641c04fa87d924b9508eea05936
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Aug 16 06:40:38 2020 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Aug 16 08:12:51 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d392b6f6

dev-python/dask: Bump to 2.23.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/dask/Manifest           |  1 +
 dev-python/dask/dask-2.23.0.ebuild | 53 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 54 insertions(+)

diff --git a/dev-python/dask/Manifest b/dev-python/dask/Manifest
index 497e326a6d3..f1316aaa510 100644
--- a/dev-python/dask/Manifest
+++ b/dev-python/dask/Manifest
@@ -1,2 +1,3 @@
 DIST dask-1.2.0.tar.gz 2381831 BLAKE2B 88d48b9bcd4444dfe066c8049eae2a8b65e6ae1a7e4f4ff89697c254efc365091a61b298333b0f8d660cc9f760d3960a355beafde2555dfd912606dbe4a49db1 SHA512 c00886768b331f48ac9627f81c39368afbb4f1083ee9f7e3ebbe64352cc48c3c580fccef8d5466592f5bf772f873bef2ac084a972d30e7c1b4d1028e1d456059
 DIST dask-2.22.0.tar.gz 2831467 BLAKE2B 641f71c868fe49a027adab11b0a84c091537bfe56a786bbb00215ade5ba5fa7687176f70f12802b06bbcaf00db76f0c97eaa5b87cb65fc28bbe3e37c8b55f2a6 SHA512 90d6391a8dfc36788e819bf09f4ea65a89f37b14d0755fe4ade9179e5d3edd6dada30d5c08ad730f4ac9e08a0cc64a354933f52b92eb13fb8e60093dbcf28567
+DIST dask-2.23.0.tar.gz 2840133 BLAKE2B 2fe8e4007acf2bbd8bfab889e4d912a15518318dc019573ce6deb7f3a64504608e1e27c3bd9c6766dd98a071ed075065da9beda3f2e5fef27c7bfc9918516d0a SHA512 6ce0f1471357cfa4f5c7f2e2ab31009e68d3e5de363569867d67038ae2e1a9c69552797fb232fb92deafc3b57aa040df9e60669c1856cbb53505a905c4f4b052

diff --git a/dev-python/dask/dask-2.23.0.ebuild b/dev-python/dask/dask-2.23.0.ebuild
new file mode 100644
index 00000000000..206edb645a4
--- /dev/null
+++ b/dev-python/dask/dask-2.23.0.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6..9} )
+
+inherit distutils-r1
+
+DESCRIPTION="Task scheduling and blocked algorithms for parallel processing"
+HOMEPAGE="https://dask.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="distributed"
+
+RDEPEND="
+	>=dev-python/cloudpickle-0.2.2[${PYTHON_USEDEP}]
+	>=dev-python/fsspec-0.6.0[${PYTHON_USEDEP}]
+	>=dev-python/numpy-1.13.0[${PYTHON_USEDEP}]
+	>=dev-python/pandas-0.23.4[${PYTHON_USEDEP}]
+	>=dev-python/partd-0.3.10[${PYTHON_USEDEP}]
+	dev-python/psutil[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	>=dev-python/toolz-0.8.2[${PYTHON_USEDEP}]
+	distributed? (
+		>=dev-python/distributed-2.0[${PYTHON_USEDEP}]
+	)
+"
+BDEPEND="
+	dev-python/toolz[${PYTHON_USEDEP}]
+	test? (
+		dev-python/numexpr[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		>=dev-python/s3fs-0.0.8[${PYTHON_USEDEP}]
+		sci-libs/scipy[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# flaky
+	sed -e 's:test_time_rolling_methods:_&:' \
+		-i dask/dataframe/tests/test_rolling.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	pytest -vv -m "not network" -n auto ||
+		die "Tests failed with ${EPYTHON}"
+}