[gentoo-commits] gentoo-x86 commit in app-accessibility/espeak: espeak-1.47.11-r1.ebuild ChangeLog

[William Hubbs (williamh)]

williamh    13/10/01 03:58:08

  Modified:             ChangeLog
  Added:                espeak-1.47.11-r1.ebuild
  Log:
  Fixes for bug #485934 and bug #485936
  
  (Portage version: 2.2.1/cvs/Linux i686, signed Manifest commit with key 0x30C46538)

Revision  Changes    Path
1.112                app-accessibility/espeak/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-accessibility/espeak/ChangeLog?rev=1.112&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-accessibility/espeak/ChangeLog?rev=1.112&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-accessibility/espeak/ChangeLog?r1=1.111&r2=1.112

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-accessibility/espeak/ChangeLog,v
retrieving revision 1.111
retrieving revision 1.112
diff -u -r1.111 -r1.112
--- ChangeLog	22 Sep 2013 20:14:41 -0000	1.111
+++ ChangeLog	1 Oct 2013 03:58:08 -0000	1.112
@@ -1,6 +1,11 @@
 # ChangeLog for app-accessibility/espeak
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-accessibility/espeak/ChangeLog,v 1.111 2013/09/22 20:14:41 williamh Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-accessibility/espeak/ChangeLog,v 1.112 2013/10/01 03:58:08 williamh Exp $
+
+*espeak-1.47.11-r1 (01 Oct 2013)
+
+  01 Oct 2013; William Hubbs <williamh@g.o> +espeak-1.47.11-r1.ebuild:
+  Fixes for bug #485934 and bug #485936
 
   22 Sep 2013; William Hubbs <williamh@g.o> espeak-1.47.11.ebuild:
   Add overrides for AR and CFLAGS, convert a call to make to emake, use the S



1.1                  app-accessibility/espeak/espeak-1.47.11-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-accessibility/espeak/espeak-1.47.11-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-accessibility/espeak/espeak-1.47.11-r1.ebuild?rev=1.1&content-type=text/plain

Index: espeak-1.47.11-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-accessibility/espeak/espeak-1.47.11-r1.ebuild,v 1.1 2013/10/01 03:58:08 williamh Exp $

EAPI=5

inherit eutils multilib toolchain-funcs

MY_P="${P}-source"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.zip"
DESCRIPTION="Speech synthesizer for English and other languages"
HOMEPAGE="http://espeak.sourceforge.net/"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
IUSE="portaudio pulseaudio"

COMMON_DEPEND="
	portaudio? ( >=media-libs/portaudio-19_pre20071207 )
	pulseaudio? (
	!portaudio? ( >=media-libs/portaudio-19_pre20071207 )
	media-sound/pulseaudio )"

DEPEND="${COMMON_DEPEND}
	app-arch/unzip"

RDEPEND="${COMMON_DEPEND}
	media-sound/sox"

S=${WORKDIR}/${MY_P}/src

get_audio() {
	if use portaudio && use pulseaudio; then
		echo runtime
	elif use portaudio; then
		echo portaudio
	elif use pulseaudio; then
		echo pulseaudio
	else
		echo none
	fi
}

src_prepare() {
	# gentoo uses portaudio 19.
	mv -f portaudio19.h portaudio.h
}

src_compile() {
	emake \
		PREFIX="${EPREFIX}/usr" \
		CC="$(tc-getCC)" \
		CFLAGS="${CFLAGS}" \
		CXX="$(tc-getCXX)" \
		CXXFLAGS="${CXXFLAGS}" \
		AR="$(tc-getAR)" \
		AUDIO="$(get_audio)" \
		all

	einfo "Fixing byte order of phoneme data files"
	pushd ../platforms/big_endian > /dev/null
	emake \
		CC="$(tc-getCC)" \
		CFLAGS="${CFLAGS}"
	./espeak-phoneme-data \
		../../espeak-data \
		. \
		../../espeak-data/phondata-manifest
	cp -f phondata phonindex phontab "../../espeak-data"
}

src_install() {
	emake \
		PREFIX="${EPREFIX}/usr" \
		LIBDIR="\$(PREFIX)/$(get_libdir)" \
		DESTDIR="${D}" \
		AUDIO="$(get_audio)" \
		install

	cd ..
	insinto /usr/share/espeak-data
	doins -r dictsource
	dodoc ChangeLog.txt ReadMe
	dohtml -r docs/*
}

pkg_preinst() {
	local voicedir="${ROOT}/usr/share/${PN}-data/voices/en"
	if [ -d "${voicedir}" ]; then
		rm -rf "${voicedir}"
	fi
}

pkg_postinst() {
	if ! use portaudio && ! use pulseaudio; then
		ewarn "Since portaudio and pulseaudio are not in your use flags,"
		ewarn "espeak will only be able to create wav files."
		ewarn "If this is not what you want, please reemerge ${CATEGORY}/${PN}"
		ewarn "with either portaudio or pulseaudio USE flag enabled."
	fi
}