[gentoo-commits] repo/gentoo:master commit in: profiles/, net-dns/dnsdist/

[Marek Szuba]

commit:     5391bc26d8e7602fe492f5d839d56541e4a0478e
Author:     Marek Szuba <marecki <AT> gentoo <DOT> org>
AuthorDate: Tue Dec 22 21:50:48 2020 +0000
Commit:     Marek Szuba <marecki <AT> gentoo <DOT> org>
CommitDate: Tue Dec 22 21:52:59 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5391bc26

net-dns/dnsdist: migrate to lua-single.eclass

Nice and easy. Builds, tests and installs fine against all implementations
currently in the tree.

Closes: https://bugs.gentoo.org/752795
Signed-off-by: Marek Szuba <marecki <AT> gentoo.org>

 net-dns/dnsdist/dnsdist-1.5.1-r100.ebuild | 85 +++++++++++++++++++++++++++++++
 profiles/package.mask                     |  1 +
 2 files changed, 86 insertions(+)

diff --git a/net-dns/dnsdist/dnsdist-1.5.1-r100.ebuild b/net-dns/dnsdist/dnsdist-1.5.1-r100.ebuild
new file mode 100644
index 00000000000..4e2054c07cc
--- /dev/null
+++ b/net-dns/dnsdist/dnsdist-1.5.1-r100.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-{1..4} luajit )
+
+inherit flag-o-matic lua-single
+
+DESCRIPTION="A highly DNS-, DoS- and abuse-aware loadbalancer"
+HOMEPAGE="https://dnsdist.org"
+
+SRC_URI="https://downloads.powerdns.com/releases/${P}.tar.bz2"
+KEYWORDS="~amd64 ~x86"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="dnscrypt dnstap doh gnutls +lmdb regex remote-logging snmp +ssl systemd test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${LUA_REQUIRED_USE}
+		dnscrypt? ( ssl )
+		gnutls? ( ssl )
+		doh? ( ssl !gnutls )"
+
+RDEPEND="acct-group/dnsdist
+	acct-user/dnsdist
+	>=dev-libs/boost-1.35:=
+	dev-libs/libedit:=
+	dnscrypt? ( dev-libs/libsodium:= )
+	dnstap? ( dev-libs/fstrm:= )
+	doh? ( www-servers/h2o:=[libh2o] )
+	lmdb? ( dev-db/lmdb:= )
+	regex? ( dev-libs/re2:= )
+	remote-logging? ( >=dev-libs/protobuf-3:= )
+	snmp? ( net-analyzer/net-snmp:= )
+	ssl? (
+		gnutls? ( net-libs/gnutls:= )
+		!gnutls? ( dev-libs/openssl:= )
+	)
+	systemd? ( sys-apps/systemd:0= )
+	${LUA_DEPS}
+"
+
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	default
+}
+
+src_configure() {
+	econf \
+		--sysconfdir=/etc/dnsdist \
+		--with-lua="${ELUA}" \
+		$(use_enable doh dns-over-https) \
+		$(use_enable dnscrypt) \
+		$(use_enable dnstap) \
+		$(use_with lmdb ) \
+		$(use_with regex re2) \
+		$(use_with remote-logging protobuf) \
+		$(use_with snmp net-snmp) \
+		$(use ssl && { echo "--enable-dns-over-tls" && use_with gnutls && use_with !gnutls libssl;} || echo "--without-gnutls --without-libssl") \
+		$(use_enable systemd) \
+		$(use_enable test unit-tests)
+		sed 's/hardcode_libdir_flag_spec_CXX='\''$wl-rpath $wl$libdir'\''/hardcode_libdir_flag_spec_CXX='\''$wl-rpath $wl\/$libdir'\''/g' \
+			-i "${S}/configure"
+}
+
+src_install() {
+	default
+
+	insinto /etc/dnsdist
+	doins "${FILESDIR}"/dnsdist.conf.example
+
+	newconfd "${FILESDIR}"/dnsdist.confd ${PN}
+	newinitd "${FILESDIR}"/dnsdist.initd ${PN}
+}
+
+pkg_postinst() {
+	elog "dnsdist provides multiple instances support. You can create more instances"
+	elog "by symlinking the dnsdist init script to another name."
+	elog
+	elog "The name must be in the format dnsdist.<suffix> and dnsdist will use the"
+	elog "/etc/dnsdist/dnsdist-<suffix>.conf configuration file instead of the default."
+}

diff --git a/profiles/package.mask b/profiles/package.mask
index fa5530ecdee..8dc2c8267c6 100644
--- a/profiles/package.mask
+++ b/profiles/package.mask
@@ -559,6 +559,7 @@ kde-apps/kdebase-meta:5
 >=net-analyzer/tracebox-0.4.4-r100
 >=net-analyzer/wireshark-3.4.2-r100
 >=net-dialup/accel-ppp-1.12.0_p20200913-r100
+>=net-dns/dnsdist-1.5.1-r100
 >=net-dns/dnsmasq-2.82-r100
 >=net-im/prosody-0.11.7-r100
 >=net-im/swift-4.0.2-r100