[gentoo-commits] repo/gentoo:master commit in: app-backup/bup/

[Tim Harder]

commit:     2b6dfb63de99d868ff0a8e57e856e3f5396c2eb4
Author:     Tim Harder <radhermit <AT> gentoo <DOT> org>
AuthorDate: Sun Jan 22 23:59:27 2017 +0000
Commit:     Tim Harder <radhermit <AT> gentoo <DOT> org>
CommitDate: Mon Jan 23 00:02:37 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2b6dfb63

app-backup/bup: add doc use flag to control man page generation

For those who want to avoid pandoc and its haskell dep tree.

 app-backup/bup/bup-0.29-r1.ebuild | 60 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)

diff --git a/app-backup/bup/bup-0.29-r1.ebuild b/app-backup/bup/bup-0.29-r1.ebuild
new file mode 100644
index 00000000..b3b8ad1
--- /dev/null
+++ b/app-backup/bup/bup-0.29-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+
+inherit python-single-r1
+
+DESCRIPTION="A highly efficient backup system based on the git packfile format"
+HOMEPAGE="https://bup.github.io/ https://github.com/bup/bup"
+SRC_URI="https://github.com/bup/bup/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+doc test web"
+
+RDEPEND="${PYTHON_DEPS}
+	app-arch/par2cmdline
+	dev-python/fuse-python[${PYTHON_USEDEP}]
+	dev-python/pylibacl[${PYTHON_USEDEP}]
+	dev-python/pyxattr[${PYTHON_USEDEP}]
+	web? ( www-servers/tornado[${PYTHON_USEDEP}] )
+	sys-libs/readline:0
+	dev-vcs/git"
+DEPEND="${RDEPEND}
+	test? (
+		dev-lang/perl
+		net-misc/rsync
+	)
+	doc? ( app-text/pandoc )
+"
+
+# unresolved sandbox issues
+RESTRICT="test"
+
+src_prepare() {
+	default
+
+	sed -e "/^CFLAGS :=/s/-O2 -Werror//" \
+		-i Makefile || die
+}
+
+src_configure() {
+	# only build/install docs if enabled
+	export PANDOC=$(usex doc pandoc "")
+
+	./configure || die
+}
+
+src_test() {
+	emake test
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX=/usr LIBDIR="/usr/$(get_libdir)/bup" DOCDIR="/usr/share/${PF}" install
+	python_fix_shebang "${ED}"
+	python_optimize "${ED}"
+}