[gentoo-commits] gentoo-x86 commit in media-video/kmplayer: ChangeLog kmplayer-0.10.0.ebuild

[Wulf Krueger (philantrop)]

philantrop    07/10/02 17:27:51

  Modified:             ChangeLog
  Added:                kmplayer-0.10.0.ebuild
  Log:
  Version bump to 0.10.0 as per bug 194209.
  (Portage version: 2.1.3.9)

Revision  Changes    Path
1.104                media-video/kmplayer/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/kmplayer/ChangeLog?rev=1.104&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/kmplayer/ChangeLog?rev=1.104&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/kmplayer/ChangeLog?r1=1.103&r2=1.104

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/kmplayer/ChangeLog,v
retrieving revision 1.103
retrieving revision 1.104
diff -u -r1.103 -r1.104
--- ChangeLog	30 Aug 2007 17:03:18 -0000	1.103
+++ ChangeLog	2 Oct 2007 17:27:51 -0000	1.104
@@ -1,6 +1,12 @@
 # ChangeLog for media-video/kmplayer
 # Copyright 2002-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/kmplayer/ChangeLog,v 1.103 2007/08/30 17:03:18 drac Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/kmplayer/ChangeLog,v 1.104 2007/10/02 17:27:51 philantrop Exp $
+
+*kmplayer-0.10.0 (02 Oct 2007)
+
+  02 Oct 2007; Wulf C. Krueger <philantrop@g.o>
+  +kmplayer-0.10.0.ebuild:
+  Version bump to 0.10.0 as per bug 194209.
 
   30 Aug 2007; Samuli Suominen <drac@g.o> kmplayer-0.9.4a-r1.ebuild:
   Remove USE gstreamer as 0.8 is going away.



1.1                  media-video/kmplayer/kmplayer-0.10.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/kmplayer/kmplayer-0.10.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/kmplayer/kmplayer-0.10.0.ebuild?rev=1.1&content-type=text/plain

Index: kmplayer-0.10.0.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/kmplayer/kmplayer-0.10.0.ebuild,v 1.1 2007/10/02 17:27:51 philantrop Exp $

inherit kde eutils

MY_P="${P/_/-}"
S="${WORKDIR}/${MY_P}"

DESCRIPTION="KMPlayer is a Video player plugin for Konqueror and basic MPlayer/Xine/ffmpeg/ffserver/VDR frontend for KDE."
HOMEPAGE="http://kmplayer.kde.org/"
SRC_URI="http://kmplayer.kde.org/pkgs/${MY_P}.tar.bz2"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="mplayer xine cairo gstreamer"

DEPEND="x11-libs/libXv
		>=dev-libs/expat-2.0.1
		xine? ( >=media-libs/xine-lib-1.1.1 )
		cairo? ( x11-libs/cairo )
		gstreamer? ( >=media-libs/gstreamer-0.10.11 )"
RDEPEND="${DEPEND}
		mplayer? ( || ( media-video/mplayer media-video/mplayer-bin ) )"

LANGS="ar be br bs ca csb cs cy da de el en_GB es et fi fr ga gl he hi hu is it
ja ka lt mt nb nl nn pa pl pt_BR pt ro ru rw sk sr@Latn sr sv ta tr uk zh_CN"
LANGS_DOC="da de en es et fr it nl pt ru sv"

for X in ${LANGS} ; do
	IUSE="${IUSE} linguas_${X}"
done

need-kde 3.5

pkg_setup() {
	if ! use mplayer && ! use xine && ! use cairo && ! use gstreamer ; then
		echo
		ewarn "Neither the mplayer, xine, cairo nor gstreamer USE flags have been set. One of"
		ewarn "them is required. mplayer can be installed afterwards; all of the others will"
		ewarn "require you to recompile ${PN}."
	fi
}

src_unpack() {
	kde_src_unpack

	if use mplayer && use amd64 && ! has_version media-video/mplayer; then
		elog 'NOTICE: You have mplayer-bin installed; you will need to configure'
		elog 'NOTICE: kmplayer to use it from within the application.'
	fi

	for X in ${LANGS} ; do
		use linguas_${X} && MAKE_LANGS="${MAKE_LANGS} ${X}.po"
	done
	cd "${S}/po"
	sed -i -e "s:POFILES =.*:POFILES = ${MAKE_LANGS}:" Makefile.am

	MAKE_DOC=$(echo $(echo "${LINGUAS} ${LANGS_DOC}" | tr ' ' '\n' | sort | uniq -d))
	[[ -n ${MAKE_DOC} ]] && [[ -n ${DOC_DIR_SUFFIX} ]] && \
		MAKE_DOC=$(echo "${MAKE_DOC}" | tr '\n' ' ') && \
		MAKE_DOC="${MAKE_DOC// /${DOC_DIR_SUFFIX} }"
	sed -i -e "s:^SUBDIRS =.*:SUBDIRS = en ${MAKE_DOC}:" \
		"${KDE_S}/doc/Makefile.am" || die "sed for locale failed"

	# Fix the desktop file
	sed -i -e 's:\(Icon=kmplayer\).png:\1:' "${S}/src/kmplayer.desktop"

	rm -f "${S}/configure"
}

src_compile(){
	local myconf="$(use_with gstreamer)
				$(use_with xine)
				$(use_with cairo)
				--disable-koffice-plugin
				--disable-npplayer
				--enable-expat"
	kde_src_compile
}

src_install() {
	kde_src_install

	# Remove this, as kdelibs 3.5.4 provides it
	rm -f "${D}/usr/share/mimelnk/application/x-mplayer2.desktop"
}



-- 
gentoo-commits@g.o mailing list