[gentoo-commits] repo/gentoo:master commit in: sys-kernel/gentoo-kernel-bin/

[Sam James]

commit:     2a24c2b87f9e2c340a5ebca4e0ee844fe0f814ad
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sun Apr 18 02:28:05 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Apr 18 02:28:05 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2a24c2b8

sys-kernel/gentoo-kernel-bin: bump to 5.4.113 for arm64

Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-kernel/gentoo-kernel-bin/Manifest              |   1 +
 .../gentoo-kernel-bin-5.4.113-r1.ebuild            | 114 +++++++++++++++++++++
 2 files changed, 115 insertions(+)

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 2d1c7ecd86f..47dcf40f001 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -49,6 +49,7 @@ DIST gentoo-kernel-5.4.112-1.amd64.xpak 61380061 BLAKE2B 00388f010fbfad30b59df09
 DIST gentoo-kernel-5.4.112-1.arm64.xpak 56418121 BLAKE2B d60e55fa97f8f9fdc6e5fe060c155c49af925fecd8071f108444d823d966349a5f6b07a045a3e1c113b909699efa4c263a64a1d2997509831a988f996609c7d5 SHA512 f0198d9a69c2b5d72248dff0c5f6e0eb5464a44ce0d81bc7e20943bcec87f73e7852894d4a134ad66d7640696a3861ccbae36c2a4e0326d46ced77e6a0c05760
 DIST gentoo-kernel-5.4.112-1.x86.xpak 53174832 BLAKE2B 90e93a7034c98e309c1cd2aa5bfe51e3a1d8e5a9fc22d803106165effda5c4507a6a754adf75a3e6552f65b831baee1aad5b4a16930b29b11c84d74f4d288c6b SHA512 00f536f700184b0d9c63ee0f998a07981045eb068d81d5a8d1e783c78ea41b1e15010cf2e74e923f17b213f20de00316ee7cb1555c16ce840ea574a7486529d7
 DIST gentoo-kernel-5.4.113-1.amd64.xpak 61382156 BLAKE2B 042a2321aa396bceb6984590e51aee79d0d790e35bc3ece36916ccfe9103a801f4892c930491f69dd76ef9932375ea0a796f07f0efa73418d016b1b9025d4866 SHA512 aaa778f541efa574f1831c36da931b17d9fb656f18cc889acec78990c16e569c75e590eecc78e3efd2d21abad37d2ecd82c6566578310a143a8a9cac8a5161e8
+DIST gentoo-kernel-5.4.113-1.arm64.xpak 56479477 BLAKE2B cd395d019db71880e48d6eca6cfa6337c7931e6dae92f80d588b58fdccffbd36c356d3d3b97e3f5d72313dcf06965f837b7ccf948d5e6f5621438196de57c547 SHA512 89c3c0e00ad9b1748332a9aebcba4b1db1d21abb74be9ac3efb6306d8d69ddfc14a367f43e5848e4862572aba0f37426f8c2801a183c8ee6f30868463234667a
 DIST gentoo-kernel-5.4.113-1.x86.xpak 53180295 BLAKE2B 10b9a5457e123367949755ed81671233ff3e4470fb437e8cdff773985dbf07e7e09cb450e56e484a8f27f4aace1abf7bd6053c339aa95aa4d903a37b826a4693 SHA512 6e3fe295073418a7cf4589e96653d71b47f6245970f4891cf44b8cc21bf3ebc4d134dfbd1ea4c2eb99e88c2dd5dd3e35042e89d212f9401b1c084463af2ec098
 DIST linux-5.10.tar.xz 116606704 BLAKE2B b923d7b66309224f42f35f8a5fa219421b0a9362d2adacdadd8d96251f61f7230878ea297a269a7f3b3c56830f0b177e068691e1d7f88501a05653b0a13274d1 SHA512 95bc137d0cf9148da6a9d1f1a878698dc27b40f68e22c597544010a6c591ce1b256f083489d3ff45ff77753289b535135590194d88ef9f007d0ddab3d74de70e
 DIST linux-5.11.tar.xz 117619104 BLAKE2B 81300c27bd5476387a83123aaeb4163c73eb61e9245806c23660cb5e6a4fa88ffc9def027031335fa0270fc4080506cd415990014364e3a98b9d2e8c58a29524 SHA512 a567ec133018bb5ec00c60281479b466c26e02137a93a9c690e83997947df02b6fd94e76e8df748f6d70ceb58a19bacc3b1467de10b7a1fad2763db32b3f1330

diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.113-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.113-r1.ebuild
new file mode 100644
index 00000000000..b63276300c5
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.113-r1.ebuild
@@ -0,0 +1,114 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 3 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}