[gentoo-commits] gentoo-x86 commit in net-misc/chrony: ChangeLog chrony-1.23.ebuild

[Torsten Veller (tove)]

tove        07/12/02 17:56:44

  Modified:             ChangeLog
  Added:                chrony-1.23.ebuild
  Log:
  Version bump
  (Portage version: 2.1.4_rc4)

Revision  Changes    Path
1.38                 net-misc/chrony/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/chrony/ChangeLog?rev=1.38&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/chrony/ChangeLog?rev=1.38&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/chrony/ChangeLog?r1=1.37&r2=1.38

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/chrony/ChangeLog,v
retrieving revision 1.37
retrieving revision 1.38
diff -u -r1.37 -r1.38
--- ChangeLog	20 Aug 2007 12:55:42 -0000	1.37
+++ ChangeLog	2 Dec 2007 17:56:44 -0000	1.38
@@ -1,6 +1,11 @@
 # ChangeLog for net-misc/chrony
 # Copyright 2002-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/chrony/ChangeLog,v 1.37 2007/08/20 12:55:42 tove Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/chrony/ChangeLog,v 1.38 2007/12/02 17:56:44 tove Exp $
+
+*chrony-1.23 (02 Dec 2007)
+
+  02 Dec 2007; Torsten Veller <tove@g.o> +chrony-1.23.ebuild:
+  Version bump.
 
   20 Aug 2007; Torsten Veller <tove@g.o> files/chronyd.conf:
   Fix bug #189037



1.1                  net-misc/chrony/chrony-1.23.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/chrony/chrony-1.23.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/chrony/chrony-1.23.ebuild?rev=1.1&content-type=text/plain

Index: chrony-1.23.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/chrony/chrony-1.23.ebuild,v 1.1 2007/12/02 17:56:44 tove Exp $

inherit eutils toolchain-funcs

MY_P=${P/_pre/-pre}
S=${WORKDIR}/${MY_P}

DESCRIPTION="NTP client and server programs"
HOMEPAGE="http://chrony.sunsite.dk/"
SRC_URI="http://chrony.sunsite.dk/download/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~hppa ~mips ~ppc ~sparc ~x86"
IUSE="readline"

DEPEND="readline? ( >=sys-libs/readline-4.1-r4 )"

src_unpack() {
	unpack ${A} ; cd "${S}"
	epatch "${FILESDIR}"/${PN}-1.20-conf.c-gentoo.diff
	epatch "${FILESDIR}"/${PN}-1.20-chrony.conf.example-gentoo.diff
	epatch "${FILESDIR}"/${PN}-1.21-makefile.diff

	sed -i "s:/etc/chrony:/etc/chrony/chrony:g" \
		chrony*.{1,5,8} faq.txt chrony.texi || die "sed failed"
	epatch "${FILESDIR}"/${PN}-1.21-hppa.patch
}

src_compile() {
	tc-export CC
	local myconf
	# selfwritten configure
	use readline || myconf="--disable-readline"
	./configure --prefix=/usr \
			--infodir=/usr/share/info \
			--mandir=/usr/share/man \
			${myconf} ${EXTRA_ECONF} || die "configure failed"
	emake all || die "make failed"
	emake docs || die "make docs failed"
}

src_install() {
	dobin chronyc || die
	dosbin chronyd || die

	dodoc chrony.txt README examples/chrony.{conf,keys}.example || die
	dohtml chrony.html || die
	doman *.{1,5,8}
	doinfo chrony.info*

	newinitd "${FILESDIR}"/chronyd.rc chronyd || die
	dosed "s:the documentation directory:/usr/share/doc/${PF}/:" \
		/etc/init.d/chronyd || die "doc sed failed"
	newconfd "${FILESDIR}"/chronyd.conf chronyd || die

	keepdir /var/{lib,log}/chrony /etc/chrony
}



-- 
gentoo-commits@g.o mailing list