[gentoo-commits] gentoo-x86 commit in net-libs/libsoup: ChangeLog libsoup-2.30.2-r1.ebuild libsoup-2.28.2-r1.ebuild

[Jonathan Callen (abcd)]

abcd        10/07/01 22:43:22

  Modified:             ChangeLog
  Added:                libsoup-2.30.2-r1.ebuild libsoup-2.28.2-r1.ebuild
  Log:
  Add fix for new versions of gnutls (bug #307343, GNOME bug #622857)
  (Portage version: 2.2_rc67/cvs/Linux i686)

Revision  Changes    Path
1.221                net-libs/libsoup/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libsoup/ChangeLog?rev=1.221&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libsoup/ChangeLog?rev=1.221&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libsoup/ChangeLog?r1=1.220&r2=1.221

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/libsoup/ChangeLog,v
retrieving revision 1.220
retrieving revision 1.221
diff -u -r1.220 -r1.221
--- ChangeLog	23 Jun 2010 11:46:31 -0000	1.220
+++ ChangeLog	1 Jul 2010 22:43:22 -0000	1.221
@@ -1,6 +1,13 @@
 # ChangeLog for net-libs/libsoup
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/libsoup/ChangeLog,v 1.220 2010/06/23 11:46:31 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libsoup/ChangeLog,v 1.221 2010/07/01 22:43:22 abcd Exp $
+
+*libsoup-2.30.2-r1 (01 Jul 2010)
+*libsoup-2.28.2-r1 (01 Jul 2010)
+
+  01 Jul 2010; Jonathan Callen <abcd@g.o> +libsoup-2.28.2-r1.ebuild,
+  +libsoup-2.30.2-r1.ebuild, +files/libsoup-2.30.2-disable-tls1.2.patch:
+  Add fix for new versions of gnutls (bug #307343, GNOME bug #622857)
 
 *libsoup-2.30.2 (23 Jun 2010)
 



1.1                  net-libs/libsoup/libsoup-2.30.2-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libsoup/libsoup-2.30.2-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libsoup/libsoup-2.30.2-r1.ebuild?rev=1.1&content-type=text/plain

Index: libsoup-2.30.2-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/libsoup/libsoup-2.30.2-r1.ebuild,v 1.1 2010/07/01 22:43:22 abcd Exp $

EAPI="2"

inherit autotools eutils gnome2

DESCRIPTION="An HTTP library implementation in C"
HOMEPAGE="http://www.gnome.org/"
SRC_URI="${SRC_URI}
	mirror://gentoo/${PN}-2.30.1-build-gir-patches.tar.bz2"

LICENSE="LGPL-2"
SLOT="2.4"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
# Do NOT build with --disable-debug/--enable-debug=no - gnome2.eclass takes care of that
IUSE="debug doc +introspection gnome ssl"

RDEPEND=">=dev-libs/glib-2.21.3
	>=dev-libs/libxml2-2
	introspection? ( >=dev-libs/gobject-introspection-0.6.7 )
	ssl? ( >=net-libs/gnutls-2.1.7 )"
DEPEND="${RDEPEND}
	>=dev-util/pkgconfig-0.9
	dev-util/gtk-doc-am
	doc? ( >=dev-util/gtk-doc-1 )"
#	test? (
#		www-servers/apache
#		dev-lang/php
#		net-misc/curl )
PDEPEND="gnome? ( ~net-libs/${PN}-gnome-${PV} )"

DOCS="AUTHORS NEWS README"

pkg_setup() {
	G2CONF="${G2CONF}
		--disable-static
		--without-gnome
		$(use_enable introspection)
		$(use_enable ssl)"
}

src_prepare() {
	gnome2_src_prepare

	# Fix test to follow POSIX (for x86-fbsd)
	# No patch to prevent having to eautoreconf
	sed -e 's/\(test.*\)==/\1=/g' -i configure.ac configure || die "sed failed"

	# Patch *must* be applied conditionally (see patch for details)
	if use doc; then
		# Fix bug 268592 (build fails !gnome && doc)
		epatch "${FILESDIR}/${PN}-2.30.1-fix-build-without-gnome-with-doc.patch"
	fi

	if use introspection; then
		epatch "${WORKDIR}/${PN}-2.30.1-build-gir-1.patch"
		epatch "${WORKDIR}/${PN}-2.30.1-build-gir-2.patch"
	fi

	# Fix for new versions of gnutls (bug #307343, GNOME bug #622857)
	epatch "${FILESDIR}/${P}-disable-tls1.2.patch"

	eautoreconf
}



1.1                  net-libs/libsoup/libsoup-2.28.2-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libsoup/libsoup-2.28.2-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libsoup/libsoup-2.28.2-r1.ebuild?rev=1.1&content-type=text/plain

Index: libsoup-2.28.2-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/libsoup/libsoup-2.28.2-r1.ebuild,v 1.1 2010/07/01 22:43:22 abcd Exp $

EAPI="2"

inherit autotools eutils gnome2

DESCRIPTION="An HTTP library implementation in C"
HOMEPAGE="http://www.gnome.org/"

LICENSE="LGPL-2"
SLOT="2.4"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
# Do NOT build with --disable-debug/--enable-debug=no - gnome2.eclass takes care of that
IUSE="debug doc gnome ssl"

RDEPEND=">=dev-libs/glib-2.21.3
	>=dev-libs/libxml2-2
	ssl? ( >=net-libs/gnutls-2.1.7 )"
DEPEND="${RDEPEND}
	>=dev-util/pkgconfig-0.9
	dev-util/gtk-doc-am
	doc? ( >=dev-util/gtk-doc-1 )"
#	test? (
#		www-servers/apache
#		dev-lang/php
#		net-misc/curl )
PDEPEND="gnome? ( ~net-libs/${PN}-gnome-${PV} )"

DOCS="AUTHORS NEWS README"

pkg_setup() {
	G2CONF="${G2CONF}
		--disable-static
		--without-gnome
		$(use_enable ssl)"
}

src_prepare() {
	gnome2_src_prepare

	# Fix test to follow POSIX (for x86-fbsd)
	# No patch to prevent having to eautoreconf
	sed -e 's/\(test.*\)==/\1=/g' -i configure.in configure || die "sed failed"

	# Patch *must* be applied conditionally (see patch for details)
	if use doc; then
		# Fix bug 268592 (build fails !gnome && doc)
		epatch "${FILESDIR}/${PN}-2.26.3-fix-build-without-gnome-with-doc.patch"
		eautoreconf
	fi

	# Fix for new versions of gnutls (bug #307343, GNOME bug #622857)
	epatch "${FILESDIR}/${PN}-2.30.2-disable-tls1.2.patch"
}