[gentoo-commits] repo/gentoo:master commit in: sys-kernel/gentoo-kernel-bin/

[Sam James]

commit:     73f9ba07de3174c493a3f9eea2ec3f4f6b1af212
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sun Nov  7 22:08:06 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Nov  7 22:08:06 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=73f9ba07

sys-kernel/gentoo-kernel-bin: add 5.14.17-r1 for arm64

Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-kernel/gentoo-kernel-bin/Manifest              |   1 +
 .../gentoo-kernel-bin-5.14.17-r1.ebuild            | 113 +++++++++++++++++++++
 2 files changed, 114 insertions(+)

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 64c85450def..6f70e093af2 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -58,6 +58,7 @@ DIST gentoo-kernel-5.14.16-1.amd64.xpak 68131257 BLAKE2B 8dc482d683f804b840b9a78
 DIST gentoo-kernel-5.14.16-1.arm64.xpak 63034327 BLAKE2B 27c1fdcd3b6df55aafcfb744a87215ab5643e07f8a1246868036257449e79d8eb18a67f2fa264526a5c0880a65ebaa9e1fcfd7bc9508211848c8331287937736 SHA512 274ef82725a6f6b6e5dddc2bdb6a05439f4cb4a69e16af5d52897de55cff8817fa2137eb0ad12186d21932a87d15c05a74968205684f1ab798428025938fbf7c
 DIST gentoo-kernel-5.14.16-1.x86.xpak 59189394 BLAKE2B 9ed0a856eeaa5a715dc0161d338f5d6fd009985068f7f5dc440c219eeae5bb7fb0e8248d15543adfc2aa0009417a6f9c5a96ed60485c1f0a30138f01b35c3856 SHA512 bc15228884dd481f01b53c67758191a01d1bdad9b566f7c818b1fceb5b38567490557817b09086c7075be252e1804ad05cd4d860dbca981ca51e8be0327bcb4d
 DIST gentoo-kernel-5.14.17-1.amd64.xpak 68122630 BLAKE2B dbb41103b0ae03250cb34a1b267a43068c2d8249a9d4d0637d74687c85be90e95d4841b4f752f2da7cff6f2cd7d9333b17c0e7dd21c17f986495c1803985e53d SHA512 0f0cbc76ce948279bc1d22139d34252f7ce22b9ac318a840458aacdb7f29fc1cc724eca8e7a3d987c69bc3b7387641267b0b8f2077bea0e9a35bbfcb23f8cd82
+DIST gentoo-kernel-5.14.17-1.arm64.xpak 63025950 BLAKE2B 63750480efdf04c30f54230907d5f193e031582dd94c199213ccd3ced454359f4ffaf4b514571b1c5908a4b4fc5238d45ba088f4aceef8bb3306424d4f5378b7 SHA512 29dc5b65dcd6e7e688ea6666d7eb61023f8181f485a593511cd27a82211a071ff9c52af38855fb022451c082e1d94e3cc06202685948620666e8be88287bea47
 DIST gentoo-kernel-5.14.17-1.x86.xpak 59184354 BLAKE2B d00d9aaf98e69f7d5345074b54f1af2340b78a26042aa09b7cac1da6d2573f553a65a9d72428467b51a2392e678585ca1413172a3facc7260ecd0355f3468e04 SHA512 50889944c47482fe3fd3a65ac2a9b45045d313f4410e4532900b57184122ac8b8494f2bff4b3168b4f6c803a507a09bcbbf7d47892a537dd8c06b795071d7a11
 DIST gentoo-kernel-5.15.1-1.amd64.xpak 68887176 BLAKE2B b431ba6e360cb987f6f72ec643762ffa9e77997c9eec3713be51105e362ececcc338410630383070c72b8a41a06b1660e414d41349e3dea0c6a9f2ce80383200 SHA512 80785b528d89c71c6e9ac4af3806c117025e6d21ff6bb5433fcbb1132c83341a9ef3cd6aa7914088a0f2d353f485d681d0311fa46fbdd0faaedb856e0cd03bd7
 DIST gentoo-kernel-5.15.1-1.x86.xpak 59745113 BLAKE2B a21641e1d691abbfd6a70b0f1b40d75480c43ba2a9625ce62945eae5685f39da0ef92f164fa443cfd0096bb670b4e7a537f2b566218cd2deb9c41cfc7cf8afc5 SHA512 4bcb87087cc1afdf6a3d8e61546ad03c231d0d24048029b684a307e4b7bae431156f9d46f03c0e35a62e0524dc0f8e4d7146c5c8010d484814e42af3ad3f8e2b

diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.14.17-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.14.17-r1.ebuild
new file mode 100644
index 00000000000..68f84f5bdd4
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.14.17-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 2 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}