[gentoo-commits] gentoo-x86 commit in gnome-extra/gnome-do-plugins: gnome-do-plugins-0.8.1.3-r2.ebuild ChangeLog

[Hans de Graaff (graaff)]

graaff      09/06/21 12:01:46

  Modified:             ChangeLog
  Added:                gnome-do-plugins-0.8.1.3-r2.ebuild
  Log:
  Fix twitter ID bug.
  (Portage version: 2.1.6.13/cvs/Linux x86_64)

Revision  Changes    Path
1.12                 gnome-extra/gnome-do-plugins/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-extra/gnome-do-plugins/ChangeLog?rev=1.12&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-extra/gnome-do-plugins/ChangeLog?rev=1.12&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-extra/gnome-do-plugins/ChangeLog?r1=1.11&r2=1.12

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/gnome-do-plugins/ChangeLog,v
retrieving revision 1.11
retrieving revision 1.12
diff -u -r1.11 -r1.12
--- ChangeLog	31 May 2009 09:54:31 -0000	1.11
+++ ChangeLog	21 Jun 2009 12:01:46 -0000	1.12
@@ -1,6 +1,13 @@
 # ChangeLog for gnome-extra/gnome-do-plugins
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-do-plugins/ChangeLog,v 1.11 2009/05/31 09:54:31 graaff Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-do-plugins/ChangeLog,v 1.12 2009/06/21 12:01:46 graaff Exp $
+
+*gnome-do-plugins-0.8.1.3-r2 (21 Jun 2009)
+
+  21 Jun 2009; Hans de Graaff <graaff@g.o>
+  +gnome-do-plugins-0.8.1.3-r2.ebuild,
+  +files/gnome-do-plugins-0.8.1.3-fix-for-twitpocolypse.patch:
+  Fix Microblogging plugin for Twitter ID rollover, taken from upstream bzr.
 
 *gnome-do-plugins-0.8.1.3-r1 (31 May 2009)
 



1.1                  gnome-extra/gnome-do-plugins/gnome-do-plugins-0.8.1.3-r2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-extra/gnome-do-plugins/gnome-do-plugins-0.8.1.3-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-extra/gnome-do-plugins/gnome-do-plugins-0.8.1.3-r2.ebuild?rev=1.1&content-type=text/plain

Index: gnome-do-plugins-0.8.1.3-r2.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-do-plugins/gnome-do-plugins-0.8.1.3-r2.ebuild,v 1.1 2009/06/21 12:01:46 graaff Exp $

inherit eutils autotools gnome2 mono versionator

MY_PN="do-plugins"
PVC=$(get_version_component_range 1-3)

DESCRIPTION="Plugins to put the Do in Gnome Do"
HOMEPAGE="http://do.davebsd.com/"
SRC_URI="https://launchpad.net/${MY_PN}/0.8/${PVC}/+download/${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="banshee evo"

RDEPEND=">=gnome-extra/gnome-do-${PV}
		dev-dotnet/wnck-sharp
		banshee? ( >=media-sound/banshee-1.4.2 )
		evo? ( dev-dotnet/evolution-sharp )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	dev-util/monodevelop"

src_unpack() {
	unpack ${A}
	cd "${S}"

	# Fix use of Twitter API in Microblogging plugin.
	epatch "${FILESDIR}/${P}-update-twitter-api.patch"
	# Fix handling of Twitter id's in Microblogging plugin.
	epatch "${FILESDIR}/${P}-fix-for-twitpocolypse.patch"

	sed -i -r -e "/(FLICKR|Flickr)/d" configure.ac Makefile.am
	use banshee || sed -i -r -e "/(BANSHEE|Banshee)/d" configure.ac Makefile.am
	use evo     || sed -i -r -e "/(EVOLUTION|Evolution)/d" configure.ac Makefile.am
	eautoreconf
}

src_compile()
{
	econf --enable-debug=no --enable-release=yes || die "configure failed"
	# The make system is unfortunately broken for parallel builds and
	# upstream indicated on IRC that they have no intention to fix
	# that.
	emake -j1 || die "make failed"
}

pkg_postinst()
{
	ewarn "Plugin handling has changed since gnome-do 0.4."
	ewarn "If you install the gnome-do-plugins package you will have local copies"
	ewarn "of the plugins, but you still need to manually enable them in Preferences."
	ewarn "Also note that plugins installed from upstream may not be compatible with"
	ewarn "your system. When in doubt check the output from gnome-do itself".
	ewarn "Old plugins may not be compatible either."
	ewarn "Check ~/.local/share/gnome-do/ if you have problems with plugins."

	# To be removed when bumping from 0.8.1.3
	ewarn
	ewarn "This revision contains an update for the Microblogging.dll plugin."
	ewarn "You will need to copy the updated version from /usr/share/gnome-do/plugins"
	ewarn "to ~/.local/share/gnome-do/plugins-${PV}/addins/Do.Microblog.1.0/ manually"
}