[gentoo-commits] gentoo-x86 commit in media-sound/amarok: ChangeLog amarok-1.4.7-r1.ebuild amarok-1.4.6.ebuild amarok-1.4.5-r1.ebuild

[Diego Petteno (flameeyes)]

flameeyes    07/11/10 16:27:37

  Modified:             ChangeLog
  Added:                amarok-1.4.7-r1.ebuild
  Removed:              amarok-1.4.6.ebuild amarok-1.4.5-r1.ebuild
  Log:
  Remove old version, revision bump to blacklist xine-lib-1.1.8 direct last.fm playback as it's broken by server change, 1.1.9 will work again.
  (Portage version: 2.1.3.19)

Revision  Changes    Path
1.235                media-sound/amarok/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/amarok/ChangeLog?rev=1.235&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/amarok/ChangeLog?rev=1.235&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/amarok/ChangeLog?r1=1.234&r2=1.235

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/amarok/ChangeLog,v
retrieving revision 1.234
retrieving revision 1.235
diff -u -r1.234 -r1.235
--- ChangeLog	4 Nov 2007 14:10:08 -0000	1.234
+++ ChangeLog	10 Nov 2007 16:27:36 -0000	1.235
@@ -1,6 +1,15 @@
 # ChangeLog for media-sound/amarok
 # Copyright 2000-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/amarok/ChangeLog,v 1.234 2007/11/04 14:10:08 angelos Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/amarok/ChangeLog,v 1.235 2007/11/10 16:27:36 flameeyes Exp $
+
+*amarok-1.4.7-r1 (10 Nov 2007)
+
+  10 Nov 2007; Diego Pettenò <flameeyes@g.o>
+  -files/amarok-1.4.5-magnatune.patch,
+  +files/amarok-1.4.7+xine-lib-1.1.8-lastfm.patch, -amarok-1.4.5-r1.ebuild,
+  -amarok-1.4.6.ebuild, +amarok-1.4.7-r1.ebuild:
+  Remove old version, revision bump to blacklist xine-lib-1.1.8 direct last.fm
+  playback as it's broken by server change, 1.1.9 will work again.
 
   04 Nov 2007; Christoph Mende <angelos@g.o> amarok-1.4.7.ebuild:
   Stable on amd64 wrt bug #192678



1.1                  media-sound/amarok/amarok-1.4.7-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/amarok/amarok-1.4.7-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/amarok/amarok-1.4.7-r1.ebuild?rev=1.1&content-type=text/plain

Index: amarok-1.4.7-r1.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/amarok/amarok-1.4.7-r1.ebuild,v 1.1 2007/11/10 16:27:36 flameeyes Exp $

LANGS="af ar az be bg bn br ca cs cy da de el en_GB eo es et eu fa fi
fr ga gl he hi hu id is it ja km ko ku lo lt mk ms nb nds ne nl nn pa pl
pt pt_BR ro ru rw se sk sl sq sr sr@Latn ss sv ta tg th tr uk uz zh_CN
zh_TW"
LANGS_DOC="da de es et fr it nl pl pt pt_BR ru sv"

USE_KEG_PACKAGING=1

inherit kde eutils flag-o-matic

PKG_SUFFIX=""

if [[ ${P/_pre} == ${P} ]]; then
	MY_P="${P/_/-}"

	if [[ ${P/_rc} == ${P} ]]; then
		SRC_URI="mirror://kde/stable/amarok/${PV}/src/${MY_P}.tar.bz2"
		S="${WORKDIR}/${P/_/-}"
	else
		SRC_URI="mirror://gentoo/${MY_P}.tar.bz2"
		S="${WORKDIR}/${P/_rc*}"
	fi
else
	SRC_URI="mirror://gentoo/${P}.tar.bz2"
fi

DESCRIPTION="Advanced audio player based on KDE framework."
HOMEPAGE="http://amarok.kde.org/"

LICENSE="GPL-2"

SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="mp4 kde mysql amazon opengl postgres
visualization ipod ifp real njb mtp musicbrainz daap
python"
# kde: enables compilation of the konqueror sidebar plugin

RDEPEND="kde? ( || ( kde-base/konqueror kde-base/kdebase ) )
	>=media-libs/xine-lib-1.1.2_pre20060328-r8
	>=media-libs/taglib-1.4
	mysql? ( >=virtual/mysql-4.0 )
	postgres? ( dev-db/libpq )
	opengl? ( virtual/opengl )
	visualization? ( media-libs/libsdl
					 =media-plugins/libvisual-plugins-0.4* )
	ipod? ( >=media-libs/libgpod-0.4.2 )
	mp4? ( media-libs/libmp4v2 )
	ifp? ( media-libs/libifp )
	real? ( media-video/realplayer )
	njb? ( >=media-libs/libnjb-2.2.4 )
	mtp? ( >=media-libs/libmtp-0.1.1 )
	musicbrainz? ( media-libs/tunepimp )
	=dev-lang/ruby-1.8*"

DEPEND="${RDEPEND}"

RDEPEND="${RDEPEND}
	app-arch/unzip
	python? ( dev-python/PyQt )
	daap? ( www-servers/mongrel )"

PATCHES="${FILESDIR}/${P}+xine-lib-1.1.8-lastfm.patch"

need-kde 3.3

src_compile() {
	# Extra, unsupported engines are forcefully disabled.
	local myconf="$(use_enable mysql) $(use_enable postgres postgresql)
				  $(use_with opengl) --without-xmms
				  $(use_with visualization libvisual)
				  $(use_enable amazon)
				  $(use_with ipod libgpod)
				  $(use_with mp4 mp4v2)
				  $(use_with ifp)
				  $(use_with real helix)
				  $(use_with njb libnjb)
				  $(use_with mtp libmtp)
				  $(use_with musicbrainz)
				  $(use_with daap)
				  --with-xine
				  --without-mas
				  --without-nmm"

	kde_src_compile
}

src_install() {
	kde_src_install

	# As much as I respect Ian, I'd rather leave Amarok to use mongrel
	# from Portage, for security and policy reasons.
	rm -rf "${D}"/usr/share/apps/amarok/ruby_lib/rbconfig \
		"${D}"/usr/share/apps/amarok/ruby_lib/mongrel* \
		"${D}"/usr/share/apps/amarok/ruby_lib/rubygems* \
		"${D}"/usr/share/apps/amarok/ruby_lib/gem* \
		"${D}"/usr/$(get_libdir)/ruby_lib

	if ! use python; then
		rm -r "${D}"/usr/share/apps/amarok/scripts/webcontrol \
			|| die "Unable to remove webcontrol."
	fi
}



-- 
gentoo-commits@g.o mailing list