[gentoo-commits] gentoo-x86 commit in x11-misc/pcmanfm: ChangeLog pcmanfm-0.9.9_pre20110202.ebuild pcmanfm-0.9.8.ebuild

[Markos Chandras (hwoarang)]

hwoarang    11/02/02 22:18:03

  Modified:             ChangeLog
  Added:                pcmanfm-0.9.9_pre20110202.ebuild
  Removed:              pcmanfm-0.9.8.ebuild
  Log:
  Introduce snapshot. Remove old broken version
  
  (Portage version: 2.2.0_alpha19/cvs/Linux x86_64)

Revision  Changes    Path
1.46                 x11-misc/pcmanfm/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/pcmanfm/ChangeLog?rev=1.46&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/pcmanfm/ChangeLog?rev=1.46&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/pcmanfm/ChangeLog?r1=1.45&r2=1.46

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-misc/pcmanfm/ChangeLog,v
retrieving revision 1.45
retrieving revision 1.46
diff -u -r1.45 -r1.46
--- ChangeLog	22 Jan 2011 13:35:01 -0000	1.45
+++ ChangeLog	2 Feb 2011 22:18:03 -0000	1.46
@@ -1,6 +1,12 @@
 # ChangeLog for x11-misc/pcmanfm
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/pcmanfm/ChangeLog,v 1.45 2011/01/22 13:35:01 xarthisius Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/pcmanfm/ChangeLog,v 1.46 2011/02/02 22:18:03 hwoarang Exp $
+
+*pcmanfm-0.9.9_pre20110202 (02 Feb 2011)
+
+  02 Feb 2011; Markos Chandras <hwoarang@g.o> -pcmanfm-0.9.8.ebuild,
+  +pcmanfm-0.9.9_pre20110202.ebuild:
+  Introduce snapshot. Remove old broken version
 
   22 Jan 2011; Kacper Kowalik <xarthisius@g.o>
   pcmanfm-0.9.7-r2.ebuild:



1.1                  x11-misc/pcmanfm/pcmanfm-0.9.9_pre20110202.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/pcmanfm/pcmanfm-0.9.9_pre20110202.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/pcmanfm/pcmanfm-0.9.9_pre20110202.ebuild?rev=1.1&content-type=text/plain

Index: pcmanfm-0.9.9_pre20110202.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/pcmanfm/pcmanfm-0.9.9_pre20110202.ebuild,v 1.1 2011/02/02 22:18:03 hwoarang Exp $

EAPI=2

if [[ ${PV} == 9999 ]]; then
	EGIT_REPO_URI="git://pcmanfm.git.sourceforge.net/gitroot/pcmanfm/${PN}"
	inherit autotools git
	SRC_URI=""
else
	inherit autotools
	SRC_URI="http://dev.gentoo.org/~hwoarang/distfiles/${P}.tar.gz"
	KEYWORDS="~amd64 ~arm ~ppc ~x86"
fi

inherit fdo-mime

DESCRIPTION="Fast lightweight tabbed filemanager"
HOMEPAGE="http://pcmanfm.sourceforge.net/"

LICENSE="GPL-2"
SLOT="0"
IUSE="debug"

COMMON_DEPEND=">=dev-libs/glib-2.18:2
	>=x11-libs/gtk+-2.16:2
	>=lxde-base/menu-cache-0.3.2
	>=x11-libs/libfm-0.1.15_pre20110202"
RDEPEND="${COMMON_DEPEND}
	virtual/eject"
DEPEND="${COMMON_DEPEND}
	>=dev-util/intltool-0.40
	dev-util/pkgconfig
	sys-devel/gettext"

src_prepare() {
	intltoolize --force --copy --automake || die
	eautoreconf
}

src_configure() {
	econf \
		--sysconfdir=/etc \
		$(use_enable debug)
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodoc AUTHORS
}

pkg_postinst() {
	fdo-mime_desktop_database_update

	elog 'PCmanFM can optionally support the menu://applications/ location.'
	elog 'You should install lxde-base/lxmenu-data for that	functionality.'
}

pkg_postrm() {
	fdo-mime_desktop_database_update
}