[gentoo-commits] gentoo-x86 commit in dev-libs/ppl: ChangeLog ppl-0.11.1.ebuild

[Ryan Hill (dirtyepic)]

dirtyepic    11/02/21 02:38:15

  Modified:             ChangeLog
  Added:                ppl-0.11.1.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha24/cvs/Linux x86_64)

Revision  Changes    Path
1.33                 dev-libs/ppl/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/ppl/ChangeLog?rev=1.33&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/ppl/ChangeLog?rev=1.33&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/ppl/ChangeLog?r1=1.32&r2=1.33

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/ppl/ChangeLog,v
retrieving revision 1.32
retrieving revision 1.33
diff -u -r1.32 -r1.33
--- ChangeLog	23 Jan 2011 20:03:54 -0000	1.32
+++ ChangeLog	21 Feb 2011 02:38:15 -0000	1.33
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/ppl
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/ppl/ChangeLog,v 1.32 2011/01/23 20:03:54 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/ppl/ChangeLog,v 1.33 2011/02/21 02:38:15 dirtyepic Exp $
+
+*ppl-0.11.1 (21 Feb 2011)
+
+  21 Feb 2011; Ryan Hill <dirtyepic@g.o> +ppl-0.11.1.ebuild:
+  Version bump.
 
   23 Jan 2011; Mike Frysinger <vapier@g.o> ppl-0.11.ebuild:
   Inherit eutils for epause #352519 by Diego Elio Pettenò.



1.1                  dev-libs/ppl/ppl-0.11.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/ppl/ppl-0.11.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/ppl/ppl-0.11.1.ebuild?rev=1.1&content-type=text/plain

Index: ppl-0.11.1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/ppl/ppl-0.11.1.ebuild,v 1.1 2011/02/21 02:38:15 dirtyepic Exp $

EAPI="3"

inherit eutils

DESCRIPTION="The Parma Polyhedra Library provides numerical abstractions for analysis of complex systems"
HOMEPAGE="http://www.cs.unipr.it/ppl/"
SRC_URI="http://www.cs.unipr.it/ppl/Download/ftp/releases/${PV}/${P}.tar.bz2"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd ~amd64-linux"
IUSE="doc lpsol pch test watchdog"

RDEPEND=">=dev-libs/gmp-4.1.3[-nocxx]
	lpsol? ( sci-mathematics/glpk )
	!<dev-libs/cloog-ppl-0.15.10"
DEPEND="${RDEPEND}
		sys-devel/m4"

pkg_setup() {
	if use test; then
		ewarn "The PPL testsuite will be run."
		ewarn "Note that this can take several hours to complete on a fast machine."
		epause 3
	fi
}

src_configure() {
	# --disable-check doesn't work
	use test && want_check="--enable-check=quick"
	econf \
		--docdir="${EPREFIX}"/usr/share/doc/${PF}	\
		--disable-debugging						\
		--disable-optimization					\
		$(use_enable lpsol ppl_lpsol)			\
		$(use_enable pch)						\
		$(use_enable watchdog)					\
		--enable-interfaces="c cxx"				\
		${want_check}							\
			|| die "configure failed"
}

src_test() {
	# default src_test runs with -j1, overriding it here saves about
	# 30 minutes and is recommended by upstream
	if emake -j1 check -n &> /dev/null; then
		emake check || die "tests failed"
	fi
}

src_install() {
	emake DESTDIR="${D}" install || die "Failed install"

	local docsdir="${ED}/usr/share/doc/${PF}"
	rm "${docsdir}"/gpl* "${docsdir}"/fdl* || die "Failed removing licenses"

	if ! use doc; then
		rm -r "${docsdir}"/*-html/ || die "Failed removing docs"
	fi

	dodoc NEWS README* STANDARDS TODO
}

pkg_postinst() {
	echo
	ewarn "After an upgrade of PPL it is important that you rebuild"
	ewarn "dev-libs/cloog-ppl."
	ewarn
	ewarn "If you use gcc-config to switch to an older compiler version than"
	ewarn "the one PPL was built with, PPL must be rebuilt with that version."
	ewarn
	ewarn "In both cases failure to do this will get you this error when"
	ewarn "graphite flags are used:"
	ewarn
	ewarn "    sorry, unimplemented: Graphite loop optimizations cannot be used"
	ewarn
	echo
}