[gentoo-commits] repo/gentoo:master commit in: media-libs/mlt/

[Andreas Sturmlechner]

commit:     d9fbc07c52a79f098897882fb2a4d2adf6350793
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Fri Jan 21 12:57:56 2022 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Fri Jan 21 12:57:56 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d9fbc07c

media-libs/mlt: Drop 7.2.0-r1

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 media-libs/mlt/Manifest            |   1 -
 media-libs/mlt/mlt-7.2.0-r1.ebuild | 156 -------------------------------------
 2 files changed, 157 deletions(-)

diff --git a/media-libs/mlt/Manifest b/media-libs/mlt/Manifest
index 4ca67b35101a..5f41e52d98ea 100644
--- a/media-libs/mlt/Manifest
+++ b/media-libs/mlt/Manifest
@@ -1,2 +1 @@
-DIST mlt-7.2.0.tar.gz 1203489 BLAKE2B 2b53a813146f4868469c945208b4e7b509f67667357df615954a7d0f02ebe809dba0c15acd302f9a8609978929d00dd1e20fb03fc5d29a7dd5196253f37f70b7 SHA512 cee8d6cef2db5aae5747a80a292eca29d25adedd7754ea88a1857b429c0ccd35f689bcd9381c069c0e9e04b9eae5b7301e7c9548c536b43e4a9d54af664d629f
 DIST mlt-7.4.0.tar.gz 1206316 BLAKE2B 56e6ea7a5545b80de45cffd206e555a577ada8e59f9b63c6487491e130ba7e4fdca5dc1b3836fcff22d49b6dcb048779dc8db1e9888b1137653c80196bdb81e2 SHA512 e9a65e76ca0a2464fb923d19d6f21bd49f13d637b0a974eeeb1e123ab753914d742e373f9fdcfe07cdeb9f39ebd2f0dde75a7299c0b6cd4807ee48ec710b3fd4

diff --git a/media-libs/mlt/mlt-7.2.0-r1.ebuild b/media-libs/mlt/mlt-7.2.0-r1.ebuild
deleted file mode 100644
index e0c70f26c65e..000000000000
--- a/media-libs/mlt/mlt-7.2.0-r1.ebuild
+++ /dev/null
@@ -1,156 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{8,9,10} )
-inherit python-single-r1 cmake
-
-DESCRIPTION="Open source multimedia framework for television broadcasting"
-HOMEPAGE="https://www.mltframework.org/"
-SRC_URI="https://github.com/mltframework/${PN}/releases/download/v${PV}/${P}.tar.gz"
-
-LICENSE="GPL-3"
-SLOT="0/7"
-KEYWORDS="amd64 arm64 ~ppc64 x86 ~amd64-linux ~x86-linux"
-IUSE="debug ffmpeg frei0r gtk jack libsamplerate opencv opengl python qt5 rtaudio rubberband sdl test vdpau vidstab xine xml"
-
-REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
-
-# Needs unpackaged 'kwalify'
-RESTRICT="test"
-
-# rtaudio will use OSS on non linux OSes
-# Qt already needs FFTW/PLUS so let's just always have it on to ensure
-# MLT is useful: bug #603168.
-DEPEND="
-	>=media-libs/libebur128-1.2.2:=
-	sci-libs/fftw:3.0=
-	ffmpeg? ( media-video/ffmpeg:0=[vdpau?,-flite] )
-	frei0r? ( media-plugins/frei0r-plugins )
-	gtk? (
-		media-libs/libexif
-		x11-libs/pango
-	)
-	jack? (
-		>=dev-libs/libxml2-2.5
-		media-libs/ladspa-sdk
-		virtual/jack
-	)
-	libsamplerate? ( >=media-libs/libsamplerate-0.1.2 )
-	opencv? ( >=media-libs/opencv-4.5.1:=[contrib] )
-	opengl? (
-		media-libs/libglvnd
-		media-video/movit
-	)
-	python? ( ${PYTHON_DEPS} )
-	qt5? (
-		dev-qt/qtcore:5
-		dev-qt/qtgui:5
-		dev-qt/qtsvg:5
-		dev-qt/qtwidgets:5
-		dev-qt/qtxml:5
-		media-libs/libexif
-		x11-libs/libX11
-	)
-	rtaudio? (
-		>=media-libs/rtaudio-4.1.2
-		kernel_linux? ( media-libs/alsa-lib )
-	)
-	rubberband? ( media-libs/rubberband )
-	sdl? (
-		media-libs/libsdl2[X,opengl,video]
-		media-libs/sdl2-image
-	)
-	vidstab? ( media-libs/vidstab )
-	xine? ( >=media-libs/xine-lib-1.1.2_pre20060328-r7 )
-	xml? ( >=dev-libs/libxml2-2.5 )
-"
-#	java? ( >=virtual/jre-1.8:* )
-#	perl? ( dev-lang/perl )
-#	php? ( dev-lang/php )
-#	ruby? ( ${RUBY_DEPS} )
-#	sox? ( media-sound/sox )
-#	tcl? ( dev-lang/tcl:0= )
-RDEPEND="${DEPEND}"
-BDEPEND="
-	virtual/pkgconfig
-	python? ( >=dev-lang/swig-2.0 )
-"
-
-DOCS=( AUTHORS NEWS README.md )
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-6.10.0-swig-underlinking.patch
-	"${FILESDIR}"/${PN}-6.22.1-no_lua_bdepend.patch
-	"${FILESDIR}"/${PN}-7.0.1-cmake-symlink.patch
-)
-
-pkg_setup() {
-	use python && python-single-r1_pkg_setup
-}
-
-src_prepare() {
-	# respect CFLAGS LDFLAGS when building shared libraries. Bug #308873
-	if use python; then
-		sed -i "/mlt.so/s/ -lmlt++ /& ${CFLAGS} ${LDFLAGS} /" src/swig/python/build || die
-		python_fix_shebang src/swig/python
-	fi
-
-	cmake_src_prepare
-}
-
-src_configure() {
-	local mycmakeargs=(
-		-DCMAKE_SKIP_RPATH=ON
-		-DGPL=ON
-		-DGPL3=ON
-		-DBUILD_TESTING=$(usex test)
-		-DMOD_KDENLIVE=ON
-		-DMOD_SDL1=OFF
-		-DMOD_SDL2=$(usex sdl)
-		-DMOD_AVFORMAT=$(usex ffmpeg)
-		-DMOD_PLUS=ON
-		-DMOD_FREI0R=$(usex frei0r)
-		-DMOD_GDK=$(usex gtk)
-		-DMOD_JACKRACK=$(usex jack)
-		-DMOD_RESAMPLE=$(usex libsamplerate)
-		-DMOD_OPENCV=$(usex opencv)
-		-DMOD_MOVIT=$(usex opengl)
-		-DMOD_QT=$(usex qt5)
-		-DMOD_RTAUDIO=$(usex rtaudio)
-		-DMOD_RUBBERBAND=$(usex rubberband)
-		-DMOD_VIDSTAB=$(usex vidstab)
-		-DMOD_XINE=$(usex xine)
-		-DMOD_XML=$(usex xml)
-		-DMOD_SOX=OFF
-	)
-
-	# TODO: rework upstream CMake to allow controlling MMX/SSE/SSE2
-	# TODO: add swig language bindings?
-	# see also https://www.mltframework.org/twiki/bin/view/MLT/ExtremeMakeover
-
-	if use python; then
-		mycmakeargs+=( -DSWIG_PYTHON=ON )
-	fi
-
-	cmake_src_configure
-}
-
-src_install() {
-	cmake_src_install
-
-	insinto /usr/share/${PN}
-	doins -r demo
-
-	#
-	# Install SWIG bindings
-	#
-
-	docinto swig
-
-	if use python; then
-		dodoc "${S}"/src/swig/python/play.py
-		python_optimize
-	fi
-}