[gentoo-commits] gentoo-x86 commit in app-arch/libarchive: ChangeLog libarchive-2.5.3_beta.ebuild

[Diego Petteno (flameeyes)]

flameeyes    08/05/05 14:27:08

  Modified:             ChangeLog
  Added:                libarchive-2.5.3_beta.ebuild
  Log:
  Version bump.
  (Portage version: 2.1.5_rc6)

Revision  Changes    Path
1.25                 app-arch/libarchive/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/libarchive/ChangeLog?rev=1.25&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/libarchive/ChangeLog?rev=1.25&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/libarchive/ChangeLog?r1=1.24&r2=1.25

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-arch/libarchive/ChangeLog,v
retrieving revision 1.24
retrieving revision 1.25
diff -u -r1.24 -r1.25
--- ChangeLog	5 Apr 2008 14:49:32 -0000	1.24
+++ ChangeLog	5 May 2008 14:27:07 -0000	1.25
@@ -1,6 +1,12 @@
 # ChangeLog for app-arch/libarchive
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-arch/libarchive/ChangeLog,v 1.24 2008/04/05 14:49:32 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-arch/libarchive/ChangeLog,v 1.25 2008/05/05 14:27:07 flameeyes Exp $
+
+*libarchive-2.5.3_beta (05 May 2008)
+
+  05 May 2008; Diego Pettenò <flameeyes@g.o>
+  +libarchive-2.5.3_beta.ebuild:
+  Version bump.
 
 *libarchive-2.5.1_beta (05 Apr 2008)
 *libarchive-2.4.17 (05 Apr 2008)



1.1                  app-arch/libarchive/libarchive-2.5.3_beta.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/libarchive/libarchive-2.5.3_beta.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/libarchive/libarchive-2.5.3_beta.ebuild?rev=1.1&content-type=text/plain

Index: libarchive-2.5.3_beta.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-arch/libarchive/libarchive-2.5.3_beta.ebuild,v 1.1 2008/05/05 14:27:07 flameeyes Exp $

MY_P="${P/_beta/b}"

inherit eutils libtool toolchain-funcs

DESCRIPTION="BSD tar command"
HOMEPAGE="http://people.freebsd.org/~kientzle/libarchive"
SRC_URI="http://people.freebsd.org/~kientzle/libarchive/src/${MY_P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~hppa ~ia64 ~ppc ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
IUSE="build static acl xattr kernel_linux"

RDEPEND="!dev-libs/libarchive
	kernel_linux? (
		acl? ( sys-apps/acl )
		xattr? ( sys-apps/attr )
	)
	!static? ( !build? (
		app-arch/bzip2
		sys-libs/zlib ) )"
DEPEND="${RDEPEND}
	kernel_linux? ( sys-fs/e2fsprogs
		virtual/os-headers )"

S="${WORKDIR}/${MY_P}"

src_unpack() {
	unpack ${A}
	cd "${S}"
	elibtoolize
	epunt_cxx
}

src_compile() {
	local myconf

	if ! use static && ! use build ; then
		myconf="--enable-bsdtar=shared --enable-bsdcpio=shared"
	fi

	econf --bindir=/bin --enable-bsdcpio \
		$(use_enable acl) $(use_enable xattr) \
		${myconf} \
		--disable-dependency-tracking || die "econf failed."

	emake || die "emake failed."
}

src_install() {
	emake -j1 DESTDIR="${D}" install || die "emake install failed."

	# Create tar symlink for FreeBSD
	if [[ ${CHOST} == *-freebsd* ]]; then
		dosym bsdtar /bin/tar
		dosym bsdtar.1 /usr/share/man/man1/tar.1
		# We may wish to switch to symlink bsdcpio to cpio too one day
	fi

	dodoc NEWS README

	if use build; then
		rm -rf "${D}"/usr
		rm -rf "${D}"/lib/*.so*
		return 0
	fi

	dodir /$(get_libdir)
	mv "${D}"/usr/$(get_libdir)/*.so* "${D}"/$(get_libdir)
	gen_usr_ldscript libarchive.so
}



-- 
gentoo-commits@l.g.o mailing list