[gentoo-commits] gentoo-x86 commit in sys-apps/pmount: ChangeLog pmount-0.9.17.ebuild

[Doug Klima (cardoe)]

cardoe      08/02/20 23:49:56

  Modified:             ChangeLog
  Added:                pmount-0.9.17.ebuild
  Log:
  version bump. bug #204991
  (Portage version: 2.1.4.4)

Revision  Changes    Path
1.55                 sys-apps/pmount/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/pmount/ChangeLog?rev=1.55&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/pmount/ChangeLog?rev=1.55&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/pmount/ChangeLog?r1=1.54&r2=1.55

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/pmount/ChangeLog,v
retrieving revision 1.54
retrieving revision 1.55
diff -u -r1.54 -r1.55
--- ChangeLog	27 Jan 2008 23:43:39 -0000	1.54
+++ ChangeLog	20 Feb 2008 23:49:55 -0000	1.55
@@ -1,6 +1,11 @@
 # ChangeLog for sys-apps/pmount
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/pmount/ChangeLog,v 1.54 2008/01/27 23:43:39 leio Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/pmount/ChangeLog,v 1.55 2008/02/20 23:49:55 cardoe Exp $
+
+*pmount-0.9.17 (20 Feb 2008)
+
+  20 Feb 2008; Doug Klima <cardoe@g.o> +pmount-0.9.17.ebuild:
+  version bump. bug #204991
 
   27 Jan 2008; Mart Raudsepp <leio@g.o> pmount-0.9.16.ebuild:
   Add missing intltool DEPEND



1.1                  sys-apps/pmount/pmount-0.9.17.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/pmount/pmount-0.9.17.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/pmount/pmount-0.9.17.ebuild?rev=1.1&content-type=text/plain

Index: pmount-0.9.17.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/pmount/pmount-0.9.17.ebuild,v 1.1 2008/02/20 23:49:55 cardoe Exp $

inherit eutils

DESCRIPTION="Policy based mounter that gives the ability to mount removable devices as a user"
HOMEPAGE="http://pmount.alioth.debian.org/"
SRC_URI="http://alioth.debian.org/frs/download.php/2057/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86"
IUSE="crypt hal"

RDEPEND="hal? ( >=sys-apps/dbus-0.33 >=sys-apps/hal-0.5.2 )
	>=sys-fs/sysfsutils-1.3.0
	crypt? ( || ( >=sys-fs/cryptsetup-1.0.5 sys-fs/cryptsetup-luks ) )"
DEPEND="${RDEPEND}
	>=dev-util/intltool-0.21"

pkg_setup() {
	enewgroup plugdev
}

src_unpack() {
	unpack ${A}
	cd "${S}"
	# Fix make check wrt #202150.
	echo src/luks.c >> po/POTFILES.skip
	echo src/realpath.c >> po/POTFILES.skip
}

src_compile() {
	econf $(use_enable hal) \
		--with-cryptsetup-prog=/bin/cryptsetup
	emake || die "emake failed"
}

src_install () {
	# this is where we mount stuff
	# moved to hal as of 0.5.7-r1
	#keepdir /media

	# Must be run SETUID
	exeinto /usr/bin
	exeopts -m 4710 -g plugdev
	doexe src/pmount src/pumount src/pmount-hal

	dodoc AUTHORS ChangeLog TODO
	doman man/pmount.1 man/pumount.1 man/pmount-hal.1

	insinto /etc
	doins etc/pmount.allow
}

pkg_postinst() {
	elog
	elog "This package has been installed setuid.  The permissions are as such that"
	elog "only users that belong to the plugdev group are allowed to run this."
	elog
	elog "Please add your user to the plugdev group to be able to mount USB drives"
}



-- 
gentoo-commits@l.g.o mailing list