[gentoo-commits] gentoo-x86 commit in games-puzzle/neverball: ChangeLog neverball-1.5.3.ebuild

[Michael Sterrett (mr_bones_)]

mr_bones_    09/09/09 16:04:21

  Modified:             ChangeLog
  Added:                neverball-1.5.3.ebuild
  Log:
  version bump
  (Portage version: 2.1.6.13/cvs/Linux i686)

Revision  Changes    Path
1.37                 games-puzzle/neverball/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-puzzle/neverball/ChangeLog?rev=1.37&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-puzzle/neverball/ChangeLog?rev=1.37&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-puzzle/neverball/ChangeLog?r1=1.36&r2=1.37

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-puzzle/neverball/ChangeLog,v
retrieving revision 1.36
retrieving revision 1.37
diff -u -r1.36 -r1.37
--- ChangeLog	17 Aug 2009 19:09:20 -0000	1.36
+++ ChangeLog	9 Sep 2009 16:04:21 -0000	1.37
@@ -1,6 +1,12 @@
 # ChangeLog for games-puzzle/neverball
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-puzzle/neverball/ChangeLog,v 1.36 2009/08/17 19:09:20 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-puzzle/neverball/ChangeLog,v 1.37 2009/09/09 16:04:21 mr_bones_ Exp $
+
+*neverball-1.5.3 (09 Sep 2009)
+
+  09 Sep 2009; Michael Sterrett <mr_bones_@g.o>
+  +neverball-1.5.3.ebuild:
+  version bump
 
   17 Aug 2009; Michael Sterrett <mr_bones_@g.o>
   neverball-1.5.2.ebuild:



1.1                  games-puzzle/neverball/neverball-1.5.3.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-puzzle/neverball/neverball-1.5.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-puzzle/neverball/neverball-1.5.3.ebuild?rev=1.1&content-type=text/plain

Index: neverball-1.5.3.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-puzzle/neverball/neverball-1.5.3.ebuild,v 1.1 2009/09/09 16:04:21 mr_bones_ Exp $

EAPI=2
inherit eutils games

DESCRIPTION="Clone of Super Monkey Ball using SDL/OpenGL"
HOMEPAGE="http://icculus.org/neverball/"
SRC_URI="http://icculus.org/neverball/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="nls"
RESTRICT="test"

RDEPEND="media-libs/libsdl[joystick]
	media-libs/sdl-ttf
	media-libs/libpng
	media-libs/jpeg
	media-libs/libvorbis
	virtual/opengl
	dev-games/physfs
	media-fonts/dejavu
	nls? ( virtual/libintl )"
DEPEND="${RDEPEND}
	sys-devel/gettext"

src_prepare() {
	sed -i \
		-e 's:mapc:neverball-mapc:g' \
		-e 's:MAPC:NEVERBALL-MAPC:g' \
		-e '1 s/ 1 / 6 /' \
		dist/mapc.1 \
		|| die "sed failed"
	sed -i \
		-e 's:-O2:$(E_CFLAGS):' \
		-e "/^MAPC_TARG/s/mapc/${PN}-mapc/" \
		Makefile \
		|| die "sed failed"
	sed -i \
		-e "s/LOCALEDIR/LLOCALEDIR/g" \
		po/Makefile \
		|| die "sed failed"
}

src_compile() {
	LINGUAS= \
	emake \
		ENABLE_NLS=$(use nls && echo 1 || echo 0) \
		E_CFLAGS="${CFLAGS}" \
		LOCALEDIR=/usr/share/locale \
		DATADIR="${GAMES_DATADIR}/${PN}" \
		|| die "emake failed"
}

src_install() {
	dogamesbin ${PN}-mapc neverball neverputt || die "dogamesbin failed"
	insinto "${GAMES_DATADIR}/${PN}"
	doins -r data/* || die "doins failed"
	rm -f "${D}${GAMES_DATADIR}/${PN}"/ttf/DejaVuSans-Bold.ttf
	dosym /usr/share/fonts/dejavu/DejaVuSans-Bold.ttf "${GAMES_DATADIR}/${PN}"/ttf/
	if use nls ; then
		insinto /usr/share
		doins -r locale || die "doins failed"
	fi
	dodoc CHANGES README

	newicon dist/neverball_512.png neverball.png
	newicon dist/neverputt_512.png neverputt.png
	doman dist/*.6
	newman dist/mapc.1 neverball-mapc.6
	make_desktop_entry neverball Neverball
	make_desktop_entry neverputt Neverputt neverputt

	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst
	elog "${P} will overwrite existing high-score files, so back them up if you want to preserve your old scores and progress."
}