[gentoo-commits] repo/gentoo:master commit in: net-dns/hash-slinger/

[Sam James]

commit:     5017bd3e9ffc4b20e5baeb9c821c96f59a257763
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Mon May 31 22:55:13 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Mon May 31 23:19:02 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5017bd3e

net-dns/hash-slinger: add 3.1

Signed-off-by: Sam James <sam <AT> gentoo.org>

 net-dns/hash-slinger/Manifest                |  1 +
 net-dns/hash-slinger/hash-slinger-3.1.ebuild | 49 ++++++++++++++++++++++++++++
 2 files changed, 50 insertions(+)

diff --git a/net-dns/hash-slinger/Manifest b/net-dns/hash-slinger/Manifest
index 4c30a704868..18e33b84ba6 100644
--- a/net-dns/hash-slinger/Manifest
+++ b/net-dns/hash-slinger/Manifest
@@ -1 +1,2 @@
 DIST hash-slinger-3.0.tar.gz 38056 BLAKE2B e72bbddf587225c86ccf7b5c76a48bdece2bf1925a496ae930e9a4973ae47992fea5ca6c0e9e594a1170c0bdbbb3c8712c492c870c8c2e8f523ce247e4e2a4a4 SHA512 7528f267669cdc0c18e1d00c27fff96d915b3143c5534a09c834df3e140035159feeeb8b177528e89cd25265560d0734ef1af94d2f9d28fef47d7ca391e84516
+DIST hash-slinger-3.1.tar.gz 38224 BLAKE2B 35d60b648704e1aa96fbec000ff07c06a31a1f45c58f708fdad1bab464849d4de60963acde9f2c26eb4304454ed1406f698c8007dbf471794f16f26b8ebdb080 SHA512 04ad33b718f716cfd08bd52ee50db81372b7dc13895695e1b23cf904306166b73e388285c7cce8a0a0e5003e783bc61dea4c9ede7a44f22c16e24e2411c7f427

diff --git a/net-dns/hash-slinger/hash-slinger-3.1.ebuild b/net-dns/hash-slinger/hash-slinger-3.1.ebuild
new file mode 100644
index 00000000000..2f14f5b8fea
--- /dev/null
+++ b/net-dns/hash-slinger/hash-slinger-3.1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+
+inherit python-single-r1
+
+DESCRIPTION="Various tools to generate DNS records like SSHFP, TLSA, OPENPGPKEY, IPSECKEY"
+HOMEPAGE="https://github.com/letoams/hash-slinger"
+SRC_URI="https://github.com/letoams/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="ipsec +openpgp +ssh"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	$(python_gen_cond_dep '
+		dev-python/dnspython[${PYTHON_MULTI_USEDEP}]
+		dev-python/ipaddr[${PYTHON_MULTI_USEDEP}]
+		dev-python/m2crypto[${PYTHON_MULTI_USEDEP}]
+	')
+	net-dns/unbound[python,${PYTHON_SINGLE_USEDEP}]
+	ipsec? ( net-vpn/libreswan[dnssec] )
+	openpgp? ( $(python_gen_cond_dep 'dev-python/python-gnupg[${PYTHON_MULTI_USEDEP}]') )
+	ssh? ( net-misc/openssh )
+"
+
+src_install() {
+	local tools tool
+
+	tools="tlsa"
+
+	use ssh	&& tools+=" sshfp"
+	use openpgp && tools+=" openpgpkey"
+	use ipsec && tools+=" ipseckey"
+
+	for tool in $tools ; do
+		doman ${tool}.1
+		python_doscript ${tool}
+	done
+
+	dodoc BUGS CHANGES README
+}