[gentoo-commits] gentoo-x86 commit in x11-wm/herbstluftwm: ChangeLog herbstluftwm-0.4.1.ebuild

[Tim Harder (radhermit)]

radhermit    12/09/02 04:39:27

  Modified:             ChangeLog
  Added:                herbstluftwm-0.4.1.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha123/cvs/Linux x86_64)

Revision  Changes    Path
1.7                  x11-wm/herbstluftwm/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/herbstluftwm/ChangeLog?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/herbstluftwm/ChangeLog?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/herbstluftwm/ChangeLog?r1=1.6&r2=1.7

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-wm/herbstluftwm/ChangeLog,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- ChangeLog	20 Aug 2012 16:59:22 -0000	1.6
+++ ChangeLog	2 Sep 2012 04:39:27 -0000	1.7
@@ -1,6 +1,11 @@
 # ChangeLog for x11-wm/herbstluftwm
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/herbstluftwm/ChangeLog,v 1.6 2012/08/20 16:59:22 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/herbstluftwm/ChangeLog,v 1.7 2012/09/02 04:39:27 radhermit Exp $
+
+*herbstluftwm-0.4.1 (02 Sep 2012)
+
+  02 Sep 2012; Tim Harder <radhermit@g.o> +herbstluftwm-0.4.1.ebuild:
+  Version bump.
 
 *herbstluftwm-0.4 (20 Aug 2012)
 



1.1                  x11-wm/herbstluftwm/herbstluftwm-0.4.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/herbstluftwm/herbstluftwm-0.4.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/herbstluftwm/herbstluftwm-0.4.1.ebuild?rev=1.1&content-type=text/plain

Index: herbstluftwm-0.4.1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-wm/herbstluftwm/herbstluftwm-0.4.1.ebuild,v 1.1 2012/09/02 04:39:27 radhermit Exp $

EAPI=4

inherit toolchain-funcs bash-completion-r1

DESCRIPTION="A manual tiling window manager for X"
HOMEPAGE="http://wwwcip.cs.fau.de/~re06huxa/herbstluftwm/"
SRC_URI="http://wwwcip.cs.fau.de/~re06huxa/${PN}/tarballs/${P}.tar.gz"

LICENSE="BSD-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="examples xinerama zsh-completion"

CDEPEND=">=dev-libs/glib-2.24:2
	x11-libs/libX11
	xinerama? ( x11-libs/libXinerama )"
RDEPEND="${CDEPEND}
	app-shells/bash
	zsh-completion? ( app-shells/zsh )"
DEPEND="${CDEPEND}
	virtual/pkgconfig"

src_compile() {
	emake CC="$(tc-getCC)" LD="$(tc-getCC)" COLOR=0 VERBOSE= \
		$(use xinerama || echo XINERAMAFLAGS= XINERAMALIBS= )
}

src_install() {
	dobin herbstluftwm herbstclient
	dodoc BUGS NEWS README

	doman doc/{herbstluftwm,herbstclient}.1

	exeinto /etc/xdg/herbstluftwm
	doexe share/{autostart,panel.sh,restartpanels.sh}

	insinto /usr/share/xsessions
	doins share/herbstluftwm.desktop

	newbashcomp share/herbstclient-completion herbstclient

	if use zsh-completion ; then
		insinto /usr/share/zsh/site-functions
		doins share/_herbstclient
	fi

	if use examples ; then
		exeinto /usr/share/doc/${PF}/examples
		doexe scripts/*.sh
		docinto examples
		dodoc scripts/README
		docompress -x /usr/share/doc/${PF}/examples
	fi
}