[gentoo-commits] gentoo-x86 commit in dev-python/routes: ChangeLog routes-2.0.ebuild

[Tim Harder (radhermit)]

radhermit    13/11/21 20:53:58

  Modified:             ChangeLog
  Added:                routes-2.0.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

Revision  Changes    Path
1.18                 dev-python/routes/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/routes/ChangeLog?rev=1.18&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/routes/ChangeLog?rev=1.18&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/routes/ChangeLog?r1=1.17&r2=1.18

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/routes/ChangeLog,v
retrieving revision 1.17
retrieving revision 1.18
diff -u -r1.17 -r1.18
--- ChangeLog	22 Oct 2013 14:24:30 -0000	1.17
+++ ChangeLog	21 Nov 2013 20:53:58 -0000	1.18
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/routes
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/routes/ChangeLog,v 1.17 2013/10/22 14:24:30 grobian Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/routes/ChangeLog,v 1.18 2013/11/21 20:53:58 radhermit Exp $
+
+*routes-2.0 (21 Nov 2013)
+
+  21 Nov 2013; Tim Harder <radhermit@g.o> +routes-2.0.ebuild,
+  +files/routes-2.0-tests-py3.patch:
+  Version bump.
 
   22 Oct 2013; Fabian Groffen <grobian@g.o> routes-1.13-r1.ebuild:
   Marked ~x64-macos, bug #487670



1.1                  dev-python/routes/routes-2.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/routes/routes-2.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/routes/routes-2.0.ebuild?rev=1.1&content-type=text/plain

Index: routes-2.0.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/routes/routes-2.0.ebuild,v 1.1 2013/11/21 20:53:58 radhermit Exp $

EAPI=5
PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} )

inherit distutils-r1

MY_PN="Routes"
MY_P="${MY_PN}-${PV}"

DESCRIPTION="A Python re-implementation of the Rails routes system for mapping URL's to Controllers/Actions"
HOMEPAGE="http://routes.groovie.org http://pypi.python.org/pypi/Routes"
SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
IUSE="doc test"

RDEPEND="dev-python/webob[${PYTHON_USEDEP}]
	>=dev-python/repoze-lru-0.3[${PYTHON_USEDEP}]"
DEPEND="${RDEPEND}
	dev-python/setuptools[${PYTHON_USEDEP}]
	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
	test? (
		dev-python/coverage[${PYTHON_USEDEP}]
		dev-python/nose[${PYTHON_USEDEP}]
		dev-python/webtest[${PYTHON_USEDEP}]
	)"

S="${WORKDIR}/${MY_P}"

PATCHES=( "${FILESDIR}"/${PN}-2.0-tests-py3.patch )

python_prepare_all() {
	use test && DISTUTILS_IN_SOURCE_BUILD=1
	distutils-r1_python_prepare_all
}

python_compile_all() {
	use doc && emake -C docs html
}

python_test() {
	cp -r tests "${BUILD_DIR}" || die
	if [[ ${EPYTHON} == python3* ]]; then
		2to3 -w --no-diffs "${BUILD_DIR}"/tests || die
	fi

	nosetests -w "${BUILD_DIR}"/tests || die "Tests fail with ${EPYTHON}"
}

python_install_all() {
	use doc && local HTML_DOCS=( docs/_build/html/. )
	distutils-r1_python_install_all
}