[gentoo-commits] gentoo-x86 commit in net-misc/nx: ChangeLog nx-3.3.0.ebuild nx-3.2.0.ebuild nx-3.1.0-r1.ebuild nx-3.2.0-r3.ebuild nx-3.2.0-r4.ebuild

[Bernard Cafarelli (voyageur)]

voyageur    08/11/24 14:08:17

  Modified:             ChangeLog
  Added:                nx-3.3.0.ebuild
  Removed:              nx-3.2.0.ebuild nx-3.1.0-r1.ebuild
                        nx-3.2.0-r3.ebuild nx-3.2.0-r4.ebuild
  Log:
  3.3.0 version bump, remove old versions
  (Portage version: 2.2_rc16/cvs/Linux 2.6.26-gentoo x86_64)

Revision  Changes    Path
1.34                 net-misc/nx/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/nx/ChangeLog?rev=1.34&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/nx/ChangeLog?rev=1.34&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/nx/ChangeLog?r1=1.33&r2=1.34

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/nx/ChangeLog,v
retrieving revision 1.33
retrieving revision 1.34
diff -u -r1.33 -r1.34
--- ChangeLog	8 Nov 2008 16:05:16 -0000	1.33
+++ ChangeLog	24 Nov 2008 14:08:17 -0000	1.34
@@ -1,6 +1,13 @@
 # ChangeLog for net-misc/nx
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/nx/ChangeLog,v 1.33 2008/11/08 16:05:16 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/nx/ChangeLog,v 1.34 2008/11/24 14:08:17 voyageur Exp $
+
+*nx-3.3.0 (24 Nov 2008)
+
+  24 Nov 2008; Bernard Cafarelli <voyageur@g.o> -nx-3.1.0-r1.ebuild,
+  -nx-3.2.0.ebuild, -nx-3.2.0-r3.ebuild, -nx-3.2.0-r4.ebuild,
+  +nx-3.3.0.ebuild:
+  3.3.0 version bump, remove old versions
 
   08 Nov 2008; Markus Meier <maekke@g.o> nx-3.2.0-r5.ebuild:
   amd64/x86 stable, bug #245685



1.1                  net-misc/nx/nx-3.3.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/nx/nx-3.3.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/nx/nx-3.3.0.ebuild?rev=1.1&content-type=text/plain

Index: nx-3.3.0.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/nx/nx-3.3.0.ebuild,v 1.1 2008/11/24 14:08:17 voyageur Exp $

inherit autotools eutils multilib

DESCRIPTION="NX compression technology core libraries"
HOMEPAGE="http://www.nomachine.com/developers.php"

URI_BASE="http://web04.nomachine.com/download/${PV}/sources"
SRC_NX_X11="nx-X11-$PV-3.tar.gz"
SRC_NXAGENT="nxagent-$PV-6.tar.gz"
SRC_NXAUTH="nxauth-$PV-1.tar.gz"
SRC_NXCOMP="nxcomp-$PV-3.tar.gz"
SRC_NXCOMPEXT="nxcompext-$PV-2.tar.gz"
SRC_NXCOMPSHAD="nxcompshad-$PV-2.tar.gz"
SRC_NXPROXY="nxproxy-$PV-2.tar.gz"

SRC_URI="$URI_BASE/$SRC_NX_X11 $URI_BASE/$SRC_NXAGENT $URI_BASE/$SRC_NXPROXY $URI_BASE/$SRC_NXAUTH $URI_BASE/$SRC_NXCOMPEXT $URI_BASE/$SRC_NXCOMPSHAD $URI_BASE/$SRC_NXCOMP"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="rdesktop vnc"

RDEPEND="x11-libs/libXau
	x11-libs/libXcomposite
	x11-libs/libXdamage
	x11-libs/libXdmcp
	x11-libs/libXpm
	x11-libs/libXrandr
	x11-libs/libXtst
	>=media-libs/jpeg-6b-r4
	>=media-libs/libpng-1.2.8
	>=sys-libs/zlib-1.2.3
	rdesktop? ( net-misc/rdesktop )
	vnc? ( || ( net-misc/vnc net-misc/tightvnc ) )"

DEPEND="${RDEPEND}
		x11-misc/gccmakedep
		x11-misc/imake
		x11-proto/inputproto"

S=${WORKDIR}/${PN}-X11

pkg_setup() {
	if use vnc; then
		if has_version net-misc/vnc && ! built_with_use net-misc/vnc server;
		then
			die "net-misc/vnc needs to be built with USE=\"server\" for VNC support"
		fi

		if has_version net-misc/tightvnc && ! built_with_use net-misc/tightvnc server;
		then
			die "net-misc/tightvnc needs to be built with USE=\"server\" for VNC support"
		fi
	fi
}

src_unpack() {
	unpack ${A}

	cd "${WORKDIR}"
	epatch "${FILESDIR}"/1.5.0/nx-x11-1.5.0-tmp-exec.patch
	epatch "${FILESDIR}"/1.5.0/nxcomp-1.5.0-pic.patch

	cd "${WORKDIR}"/nxproxy
	epatch "${FILESDIR}"/${PN}-3.2.0-nxproxy_read_from_stdin.patch

	cd "${WORKDIR}"/nxcomp
	epatch "${FILESDIR}"/${PN}-2.1.0-invalid-options.patch
	eautoreconf
}

src_compile() {
	cd "${WORKDIR}"/nxcomp || die "No nxcomp directory found"
	econf || die "nxcomp econf failed"
	emake || die "nxcomp emake failed"

	cd "${WORKDIR}"/nxcompshad || die "No nxcompshad directory found"

	econf || die "nxcompshad econf failed"
	emake || die "nxcompshad emake failed"

	cd "${WORKDIR}"/nxproxy || die "No nxproxy directory found"
	econf || die "nxproxy econf failed"
	emake || die "nxproxy emake failed"

	cd "${S}" || die "No nx-X11 directory found"
	emake World || die "nx-X11 emake failed"

	cd "${WORKDIR}"/nxcompext || die "No nxcompext directory found"
	econf || die "nxcompext econf failed"
	emake || die "nxcompext emake failed"
}

src_install() {
	NX_ROOT=/usr/$(get_libdir)/NX

	for x in nxagent nxauth nxproxy; do
		make_wrapper $x ./$x ${NX_ROOT}/bin ${NX_ROOT}/$(get_libdir) ||
			die " $x wrapper creation failed"
	done

	into ${NX_ROOT}
	dobin "${S}"/programs/Xserver/nxagent
	dobin "${S}"/programs/nxauth/nxauth
	dobin "${WORKDIR}"/nxproxy/nxproxy

	dolib.so "${S}"/lib/X11/libX11.so*
	dolib.so "${S}"/lib/Xext/libXext.so*
	dolib.so "${S}"/lib/Xrender/libXrender.so*
	dolib.so "${WORKDIR}"/nxcomp/libXcomp.so*
	dolib.so "${WORKDIR}"/nxcompext/libXcompext.so*
	dolib.so "${WORKDIR}"/nxcompshad/libXcompshad.so*
}