[gentoo-commits] gentoo-x86 commit in x11-wm/ratpoison: ChangeLog ratpoison-9999.ebuild

[Jeroen Roovers (jer)]

jer         14/01/29 12:21:49

  Modified:             ChangeLog
  Added:                ratpoison-9999.ebuild
  Log:
  Add live ebuild.
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.95                 x11-wm/ratpoison/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/ratpoison/ChangeLog?rev=1.95&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/ratpoison/ChangeLog?rev=1.95&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/ratpoison/ChangeLog?r1=1.94&r2=1.95

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-wm/ratpoison/ChangeLog,v
retrieving revision 1.94
retrieving revision 1.95
diff -u -r1.94 -r1.95
--- ChangeLog	19 Oct 2013 15:29:24 -0000	1.94
+++ ChangeLog	29 Jan 2014 12:21:49 -0000	1.95
@@ -1,6 +1,11 @@
 # ChangeLog for x11-wm/ratpoison
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/ratpoison/ChangeLog,v 1.94 2013/10/19 15:29:24 pacho Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/ratpoison/ChangeLog,v 1.95 2014/01/29 12:21:49 jer Exp $
+
+*ratpoison-9999 (29 Jan 2014)
+
+  29 Jan 2014; Jeroen Roovers <jer@g.o> +ratpoison-9999.ebuild:
+  Add live ebuild.
 
   19 Oct 2013; Pacho Ramos <pacho@g.o> metadata.xml:
   Cleanup due desktop-wm removal



1.1                  x11-wm/ratpoison/ratpoison-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/ratpoison/ratpoison-9999.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/ratpoison/ratpoison-9999.ebuild?rev=1.1&content-type=text/plain

Index: ratpoison-9999.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-wm/ratpoison/ratpoison-9999.ebuild,v 1.1 2014/01/29 12:21:49 jer Exp $

EAPI=5

inherit autotools elisp-common eutils git-r3

DESCRIPTION="Ratpoison is an extremely light-weight and barebones wm modelled after screen"
HOMEPAGE="http://www.nongnu.org/ratpoison/"
EGIT_REPO_URI="git://git.savannah.nongnu.org/ratpoison.git"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS=""
IUSE="debug emacs +history +xft"

RDEPEND="
	emacs? ( virtual/emacs )
	history? ( sys-libs/readline )
	virtual/perl-PodParser
	x11-libs/libXinerama
	x11-libs/libXtst
	xft? ( x11-libs/libXft )
"
DEPEND="
	${RDEPEND}
	app-arch/xz-utils
"

SITEFILE=50ratpoison-gentoo.el
DOCS=( AUTHORS ChangeLog NEWS README TODO )

src_prepare() {
	epatch "${FILESDIR}/ratpoison.el-gentoo.patch"
	eautoreconf
}

src_configure() {
	econf \
		--without-electric-fence \
		$(use_enable debug) \
		$(use_with xft) \
		$(usex history '' --disable-history)
}

src_compile() {
	emake CFLAGS="${CFLAGS}"
	if use emacs; then
		elisp-compile contrib/ratpoison.el || die "elisp-compile failed"
	fi
}

src_install() {
	default

	exeinto /etc/X11/Sessions
	newexe "${FILESDIR}"/ratpoison.xsession ratpoison

	insinto /usr/share/xsessions
	doins "${FILESDIR}"/${PN}.desktop || die

	docinto example
	dodoc contrib/{genrpbindings,split.sh} \
		doc/{ipaq.ratpoisonrc,sample.ratpoisonrc}

	rm -rf "${ED}/usr/share/"{doc/ratpoison,ratpoison}

	if use emacs; then
		elisp-install ${PN} contrib/ratpoison.*
		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
	fi
}

pkg_postinst() {
	use emacs && elisp-site-regen
}

pkg_postrm() {
	use emacs && elisp-site-regen
}