[gentoo-commits] gentoo-x86 commit in app-text/apvlv: ChangeLog apvlv-0.1.1.ebuild

[Tim Harder (radhermit)]

radhermit    11/01/31 21:06:18

  Modified:             ChangeLog
  Added:                apvlv-0.1.1.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.0_alpha19/cvs/Linux x86_64)

Revision  Changes    Path
1.10                 app-text/apvlv/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/apvlv/ChangeLog?rev=1.10&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/apvlv/ChangeLog?rev=1.10&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/apvlv/ChangeLog?r1=1.9&r2=1.10

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-text/apvlv/ChangeLog,v
retrieving revision 1.9
retrieving revision 1.10
diff -u -r1.9 -r1.10
--- ChangeLog	17 Jan 2011 23:47:21 -0000	1.9
+++ ChangeLog	31 Jan 2011 21:06:18 -0000	1.10
@@ -1,6 +1,11 @@
 # ChangeLog for app-text/apvlv
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/apvlv/ChangeLog,v 1.9 2011/01/17 23:47:21 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-text/apvlv/ChangeLog,v 1.10 2011/01/31 21:06:18 radhermit Exp $
+
+*apvlv-0.1.1 (31 Jan 2011)
+
+  31 Jan 2011; Tim Harder <radhermit@g.o> +apvlv-0.1.1.ebuild:
+  Version bump
 
 *apvlv-0.1.0 (17 Jan 2011)
 



1.1                  app-text/apvlv/apvlv-0.1.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/apvlv/apvlv-0.1.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/apvlv/apvlv-0.1.1.ebuild?rev=1.1&content-type=text/plain

Index: apvlv-0.1.1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-text/apvlv/apvlv-0.1.1.ebuild,v 1.1 2011/01/31 21:06:18 radhermit Exp $

EAPI=3

inherit eutils cmake-utils

MY_P="${P}-Source"
DESCRIPTION="Alf's PDF Viewer Like Vim"
HOMEPAGE="http://code.google.com/p/apvlv/"
SRC_URI="http://apvlv.googlecode.com/files/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug djvu"

RDEPEND=">=x11-libs/gtk+-2.10.4:2
	>=app-text/poppler-0.12.3-r3[cairo]
	djvu? ( app-text/djvu )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

S="${WORKDIR}/${MY_P}"

src_prepare() {
	# bug #349979
	has_version ">=app-text/poppler-0.15.0" && epatch "${FILESDIR}"/${PN}-0.1.0-poppler-0.16.patch

	# Remove prefixes so it works with the cmake-utils eclass
	sed -i -e "s:APVLV_::" CMakeLists.txt src/CMakeLists.txt
}

src_configure() {
	mycmakeargs=(
		-DSYSCONFDIR=/etc/${PN}
		-DDOCDIR=/usr/share/doc/${PF}
		-DMANDIR=/usr/share/man
		-DWITH_UMD=OFF
		$(cmake-utils_use_enable debug)
		$(cmake-utils_use_with djvu)
	)

	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install
	dodoc AUTHORS NEWS README THANKS TODO
	newicon icons/pdf.png ${PN}.png
	make_desktop_entry ${PN} "Alf's PDF Viewer Like Vim" ${PN} "Office;Viewer"
}