[gentoo-commits] gentoo-x86 commit in x11-drivers/xf86-input-virtualbox: ChangeLog xf86-input-virtualbox-3.0.6.ebuild

[Patrick Lauer (patrick)]

patrick     09/09/10 20:04:00

  Modified:             ChangeLog
  Added:                xf86-input-virtualbox-3.0.6.ebuild
  Log:
  Bump to 3.0.6, thanks to Alessio Cassiba. Fixes #284407
  (Portage version: 2.2_rc40/cvs/Linux x86_64)

Revision  Changes    Path
1.16                 x11-drivers/xf86-input-virtualbox/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-drivers/xf86-input-virtualbox/ChangeLog?rev=1.16&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-drivers/xf86-input-virtualbox/ChangeLog?rev=1.16&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-drivers/xf86-input-virtualbox/ChangeLog?r1=1.15&r2=1.16

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-drivers/xf86-input-virtualbox/ChangeLog,v
retrieving revision 1.15
retrieving revision 1.16
diff -u -r1.15 -r1.16
--- ChangeLog	17 Aug 2009 14:32:07 -0000	1.15
+++ ChangeLog	10 Sep 2009 20:04:00 -0000	1.16
@@ -1,6 +1,13 @@
 # ChangeLog for x11-drivers/xf86-input-virtualbox
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-drivers/xf86-input-virtualbox/ChangeLog,v 1.15 2009/08/17 14:32:07 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-drivers/xf86-input-virtualbox/ChangeLog,v 1.16 2009/09/10 20:04:00 patrick Exp $
+
+*xf86-input-virtualbox-3.0.6 (10 Sep 2009)
+
+  10 Sep 2009; Patrick Lauer <patrick@g.o>
+  files/xf86-input-virtualbox-2-localconfig,
+  +xf86-input-virtualbox-3.0.6.ebuild:
+  Bump to 3.0.6, thanks to Alessio Cassiba. Fixes #284407
 
 *xf86-input-virtualbox-3.0.4 (17 Aug 2009)
 



1.1                  x11-drivers/xf86-input-virtualbox/xf86-input-virtualbox-3.0.6.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-drivers/xf86-input-virtualbox/xf86-input-virtualbox-3.0.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-drivers/xf86-input-virtualbox/xf86-input-virtualbox-3.0.6.ebuild?rev=1.1&content-type=text/plain

Index: xf86-input-virtualbox-3.0.6.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-drivers/xf86-input-virtualbox/xf86-input-virtualbox-3.0.6.ebuild,v 1.1 2009/09/10 20:04:00 patrick Exp $

EAPI=2

inherit x-modular eutils multilib

MY_P=VirtualBox-${PV}-OSE
DESCRIPTION="VirtualBox input driver"
HOMEPAGE="http://www.virtualbox.org/"
SRC_URI="http://download.virtualbox.org/virtualbox/${PV}/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="hal"

RDEPEND="x11-base/xorg-server
		hal? ( sys-apps/hal )"
DEPEND="${RDEPEND}
		>=dev-util/kbuild-0.1.5-r1
		>=dev-lang/yasm-0.6.2
		sys-devel/dev86
		sys-power/iasl
		x11-proto/inputproto
		x11-proto/randrproto
		x11-proto/xproto"

S=${WORKDIR}/${MY_P/-OSE/_OSE}

src_prepare() {
		# Remove shipped binaries (kBuild,yasm), see bug #232775
		rm -rf kBuild/bin tools

		# Disable things unused or splitted into separate ebuilds
		cp "${FILESDIR}/${PN}-2-localconfig" LocalConfig.kmk
}

src_configure() {
		# build the user-space tools, warnings are harmless
		./configure --nofatal \
		--disable-xpcom \
		--disable-sdl-ttf \
		--disable-pulse \
		--disable-alsa \
		--build-headless || die "configure failed"
		source ./env.sh
}

src_compile() {
		for each in /src/VBox/{Runtime,Additions/common/VBoxGuestLib} \
		/src/VBox/Additions/x11/vboxmouse ; do
			cd "${S}"${each}
			MAKE="kmk" emake TOOL_YASM_AS=yasm \
			KBUILD_PATH="${S}/kBuild" \
			|| die "kmk failed"
		done
}

src_install() {
		cd "${S}/out/linux.${ARCH}/release/bin/additions"
		insinto /usr/$(get_libdir)/xorg/modules/input

		# xorg-server-1.6.x
		if has_version ">=x11-base/xorg-server-1.6" ; then
				newins vboxmouse_drv_16.so vboxmouse_drv.so
		# xorg-server-1.5.x
		else
				newins vboxmouse_drv_15.so vboxmouse_drv.so
		fi

		# install hal information file about the mouse driver
		if use hal; then
			cd "${S}/src/VBox/Additions/linux/installer"
			insinto /usr/share/hal/fdi/information/20thirdparty
			doins 90-vboxguest.fdi
		fi
}

pkg_postinst() {
		elog "You need to edit the file /etc/X11/xorg.conf and set:"
		elog ""
		elog "	Driver  \"vboxmouse\""
		elog ""
		elog "in the Core Pointer's InputDevice section (Section \"InputDevice\")"
		elog ""
		if has_version ">=x11-base/xorg-server-1.5" ; then
			elog "Starting with 1.5 version, X.Org Server can do mouse auto-detection"
			elog "you may install the hal information file about the mouse driver:"
			elog ""
			elog "/usr/share/hal/fdi/information/20thirdparty/90-vboxguest.fdi"
			elog ""
			elog "dropping it into: /etc/hal/fdi/policy/"
			elog ""
		fi
}