[gentoo-commits] gentoo-x86 commit in sys-kernel/spl: spl-0.6.0_rc9-r2.ebuild spl-9999.ebuild ChangeLog

[Richard Yao (ryao)]

ryao        12/07/10 00:26:07

  Modified:             spl-9999.ebuild ChangeLog
  Added:                spl-0.6.0_rc9-r2.ebuild
  Log:
  Make KM_SLEEP an alias of KM_PUSHPAGE like it is in FreeBSD
  
  (Portage version: 2.1.10.65/cvs/Linux x86_64)

Revision  Changes    Path
1.20                 sys-kernel/spl/spl-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-kernel/spl/spl-9999.ebuild?rev=1.20&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-kernel/spl/spl-9999.ebuild?rev=1.20&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-kernel/spl/spl-9999.ebuild?r1=1.19&r2=1.20

Index: spl-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-kernel/spl/spl-9999.ebuild,v
retrieving revision 1.19
retrieving revision 1.20
diff -u -r1.19 -r1.20
--- spl-9999.ebuild	25 Jun 2012 17:54:06 -0000	1.19
+++ spl-9999.ebuild	10 Jul 2012 00:26:07 -0000	1.20
@@ -1,6 +1,6 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-kernel/spl/spl-9999.ebuild,v 1.19 2012/06/25 17:54:06 ryao Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-kernel/spl/spl-9999.ebuild,v 1.20 2012/07/10 00:26:07 ryao Exp $
 
 EAPI="4"
 AUTOTOOLS_AUTORECONF="1"
@@ -53,6 +53,7 @@
 	then
 		epatch "${FILESDIR}/${P}-detect-kernel-honors-gfp-flags.patch"
 		epatch "${FILESDIR}/${P}-constify-free-functions.patch"
+		epatch "${FILESDIR}/${P}-alias-km-sleep-with-km-pushpage.patch"
 	fi
 
 	autotools-utils_src_prepare



1.22                 sys-kernel/spl/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-kernel/spl/ChangeLog?rev=1.22&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-kernel/spl/ChangeLog?rev=1.22&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-kernel/spl/ChangeLog?r1=1.21&r2=1.22

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-kernel/spl/ChangeLog,v
retrieving revision 1.21
retrieving revision 1.22
diff -u -r1.21 -r1.22
--- ChangeLog	25 Jun 2012 17:54:06 -0000	1.21
+++ ChangeLog	10 Jul 2012 00:26:07 -0000	1.22
@@ -1,6 +1,13 @@
 # ChangeLog for sys-kernel/spl
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-kernel/spl/ChangeLog,v 1.21 2012/06/25 17:54:06 ryao Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-kernel/spl/ChangeLog,v 1.22 2012/07/10 00:26:07 ryao Exp $
+
+*spl-0.6.0_rc9-r2 (10 Jul 2012)
+
+  10 Jul 2012; Richard Yao <ryao@g.o>
+  +files/spl-0.6.0_rc9-alias-km-sleep-with-km-pushpage.patch,
+  +spl-0.6.0_rc9-r2.ebuild, spl-9999.ebuild:
+  Make KM_SLEEP an alias of KM_PUSHPAGE like it is in FreeBSD
 
 *spl-0.6.0_rc9-r1 (25 Jun 2012)
 



1.1                  sys-kernel/spl/spl-0.6.0_rc9-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-kernel/spl/spl-0.6.0_rc9-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-kernel/spl/spl-0.6.0_rc9-r2.ebuild?rev=1.1&content-type=text/plain

Index: spl-0.6.0_rc9-r2.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-kernel/spl/spl-0.6.0_rc9-r2.ebuild,v 1.1 2012/07/10 00:26:07 ryao Exp $

EAPI="4"
AUTOTOOLS_AUTORECONF="1"

inherit flag-o-matic linux-mod autotools-utils

if [[ ${PV} == "9999" ]] ; then
	inherit git-2
	EGIT_REPO_URI="git://github.com/zfsonlinux/${PN}.git"
else
	inherit eutils versionator
	MY_PV=$(replace_version_separator 3 '-')
	SRC_URI="https://github.com/downloads/zfsonlinux/${PN}/${PN}-${MY_PV}.tar.gz"
	S="${WORKDIR}/${PN}-${MY_PV}"
	KEYWORDS="~amd64"
fi

DESCRIPTION="The Solaris Porting Layer is a Linux kernel module which provides many of the Solaris kernel APIs"
HOMEPAGE="http://zfsonlinux.org/"

LICENSE="|| ( GPL-2 GPL-3 )"
SLOT="0"
IUSE="custom-cflags debug"

RDEPEND="!sys-devel/spl"

AT_M4DIR="config"
AUTOTOOLS_IN_SOURCE_BUILD="1"

pkg_setup() {
	CONFIG_CHECK="
		!DEBUG_LOCK_ALLOC
		!GRKERNSEC_HIDESYM
		!PREEMPT
		!PREEMPT_VOLUNTARY
		MODULES
		KALLSYMS
		ZLIB_DEFLATE
		ZLIB_INFLATE
	"
	kernel_is ge 2 6 26 || die "Linux 2.6.26 or newer required"
	check_extra_config
}

src_prepare() {
	# Workaround for hard coded path
	sed -i "s|/sbin/lsmod|/bin/lsmod|" scripts/check.sh || die

	if [ ${PV} != "9999" ]
	then
		epatch "${FILESDIR}/${P}-detect-kernel-honors-gfp-flags.patch"
		epatch "${FILESDIR}/${P}-constify-free-functions.patch"
		epatch "${FILESDIR}/${P}-alias-km-sleep-with-km-pushpage.patch"
	fi

	autotools-utils_src_prepare
}

src_configure() {
	use custom-cflags || strip-flags
	set_arch_to_kernel
	local myeconfargs=(
		--bindir="${EPREFIX}/bin"
		--sbindir="${EPREFIX}/sbin"
		--with-config=all
		--with-linux="${KV_DIR}"
		--with-linux-obj="${KV_OUT_DIR}"
		$(use_enable debug)
	)
	autotools-utils_src_configure
}

src_test() {
	if [[ ! -e /proc/modules ]]
	then
		die  "Missing /proc/modules"
	elif [[ $UID -ne 0 ]]
	then
		ewarn "Cannot run make check tests with FEATURES=userpriv."
		ewarn "Skipping make check tests."
	elif grep -q '^spl ' /proc/modules
	then
		ewarn "Cannot run make check tests with module spl loaded."
		ewarn "Skipping make check tests."
	else
		autotools-utils_src_test
	fi
}