[gentoo-commits] gentoo-x86 commit in sys-apps/sandbox: ChangeLog sandbox-1.3.1.ebuild

[Mike Frysinger (vapier)]

vapier      08/11/29 02:54:38

  Modified:             ChangeLog
  Added:                sandbox-1.3.1.ebuild
  Log:
  Fix up #248254 and #248263.
  (Portage version: 2.2_rc16/cvs/Linux 2.6.27.4 x86_64)

Revision  Changes    Path
1.94                 sys-apps/sandbox/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/sandbox/ChangeLog?rev=1.94&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/sandbox/ChangeLog?rev=1.94&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/sandbox/ChangeLog?r1=1.93&r2=1.94

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/sandbox/ChangeLog,v
retrieving revision 1.93
retrieving revision 1.94
diff -u -r1.93 -r1.94
--- ChangeLog	16 Nov 2008 13:06:21 -0000	1.93
+++ ChangeLog	29 Nov 2008 02:54:38 -0000	1.94
@@ -1,6 +1,11 @@
 # ChangeLog for sys-apps/sandbox
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/sandbox/ChangeLog,v 1.93 2008/11/16 13:06:21 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/sandbox/ChangeLog,v 1.94 2008/11/29 02:54:38 vapier Exp $
+
+*sandbox-1.3.1 (29 Nov 2008)
+
+  29 Nov 2008; Mike Frysinger <vapier@g.o> +sandbox-1.3.1.ebuild:
+  Fix up #248254 and #248263.
 
 *sandbox-1.3.0 (16 Nov 2008)
 



1.1                  sys-apps/sandbox/sandbox-1.3.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/sandbox/sandbox-1.3.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/sandbox/sandbox-1.3.1.ebuild?rev=1.1&content-type=text/plain

Index: sandbox-1.3.1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/sandbox/sandbox-1.3.1.ebuild,v 1.1 2008/11/29 02:54:38 vapier Exp $

#
# don't monkey with this ebuild unless contacting portage devs.
# period.
#

inherit eutils flag-o-matic eutils toolchain-funcs multilib

DESCRIPTION="sandbox'd LD_PRELOAD hack"
HOMEPAGE="http://www.gentoo.org/"
SRC_URI="mirror://gentoo/${P}.tar.lzma
	http://dev.gentoo.org/~vapier/dist/${P}.tar.lzma"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
IUSE=""
RESTRICT="test"

DEPEND=""

EMULTILIB_PKG="true"
has sandbox_death_notice ${EBUILD_DEATH_HOOKS} || EBUILD_DEATH_HOOKS="${EBUILD_DEATH_HOOKS} sandbox_death_notice"

sandbox_death_notice() {
	ewarn "If configure failed with a 'cannot run C compiled programs' error, try this:"
	ewarn "FEATURES=-sandbox emerge sandbox"
}

src_compile() {
	filter-lfs-flags #90228

	local OABI=${ABI}
	for ABI in $(get_install_abis) ; do
		mkdir "${WORKDIR}/build-${ABI}"
		cd "${WORKDIR}/build-${ABI}"

		multilib_toolchain_setup ${ABI}

		einfo "Configuring sandbox for ABI=${ABI}..."
		ECONF_SOURCE="../${P}/" \
		econf ${myconf} || die
		einfo "Building sandbox for ABI=${ABI}..."
		emake || die
	done
	ABI=${OABI}
}

src_test() {
	local OABI=${ABI}
	for ABI in $(get_install_abis) ; do
		cd "${WORKDIR}/build-${ABI}"
		einfo "Checking sandbox for ABI=${ABI}..."
		emake check || die "make check failed for ${ABI}"
	done
	ABI=${OABI}
}

src_install() {
	local OABI=${ABI}
	for ABI in $(get_install_abis) ; do
		cd "${WORKDIR}/build-${ABI}"
		einfo "Installing sandbox for ABI=${ABI}..."
		emake DESTDIR="${D}" install || die "make install failed for ${ABI}"
	done
	ABI=${OABI}

	doenvd "${FILESDIR}"/09sandbox

	keepdir /var/log/sandbox
	fowners root:portage /var/log/sandbox
	fperms 0770 /var/log/sandbox

	cd "${S}"
	dodoc AUTHORS ChangeLog* NEWS README
}

pkg_preinst() {
	chown root:portage "${D}"/var/log/sandbox
	chmod 0770 "${D}"/var/log/sandbox
}