[gentoo-commits] gentoo-x86 commit in dev-java/jamvm: ChangeLog jamvm-1.5.0.ebuild

[Petteri Raty (betelgeuse)]

betelgeuse    08/03/03 17:27:53

  Modified:             ChangeLog
  Added:                jamvm-1.5.0.ebuild
  Log:
  Version bump. Fixes bug #181896 and part of fixing bug #163724.
  (Portage version: 2.1.4.4)

Revision  Changes    Path
1.26                 dev-java/jamvm/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/jamvm/ChangeLog?rev=1.26&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/jamvm/ChangeLog?rev=1.26&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/jamvm/ChangeLog?r1=1.25&r2=1.26

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-java/jamvm/ChangeLog,v
retrieving revision 1.25
retrieving revision 1.26
diff -u -r1.25 -r1.26
--- ChangeLog	28 Feb 2007 14:03:45 -0000	1.25
+++ ChangeLog	3 Mar 2008 17:27:52 -0000	1.26
@@ -1,6 +1,12 @@
 # ChangeLog for dev-java/jamvm
-# Copyright 2000-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-java/jamvm/ChangeLog,v 1.25 2007/02/28 14:03:45 betelgeuse Exp $
+# Copyright 2000-2008 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-java/jamvm/ChangeLog,v 1.26 2008/03/03 17:27:52 betelgeuse Exp $
+
+*jamvm-1.5.0 (03 Mar 2008)
+
+  03 Mar 2008; Petteri Räty <betelgeuse@g.o> +files/jamvm-1.5.0.env,
+  +files/classes-location.patch, +jamvm-1.5.0.ebuild:
+  Version bump. Fixes bug #181896 and part of fixing bug #163724.
 
 *jamvm-1.4.5 (28 Feb 2007)
 



1.1                  dev-java/jamvm/jamvm-1.5.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/jamvm/jamvm-1.5.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/jamvm/jamvm-1.5.0.ebuild?rev=1.1&content-type=text/plain

Index: jamvm-1.5.0.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/jamvm/jamvm-1.5.0.ebuild,v 1.1 2008/03/03 17:27:53 betelgeuse Exp $

EAPI=1

inherit autotools eutils flag-o-matic multilib java-vm-2

DESCRIPTION="An extremely small and specification-compliant virtual machine."
HOMEPAGE="http://jamvm.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="debug libffi"

CLASSPATH_SLOT=0.97
RDEPEND="dev-java/gnu-classpath:${CLASSPATH_SLOT}"
DEPEND="${DEPEND}"
PDEPEND="dev-java/eclipse-ecj:3.3 dev-java/gjdoc"

pkg_setup() {
	if use libffi && ! built_with_use sys-devel/gcc libffi; then
		eerror "sys-devel/gcc not built with libffi support"
		eerror "rebuild sys-devel/gcc with USE=\"libffi\" or"
		eerror "turn off the libffi use flag on on ${PN}"
		die "Rebuild sys-devel/gcc with libffi"
	fi
	java-vm-2_pkg_setup
}

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}/classes-location.patch"
	eautoreconf

	# These come precompiled.
	# configure script uses detects the compiler
	# from PATH. I guess we should compile this from source.
	# Then just make sure not to hit
	# https://bugs.gentoo.org/show_bug.cgi?id=163801
	#rm -v lib/classes.zip || die
}

src_compile() {
	filter-flags "-fomit-frame-pointer"

	# Keep libjvm.so out of /usr
	# http://bugs.gentoo.org/show_bug.cgi?id=181896
	econf \
		$(use_enable debug trace) \
		$(use_enable libffi ffi) \
		--prefix=/opt/${PN} \
		--datadir=/opt/ \
		--bindir=/usr/bin \
		--with-classpath-install-dir=/opt/gnu-classpath-${CLASSPATH_SLOT} \
		|| die "configure failed."
	emake || die "make failed."
}

src_install() {
	emake DESTDIR="${D}" install || die "installation failed."

	dodoc ACKNOWLEDGEMENTS AUTHORS ChangeLog NEWS README \
		|| die "dodoc failed"

	set_java_env "${FILESDIR}/${PN}-1.5.0.env"

	local bindir=/opt/${PN}/bin
	dodir ${bindir}
	dosym /usr/bin/jamvm ${bindir}/java
	dosym /usr/bin/ecj-3.3 ${bindir}/javac
	dosym /usr/bin/gjdoc ${bindir}/javadoc
}



-- 
gentoo-commits@l.g.o mailing list