[gentoo-commits] gentoo-x86 commit in net-misc/whois: ChangeLog whois-5.0.17.ebuild

[Tim Harder (radhermit)]

radhermit    12/06/29 03:07:32

  Modified:             ChangeLog
  Added:                whois-5.0.17.ebuild
  Log:
  Version bump. Don't generate po files when nls is disabled (bug #419889).
  
  (Portage version: 2.2.0_alpha112/cvs/Linux x86_64)

Revision  Changes    Path
1.179                net-misc/whois/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/whois/ChangeLog?rev=1.179&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/whois/ChangeLog?rev=1.179&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/whois/ChangeLog?r1=1.178&r2=1.179

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/whois/ChangeLog,v
retrieving revision 1.178
retrieving revision 1.179
diff -u -r1.178 -r1.179
--- ChangeLog	17 Jun 2012 16:04:35 -0000	1.178
+++ ChangeLog	29 Jun 2012 03:07:32 -0000	1.179
@@ -1,6 +1,11 @@
 # ChangeLog for net-misc/whois
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/whois/ChangeLog,v 1.178 2012/06/17 16:04:35 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/whois/ChangeLog,v 1.179 2012/06/29 03:07:32 radhermit Exp $
+
+*whois-5.0.17 (29 Jun 2012)
+
+  29 Jun 2012; Tim Harder <radhermit@g.o> +whois-5.0.17.ebuild:
+  Version bump. Don't generate po files when nls is disabled (bug #419889).
 
   17 Jun 2012; Raúl Porcel <armin76@g.o> whois-5.0.15.ebuild:
   alpha/ia64/s390/sh/sparc stable wrt #414239



1.1                  net-misc/whois/whois-5.0.17.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/whois/whois-5.0.17.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/whois/whois-5.0.17.ebuild?rev=1.1&content-type=text/plain

Index: whois-5.0.17.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/whois/whois-5.0.17.ebuild,v 1.1 2012/06/29 03:07:32 radhermit Exp $

EAPI=4
inherit eutils toolchain-funcs

MY_P=${P/-/_}
DESCRIPTION="improved Whois Client"
HOMEPAGE="http://www.linux.it/~md/software/"
SRC_URI="mirror://debian/pool/main/w/whois/${MY_P}.tar.xz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux"
IUSE="iconv idn nls"
RESTRICT="test" #59327

RDEPEND="iconv? ( virtual/libiconv )
	idn? ( net-dns/libidn )
	nls? ( virtual/libintl )"
DEPEND="${RDEPEND}
	app-arch/xz-utils
	>=dev-lang/perl-5
	nls? ( sys-devel/gettext )"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-4.7.2-config-file.patch

	if use nls ; then
		sed -i -e 's:#\(.*pos\):\1:' Makefile || die
	else
		sed -i -e '/ENABLE_NLS/s:define:undef:' config.h || die

		# don't generate po files when nls is disabled (bug #419889)
		sed -i -e '/^all:/s/ pos//' \
			-e '/^install:/s/ install-pos//' Makefile || die
	fi
}

src_configure() { :;} # expected no-op

src_compile() {
	unset HAVE_ICONV HAVE_LIBIDN
	use iconv && export HAVE_ICONV=1
	use idn && export HAVE_LIBIDN=1
	tc-export CC
	emake CFLAGS="${CFLAGS} ${CPPFLAGS}"
}

src_install() {
	emake BASEDIR="${ED}" prefix=/usr install
	insinto /etc
	doins whois.conf
	dodoc README debian/changelog

	if [[ ${USERLAND} != "GNU" ]]; then
		mv "${ED}"/usr/share/man/man1/{whois,mdwhois}.1 || die
		mv "${ED}"/usr/bin/{whois,mdwhois} || die
	fi
}