[gentoo-commits] gentoo-x86 commit in app-mobilephone/smstools: ChangeLog smstools-3.1.14-r2.ebuild

[Tony Vroon (chainsaw)]

chainsaw    11/11/28 22:36:01

  Modified:             ChangeLog
  Added:                smstools-3.1.14-r2.ebuild
  Log:
  CFLAGS respect & die statements by Agostino "ago" Sarubbo in bug #385273.
  
  (Portage version: 2.1.10.38/cvs/Linux x86_64)

Revision  Changes    Path
1.17                 app-mobilephone/smstools/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-mobilephone/smstools/ChangeLog?rev=1.17&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-mobilephone/smstools/ChangeLog?rev=1.17&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-mobilephone/smstools/ChangeLog?r1=1.16&r2=1.17

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-mobilephone/smstools/ChangeLog,v
retrieving revision 1.16
retrieving revision 1.17
diff -u -r1.16 -r1.17
--- ChangeLog	27 Jul 2011 10:41:13 -0000	1.16
+++ ChangeLog	28 Nov 2011 22:36:01 -0000	1.17
@@ -1,6 +1,11 @@
 # ChangeLog for app-mobilephone/smstools
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/smstools/ChangeLog,v 1.16 2011/07/27 10:41:13 chainsaw Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/smstools/ChangeLog,v 1.17 2011/11/28 22:36:01 chainsaw Exp $
+
+*smstools-3.1.14-r2 (28 Nov 2011)
+
+  28 Nov 2011; Tony Vroon <chainsaw@g.o> +smstools-3.1.14-r2.ebuild:
+  CFLAGS respect & die statements by Agostino "ago" Sarubbo in bug #385273.
 
 *smstools-3.1.14-r1 (27 Jul 2011)
 



1.1                  app-mobilephone/smstools/smstools-3.1.14-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-mobilephone/smstools/smstools-3.1.14-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-mobilephone/smstools/smstools-3.1.14-r2.ebuild?rev=1.1&content-type=text/plain

Index: smstools-3.1.14-r2.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/smstools/smstools-3.1.14-r2.ebuild,v 1.1 2011/11/28 22:36:01 chainsaw Exp $

EAPI=4

inherit eutils toolchain-funcs

DESCRIPTION="Send and receive short messages through GSM modems"
HOMEPAGE="http://smstools3.kekekasvi.com/"
SRC_URI="http://smstools3.kekekasvi.com/packages/smstools3-${PV}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~amd64 ~ppc"
IUSE="stats"

DEPEND=""
RDEPEND="sys-process/procps
	stats? ( >=dev-libs/mm-1.4.0 )"

S="${WORKDIR}/${PN}3"

pkg_setup() {
	enewgroup sms
	enewuser smsd -1 -1 /var/spool/sms sms
}

src_prepare() {
	if use stats; then
		sed -i -e "s:CFLAGS += -D NOSTATS:#CFLAGS += -D NOSTATS:" \
			"${S}/src/Makefile" || die
	fi
	echo "CFLAGS += ${CFLAGS}" >> src/Makefile || die
}

src_compile() {
	cd src || die
	emake \
		CC="$(tc-getCC)" \
		LFLAGS="${LDFLAGS}"
}

src_install() {
	dobin src/smsd
	cd scripts || die
	dobin sendsms sms2html sms2unicode unicode2sms
	dobin hex2bin hex2dec email2sms
	dodoc mysmsd smsevent smsresend sms2xml sql_demo \
		smstest.php checkhandler-utf-8 eventhandler-utf-8 \
		forwardsms regular_run
	cd .. || die

	keepdir /var/spool/sms/incoming
	keepdir /var/spool/sms/outgoing
	keepdir /var/spool/sms/checked
	fowners -R smsd:sms /var/spool/sms
	fperms g+s /var/spool/sms/incoming

	newinitd "${FILESDIR}"/smsd.initd2 smsd
	insopts -o smsd -g sms -m0644
	insinto /etc
	newins examples/smsd.conf.easy smsd.conf
	dohtml -r doc
}

pkg_postinst() {
	touch "${ROOT}"/var/log/smsd.log || die
	chown -f smsd:sms "${ROOT}"/var/log/smsd.log
}