[gentoo-commits] repo/gentoo:master commit in: sys-apps/fwupd/

[Lars Wendler]

commit:     b0eb30985a96cbebcef9c077cb9c4e65a9d28fb8
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Mon Feb 25 20:50:10 2019 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Mon Feb 25 20:50:10 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b0eb3098

sys-apps/fwupd: Bump to version 1.2.5

Closes: https://bugs.gentoo.org/678748
Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>

 sys-apps/fwupd/Manifest           |   1 +
 sys-apps/fwupd/fwupd-1.2.5.ebuild | 136 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 137 insertions(+)

diff --git a/sys-apps/fwupd/Manifest b/sys-apps/fwupd/Manifest
index d70e388c67f..3278af111ed 100644
--- a/sys-apps/fwupd/Manifest
+++ b/sys-apps/fwupd/Manifest
@@ -1 +1,2 @@
 DIST fwupd-1.2.4.tar.gz 1808778 BLAKE2B 4dd8db0e73b148cba8ca43ec7942efa183f331a376b947421b8673d473ef868cef57e3abf4f50e031eb22f97fa8eb199b8bd7ef3b96efb598f842d0824c235a7 SHA512 7734be90459364c2e9ca35d9a9327e7becabe64cd0129d5c8f3cb4a95ef0195726c519862e843636952a3251ecea080907d1e6814c3037e9f90e8dde53b406ad
+DIST fwupd-1.2.5.tar.gz 1818559 BLAKE2B 0d30248bf3be093d3764624294fdd6e26b979560d70b47e67b3ca5f213177d807e749f5e30abd4d7d7d15e4be507103583834062b6a3243367169019e24a1bc7 SHA512 dc6a0def49225ce50bc89c3f76137497d4c8b71f94e42546fbf5221dc0af504ce6090f803ea9dca175f6166ff1341f6a3eab04652d744257c9e88dbd6875abc7

diff --git a/sys-apps/fwupd/fwupd-1.2.5.ebuild b/sys-apps/fwupd/fwupd-1.2.5.ebuild
new file mode 100644
index 00000000000..5ac027f9c0b
--- /dev/null
+++ b/sys-apps/fwupd/fwupd-1.2.5.ebuild
@@ -0,0 +1,136 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{4,5,6,7} )
+
+inherit meson python-single-r1 vala xdg-utils
+
+DESCRIPTION="Aims to make updating firmware on Linux automatic, safe and reliable"
+HOMEPAGE="https://fwupd.org"
+SRC_URI="https://github.com/hughsie/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="colorhug dell doc elogind +gpg +man nvme pkcs7 redfish systemd test thunderbolt uefi"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+	?? ( elogind systemd )
+	dell? ( uefi )
+"
+
+RDEPEND="${PYTHON_DEPS}
+	app-arch/gcab
+	app-arch/libarchive:=
+	dev-db/sqlite
+	>=dev-libs/glib-2.45.8:2
+	dev-libs/json-glib
+	dev-libs/libgpg-error
+	dev-libs/libgudev:=
+	>=dev-libs/libgusb-0.2.9[introspection]
+	>=dev-libs/libxmlb-0.1.5
+	dev-python/pillow[${PYTHON_USEDEP}]
+	dev-python/pycairo[${PYTHON_USEDEP}]
+	dev-python/pygobject:3[cairo,${PYTHON_USEDEP}]
+	>=net-libs/libsoup-2.51.92:2.4[introspection]
+	>=sys-auth/polkit-0.103
+	virtual/libelf:0=
+	colorhug? ( >=x11-misc/colord-1.2.12:0= )
+	dell? (
+		sys-libs/efivar
+		>=sys-libs/libsmbios-2.4.0
+	)
+	gpg? (
+		app-crypt/gpgme
+		dev-libs/libgpg-error
+	)
+	nvme? ( sys-libs/efivar )
+	pkcs7? ( >=net-libs/gnutls-3.4.4.1:= )
+	redfish? ( sys-libs/efivar )
+	!systemd? (
+		!elogind? ( >=sys-auth/consolekit-1.0.0 )
+		elogind? ( sys-auth/elogind )
+	)
+	systemd? ( >=sys-apps/systemd-211 )
+	thunderbolt? ( sys-apps/thunderbolt-software-user-space )
+	uefi? (
+		media-libs/fontconfig
+		media-libs/freetype
+		sys-boot/gnu-efi
+		>=sys-libs/efivar-33
+		x11-libs/cairo
+	)
+"
+DEPEND="${RDEPEND}
+	$(vala_depend)
+	x11-libs/pango[introspection]
+	nvme? (	>=sys-kernel/linux-headers-4.4 )
+	test? ( net-libs/gnutls[tools] )
+"
+BDEPEND="
+	>=dev-util/meson-0.47.0
+	virtual/pkgconfig
+	doc? ( dev-util/gtk-doc )
+	man? ( app-text/docbook-sgml-utils )
+"
+
+# required for fwupd daemon to run.
+# NOT a build time dependency. The build system does not check for dbus.
+PDEPEND="sys-apps/dbus"
+
+src_prepare() {
+	default
+	sed -e "s/'--create'/'--absolute-name', '--create'/" \
+		-i data/tests/builder/meson.build || die
+	sed -e "/'-Werror',/d" \
+		-i plugins/uefi/efi/meson.build || die
+	vala_src_prepare
+}
+
+src_configure() {
+	xdg_environment_reset
+	local emesonargs=(
+		--localstatedir "${EPREFIX}"/var
+		-Dgtkdoc="$(usex doc true false)"
+		-Delogind="$(usex elogind true false)"
+		-Dgpg="$(usex gpg true false)"
+		-Dman="$(usex man true false)"
+		-Dpkcs7="$(usex pkcs7 true false)"
+		-Dplugin_dell="$(usex dell true false)"
+		-Dplugin_nvme="$(usex nvme true false)"
+		-Dplugin_redfish="$(usex redfish true false)"
+		-Dplugin_synaptics="$(usex dell true false)"
+		-Dplugin_thunderbolt="$(usex thunderbolt true false)"
+		-Dplugin_uefi="$(usex uefi true false)"
+		-Dsystemd="$(usex systemd true false)"
+		-Dtests="$(usex test true false)"
+	)
+
+	if use elogind || use systemd ; then
+		emesonargs+=( -Dconsolekit=false )
+	else
+		emesonargs+=( -Dconsolekit=true )
+	fi
+
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	doinitd "${FILESDIR}"/${PN}
+
+	if ! use systemd ; then
+		# Don't timeout when fwupd is running (#673140)
+		sed '/^IdleTimeout=/s@=[[:digit:]]\+@=0@' \
+			-i "${ED}"/etc/${PN}/daemon.conf || die
+	fi
+}
+
+pkg_postinst() {
+	elog "In case you are using openrc as init system"
+	elog "and you're upgrading from <fwupd-1.1.0, you"
+	elog "need to start the fwupd daemon via the openrc"
+	elog "init script that comes with this package."
+}