[gentoo-commits] repo/gentoo:master commit in: sys-kernel/gentoo-kernel-bin/

[Sam James]

commit:     187913d7cc96113838fd31957a23b88df9f99fe7
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sat Sep 11 06:15:50 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sat Sep 11 06:15:50 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=187913d7

sys-kernel/gentoo-kernel-bin: add 5.13.15 for arm64

Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-kernel/gentoo-kernel-bin/Manifest              |   1 +
 .../gentoo-kernel-bin-5.13.15-r1.ebuild            | 113 +++++++++++++++++++++
 2 files changed, 114 insertions(+)

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 0cf0265ff2d..99c7b4ee474 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -42,6 +42,7 @@ DIST gentoo-kernel-5.13.14-1.amd64.xpak 67300474 BLAKE2B 77cd8746bd9739d4f01e8ce
 DIST gentoo-kernel-5.13.14-1.arm64-r1.xpak 62817763 BLAKE2B 9310d06d1000ef0d14d943f97025901d052c9504b43bbb77a3eb6839e873a542030045045d406496226d4b8b25cd0c20b743e81f10cff6de281487428d1b3908 SHA512 9829dccd15ae7830ba328a4bee85b596fddfe939eb808eadfd959f7313c8b15e7f6afa824ae8e3fb023e3c93b5908ab191217900b6e92572581198acd65cf312
 DIST gentoo-kernel-5.13.14-1.x86.xpak 58515585 BLAKE2B b47dcd092c5487f02505ae5e040d1297e521c5d85dd9e0ae7e26ff95caca4e708ec17a26e4780170b148cc40f6b6ec1857cde274e7ee43d2bce4e64755ebd8a0 SHA512 3f7a84091924318517d5ae48b997872d26b9dc39032ef759aede145d25138550eb17d2e57453312d7cc51101a56b9c0bd5846a52b6a42202fbb2fea832723446
 DIST gentoo-kernel-5.13.15-1.amd64.xpak 67350744 BLAKE2B b429e607be5065061b6eb8f99f8a4b12e3537237ad43e9069f951894e67fa7c14d48667cac2af3983079f84edc8495dde8ffa1df629796e25d5f64eff3b22740 SHA512 4a67455ccf661d322e2b2cdf0d0ff3bd6575e64117e24774600d370db0f0a453c624bf3f495863f0115ef0ddfe0c461107672ba42476bdfc380435b665e9be3c
+DIST gentoo-kernel-5.13.15-1.arm64.xpak 62846334 BLAKE2B a05db11934ec886868a45a7d2f1f0d301ace7408e7fa09615c416aa2ebe5b12e9be1b54867afb09c1229683d975525d1ceacd316a6e6c4bec893e04d52413856 SHA512 f960f1b90788764d1684990072c89b59fdc381092d326392a644dabcdff65cbf2b2912096f11d4a5059487497ab673670f6e044529da83d33403576fbe13d012
 DIST gentoo-kernel-5.13.15-1.x86.xpak 58514370 BLAKE2B b508f54b72970992fc621d89e5972d9d95c9e54ffbf35d73026fffe68d4f6004fa5140ebda5c4b32b5597c1b4f7b26aab54c2eb5e13fa34981ac2eb1a8bd371a SHA512 1da3f247d2fb43cbeea33ccc954ece1d96734291c7f9a8ea47705f856f15a75cc72e88f681ca61859b63ae0063b9d0646eb2164f3f54c696df43c32bc414dfca
 DIST gentoo-kernel-5.4.142-1.amd64.xpak 61382010 BLAKE2B 5753309c6f0e98adf348b332ef8acad749f0501b5a0641f2436c7ca7a48c6e57d9f2b316f06d82b5e362cbdf91aa253ba69c7425b6eda0db46531e04929ac6de SHA512 c8433c79fde6bc7b31ff2d93b24e5b327166dcf00157ef91057b006b071f6c7293940285c54f282d40a09957f91831dac9f622dd477be62ec8fea713b0a6b68e
 DIST gentoo-kernel-5.4.142-1.arm64.xpak 58037550 BLAKE2B f2f047abcfc83ed15154c617a10810c3d608106d47e8ddd7f5a70e8b3d5a77e6df34b56efeacbcd14fd479db3f7c5574026bdf4d2c6910dd8e9bb5940f4443c7 SHA512 8a9f109738071ae08ea7231964d1fda529aa5bb0810e96c19b3b82c1743868545eb254fc0604586c10645583012baaa0d2a2e930e460ba0697102b081d277521

diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.13.15-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.13.15-r1.ebuild
new file mode 100644
index 00000000000..2f16601a52d
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.13.15-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 2 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+		-> ${BINPKG}.arm64.xpak
+	)"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}