[gentoo-commits] repo/gentoo:master commit in: app-emacs/nxml-svg-schemas/

[Ulrich Müller]

commit:     982cb91a69441c74f7f7da02de9738d83bb5d44a
Author:     Ulrich Müller <ulm <AT> gentoo <DOT> org>
AuthorDate: Sun Aug 18 06:16:09 2019 +0000
Commit:     Ulrich Müller <ulm <AT> gentoo <DOT> org>
CommitDate: Sun Aug 18 06:17:16 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=982cb91a

app-emacs/nxml-svg-schemas: Bump EAPI to 7.

Add missing dependency on unzip.

Package-Manager: Portage-2.3.71, Repoman-2.3.17
Signed-off-by: Ulrich Müller <ulm <AT> gentoo.org>

 .../nxml-svg-schemas-1.1.20081123-r1.ebuild        | 43 ++++++++++++++++++++++
 1 file changed, 43 insertions(+)

diff --git a/app-emacs/nxml-svg-schemas/nxml-svg-schemas-1.1.20081123-r1.ebuild b/app-emacs/nxml-svg-schemas/nxml-svg-schemas-1.1.20081123-r1.ebuild
new file mode 100644
index 00000000000..30fe6dd0034
--- /dev/null
+++ b/app-emacs/nxml-svg-schemas/nxml-svg-schemas-1.1.20081123-r1.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit elisp
+
+DESCRIPTION="Extension for nxml-mode with SVG 1.1 schemas"
+HOMEPAGE="http://www.w3.org/TR/SVG11/"
+# original SRC_URI is http://www.w3.org/Graphics/SVG/1.1/rng/rng.zip
+# but since it's unversioned, I versioned it and got it locally.
+SRC_URI="http://www.flameeyes.eu/gentoo-distfiles/w3c-svg-rng-${PV}.zip"
+
+LICENSE="HPND"
+# In a future we might have 1.2 schemas too, but for now we can only
+# install this one anyway because the schemas.xml syntax is not
+# sophisticated enough.
+SLOT="1.1"
+KEYWORDS="~amd64 ~x86"
+
+# Yes this requires Java, but I'd rather not repackage this, if you
+# know something better in C, I'll be glad to use that.
+BDEPEND="app-arch/unzip
+	app-text/trang"
+
+S="${WORKDIR}"
+SITEFILE="60${PN}-gentoo.el"
+
+src_prepare() {
+	elisp_src_prepare
+	# we don't need the doctype for our work
+	sed -i -e '/DOCTYPE grammar/d' *.rng || die "sed failed"
+}
+
+src_compile() {
+	emake -f "${FILESDIR}/Makefile-trang"
+}
+
+src_install() {
+	insinto "${SITEETC}/${PN}"
+	doins "${FILESDIR}/schemas.xml" *.rnc
+	elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+}