[gentoo-commits] repo/gentoo:master commit in: sci-libs/indilib/

[Sam James]

commit:     2c17ddee95f39dff9c66522803e2dc566d978515
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sun Sep 26 20:55:26 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Sep 26 21:01:45 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2c17ddee

sci-libs/indilib: add 1.9.2

Signed-off-by: Sam James <sam <AT> gentoo.org>

 sci-libs/indilib/Manifest             |  1 +
 sci-libs/indilib/indilib-1.9.2.ebuild | 57 +++++++++++++++++++++++++++++++++++
 2 files changed, 58 insertions(+)

diff --git a/sci-libs/indilib/Manifest b/sci-libs/indilib/Manifest
index bcdca55e19c..7ba7dfd7f4c 100644
--- a/sci-libs/indilib/Manifest
+++ b/sci-libs/indilib/Manifest
@@ -1 +1,2 @@
 DIST indilib-1.9.1.tar.gz 2322783 BLAKE2B 801071bf9190e4c27b4f3bf9fa2d9a44c4e297f7ee879061636f041d138a02db23525ee411782f3303a0d82bb2fc4d9d6489e2bda18f8e011bfa0d1b33595343 SHA512 d87c341efdaa8109059741738c69b9d6fb4b5dc68c774453eab378aa3784af29e8ed8469dba968a41c584fec1556fdbf0bd65cbb8aa65c2d9e1784d82e7bcc67
+DIST indilib-1.9.2.tar.gz 2335834 BLAKE2B 47d8bde8e3c783cefb23c8a8f865fa46bb9a6ed4ee08618d198680f3036e9ca9a16178b1ec4dab070d0cb3ec8d638847cedb752a2a5a1d5e2dc5ddbd362c0a86 SHA512 0a1ada5b5880553ddbcf794bac952ddce76d3aa46652c48621e284a04a7d3d9ba7492d8874bf30f7e3f614a904a829109eaee9dae53dd5854d72bb1c98740f44

diff --git a/sci-libs/indilib/indilib-1.9.2.ebuild b/sci-libs/indilib/indilib-1.9.2.ebuild
new file mode 100644
index 00000000000..7bc78575bc2
--- /dev/null
+++ b/sci-libs/indilib/indilib-1.9.2.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake udev
+
+DESCRIPTION="INDI Astronomical Control Protocol library"
+HOMEPAGE="https://www.indilib.org/"
+SRC_URI="https://github.com/${PN}/${PN/lib/}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${P/lib/}"
+
+LICENSE="BSD GPL-2+ LGPL-2+ LGPL-2.1+"
+SLOT="0/1"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="ogg rtlsdr test websocket"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	net-misc/curl
+	sci-libs/cfitsio:=
+	sci-libs/fftw:3.0=
+	sci-libs/gsl:=
+	sci-libs/libnova:=
+	sys-libs/zlib
+	virtual/jpeg:0
+	virtual/libusb:0
+	ogg? (
+		media-libs/libogg
+		media-libs/libtheora
+	)
+	rtlsdr? ( net-wireless/rtl-sdr )
+	websocket? ( dev-libs/boost:= )
+"
+DEPEND="${RDEPEND}
+	kernel_linux? ( sys-kernel/linux-headers )
+	test? ( >=dev-cpp/gtest-1.8.0 )
+	websocket? ( dev-cpp/websocketpp )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DINDI_BUILD_QT5_CLIENT=OFF
+		-DUDEVRULES_INSTALL_DIR="${EPREFIX}$(get_udevdir)"/rules.d
+		$(cmake_use_find_package ogg OggTheora)
+		$(cmake_use_find_package rtlsdr RTLSDR)
+		-DINDI_BUILD_UNITTESTS=$(usex test)
+		-DINDI_BUILD_WEBSOCKET=$(usex websocket)
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	BUILD_DIR="${BUILD_DIR}"/test cmake_src_test
+}